En esta página

Qt Location Complemento de superposición de elementos

Descripción general

Este complemento de servicios geográficos es un complemento especial que solo proporciona un mapa vacío. Este complemento no ofrece ningún servicio y está pensado para utilizarse en aquellos casos en los que un elemento « Map » solo debe mostrar los elementos añadidos al mapa.

El complemento de servicios geográficos «Items Overlay» se puede cargar utilizando la clave de complemento «itemsoverlay».

Ejemplo de uso

El siguiente fragmento de código muestra cómo se puede añadir un mapa que utilice este complemento como superposición para mostrar elementos del mapa con suavizado. Ten en cuenta que, para que dicho mapa de superposición sea transparente, también es necesario establecer su color en uno transparente, como se muestra en el ejemplo.

Window {
    id: win
    visible: true
    width: 640
    height: 640

    Map {
        id: mapBase
        anchors.fill: parent
        plugin: Plugin { name: "osm" }
        center: QtPositioning.coordinate(45,10)
        zoomLevel: 4
        z: parent.z + 1
    }

    Map {
        id: mapOverlay
        anchors.fill: parent
        plugin: Plugin { name: "itemsoverlay" }
        center: mapBase.center
        color: 'transparent' // Necessary to make this map transparent
        minimumFieldOfView: mapBase.minimumFieldOfView
        maximumFieldOfView: mapBase.maximumFieldOfView
        minimumTilt: mapBase.minimumTilt
        maximumTilt: mapBase.maximumTilt
        minimumZoomLevel: mapBase.minimumZoomLevel
        maximumZoomLevel: mapBase.maximumZoomLevel
        zoomLevel: mapBase.zoomLevel
        tilt: mapBase.tilt;
        bearing: mapBase.bearing
        fieldOfView: mapBase.fieldOfView
        z: mapBase.z + 1

        MapCircle {
            id: circle
            center: QtPositioning.coordinate(44, 10)
            radius: 200000
            border.width: 5

            MouseArea {
                anchors.fill: parent
                drag.target: parent
            }
        }

        // The code below enables SSAA
        layer.enabled: true
        layer.smooth: true
        property int w : mapOverlay.width
        property int h : mapOverlay.height
        property int pr: Screen.devicePixelRatio
        layer.textureSize: Qt.size(w  * 2 * pr, h * 2 * pr)
    }
}

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.