Qt Documentation

imageprovider.pro Example File

declarative/cppextensions/imageprovider/imageprovider.pro 
TEMPLATE = lib
CONFIG += qt plugin
QT += declarative

DESTDIR = ImageProviderCore
TARGET  = qmlimageproviderplugin

SOURCES += imageprovider.cpp

sources.files = $$SOURCES imageprovider.qml imageprovider.pro
sources.path = $$[QT_INSTALL_EXAMPLES]/declarative/cppextensions/imageprovider

target.path = $$[QT_INSTALL_EXAMPLES]/declarative/cppextensions/imageprovider/ImageProviderCore

build_all:!build_pass {
    CONFIG -= build_all
    CONFIG += release
}

ImageProviderCore_sources.files = \
    ImageProviderCore/qmldir
ImageProviderCore_sources.path = $$[QT_INSTALL_EXAMPLES]/declarative/cppextensions/imageprovider/ImageProviderCore

INSTALLS = sources ImageProviderCore_sources target

symbian:{
    include($$QT_SOURCE_TREE/examples/symbianpkgrules.pri)
    TARGET.EPOCALLOWDLLDATA = 1

    importFiles.files = ImageProviderCore/qmlimageproviderplugin.dll ImageProviderCore/qmldir
    importFiles.path = ImageProviderCore
    DEPLOYMENT += importFiles
}
maemo5: include($$QT_SOURCE_TREE/examples/maemo5pkgrules.pri)

© 2016 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.