Qt Reference Documentation

BoomBlock.qml Example File

declarative/tutorials/samegame/samegame4/content/BoomBlock.qml
 /****************************************************************************
 **
 ** Copyright (C) 2010 Nokia Corporation and/or its subsidiary(-ies).
 ** All rights reserved.
 ** Contact: Nokia Corporation (qt-info@nokia.com)
 **
 ** This file is part of the QtDeclarative module of the Qt Toolkit.
 **
 ** $QT_BEGIN_LICENSE:BSD$
 ** You may use this file under the terms of the BSD license as follows:
 **
 ** "Redistribution and use in source and binary forms, with or without
 ** modification, are permitted provided that the following conditions are
 ** met:
 **   * Redistributions of source code must retain the above copyright
 **     notice, this list of conditions and the following disclaimer.
 **   * Redistributions in binary form must reproduce the above copyright
 **     notice, this list of conditions and the following disclaimer in
 **     the documentation and/or other materials provided with the
 **     distribution.
 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
 **     the names of its contributors may be used to endorse or promote
 **     products derived from this software without specific prior written
 **     permission.
 **
 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
 ** $QT_END_LICENSE$
 **
 ****************************************************************************/

 import Qt 4.7
 import Qt.labs.particles 1.0

 Item {
     id: block

     property int type: 0
     property bool dying: false

     //![1]
     property bool spawned: false

     Behavior on x {
         enabled: spawned;
         SpringAnimation{ spring: 2; damping: 0.2 }
     }
     Behavior on y {
         SpringAnimation{ spring: 2; damping: 0.2 }
     }
     //![1]

     //![2]
     Image {
         id: img

         anchors.fill: parent
         source: {
             if (type == 0)
                 return "../../shared/pics/redStone.png";
             else if (type == 1)
                 return "../../shared/pics/blueStone.png";
             else
                 return "../../shared/pics/greenStone.png";
         }
         opacity: 0

         Behavior on opacity {
             NumberAnimation { properties:"opacity"; duration: 200 }
         }
     }
     //![2]

     //![3]
     Particles {
         id: particles

         width: 1; height: 1
         anchors.centerIn: parent

         emissionRate: 0
         lifeSpan: 700; lifeSpanDeviation: 600
         angle: 0; angleDeviation: 360;
         velocity: 100; velocityDeviation: 30
         source: {
             if (type == 0)
                 return "../../shared/pics/redStar.png";
             else if (type == 1)
                 return "../../shared/pics/blueStar.png";
             else
                 return "../../shared/pics/greenStar.png";
         }
     }
     //![3]

     //![4]
     states: [
         State {
             name: "AliveState"
             when: spawned == true && dying == false
             PropertyChanges { target: img; opacity: 1 }
         },

         State {
             name: "DeathState"
             when: dying == true
             StateChangeScript { script: particles.burst(50); }
             PropertyChanges { target: img; opacity: 0 }
             StateChangeScript { script: block.destroy(1000); }
         }
     ]
     //![4]
 }
X

Thank you for giving your feedback.

Make sure it is related to this specific page. For more general bugs and requests, please use the Qt Bug Tracker.

[0]; s.parentNode.insertBefore(ga, s); })();