C

flat.pro Example File

enterprise/controls/flat/flat.pro
TEMPLATE = app
TARGET = flat
QT += quick

SOURCES += \
    main.cpp

RESOURCES += \
    flat.qrc

STYLEPATH = ../../../../../src/controls/Styles/Flat

OTHER_FILES += \
    main.qml \
    $$files($$STYLEPATH/*.qml)

unix {
    target.path = /opt/flat/bin
    INSTALLS += target
}

false { ## Fix deployment with Flat style as an import
osx {
    qml.files = $$files($$STYLEPATH/*.qml)
    qml.path = Contents/Resources/QtQuick/Controls/Styles/Flat
    images.files = $$files($$STYLEPATH/images/*.png)
    images.path = Contents/Resources/QtQuick/Controls/Styles/Flat/images
    QMAKE_BUNDLE_DATA += qml images
} else {
    GENERATED_RESOURCE_FILE = $$OUT_PWD/style.qrc

    INCLUDED_RESOURCE_FILES = \
        $$files($$STYLEPATH/*.qml) \
        $$files($$STYLEPATH/images/*.png)

    RESOURCE_CONTENT = \
        "<RCC>" \
        "<qresource prefix=\"/QtQuick/Controls/Styles/Flat\">"

    for(resourcefile, INCLUDED_RESOURCE_FILES) {
        resourcefileabsolutepath = $$absolute_path($$resourcefile)
        relativepath_in = $$relative_path($$resourcefileabsolutepath, $$STYLEPATH)
        relativepath_out = $$relative_path($$resourcefileabsolutepath, $$OUT_PWD)
        RESOURCE_CONTENT += "<file alias=\"$$relativepath_in\">$$relativepath_out</file>"
    }

    RESOURCE_CONTENT += \
        "</qresource>" \
        "</RCC>"

    write_file($$GENERATED_RESOURCE_FILE, RESOURCE_CONTENT)|error("Aborting.")

    RESOURCES += $$GENERATED_RESOURCE_FILE
}
} ## false

DISTFILES += \
    Content.qml \
    SettingsIcon.qml

Available under certain Qt licenses.
Find out more.