Example File

TARGET      = maemovibration
HEADERS     += buttonwidget.h mcevibrator.h
SOURCES     += main.cpp buttonwidget.cpp mcevibrator.cpp

# All generated files goes same directory
MOC_DIR     = build
UI_DIR      = build
DESTDIR     = build

TEMPLATE    = app
CONFIG      += debug
QT=core gui

maemo5 {
    QT += dbus
    CONFIG += link_pkgconfig
    PKG_CONFIG += mce
    INSTALLS    += target
    target.path  = /usr/bin/

    INSTALLS    += desktop
    desktop.path  = /usr/share/applications/hildon
    desktop.files  = data/maemovibration.desktop

    INSTALLS    += service
    service.path  = /usr/share/dbus-1/services
    service.files  = data/maemovibration.service

    INSTALLS    += icon64
    icon64.path  = /usr/share/icons/hicolor/64x64/apps
    icon64.files  = data/64x64/maemovibration.png

    # Targets for debian source and binary package creation
    debian-src.commands = dpkg-buildpackage -S -r -us -uc -d
    debian-bin.commands = dpkg-buildpackage -b -r -uc -d
    debian-all.depends = debian-src debian-bin

    # Clean all but Makefile
    compiler_clean.commands = -$(DEL_FILE) $(TARGET)

    QMAKE_EXTRA_TARGETS += debian-all debian-src debian-bin compiler_clean

!maemo5 {
    warning(The Maemo Vibration Example only works for the maemo target!)

© 2016 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.