Anulación de propiedades
qmllint escribe esta categoría de advertencia como « [property-override] ».
El miembro no sobrescribe nada
¿Qué ha pasado?
Has marcado una propiedad como « override » sin sobrescribir nada. El tipo base del componente actual no tiene ninguna propiedad con el mismo nombre marcada como « virtual ».
¿Por qué es un problema?
El motor QML lanza un error en tiempo de ejecución cuando encuentra una propiedad de este tipo.
Ejemplo
import QtQuick
Item {
component Base: Item { virtual property int myProperty; }
Base {
override property int myP: 42
}
}Para solucionar esta advertencia, puedes:
- Eliminar el marcador «
override». - Comprueba que el nombre de la propiedad coincida con el nombre de una propiedad «
virtual» o «override» en el tipo base del componente actual.
import QtQuick
Item {
component Base: Item { virtual property int myProperty; }
Base {
property int myP: 42 // solution 1: remove override
override property int myProperty: 42 // solution 2: fix spelling
}
}El miembro «shadows» es un miembro «final»
¿Qué ha pasado?
Has ocultado una propiedad marcada como «final».
¿Por qué es un problema?
Las propiedades se marcan como «final» para evitar que se sobrescriban o se enmascaren. El motor de QML lanza un error en tiempo de ejecución cuando encuentra la propiedad enmascarada.
Ejemplo
import QtQuick
Item {
component Base: Item { final property int myFinal; }
Base {
property int myFinal: 42
}
}Para solucionar esta advertencia, puedes:
- Cambiar el nombre de la propiedad que se sobrescribe o de la que se sobrescribe.
- Sustituir el marcador «
final» por «virtual» o «override» y añadir «override» a la propiedad que se sobrescribe.
import QtQuick
Item {
// solution 1: rename the property
component Base: Item { final property int myFinal; }
Base {
property int myFinal2: 42
}
// solution 2: replace the final marker and add override
component Base2: Item { virtual property int myFinal; }
Base2 {
override property int myFinal: 42
}
}El miembro sobrescribe al miembro final
¿Qué ha pasado?
Has sobrescrito una propiedad marcada como «final».
¿Por qué es un problema?
Las propiedades marcadas como « final » impiden la sobrescritura y la ocultación. El motor QML lanza un error en tiempo de ejecución cuando encuentra la propiedad que se está sobrescribiendo.
Ejemplo
import QtQuick
Item {
component Base: Item { final property int myFinal; }
Base {
override property int myFinal: 42
}
}Para solucionar esta advertencia, puedes:
- Cambiar el nombre de la propiedad que se enmascara o que está enmascarada y eliminar el marcador «
override». - Sustituir el marcador «
final» por «virtual» de la propiedad sobrescrita.
import QtQuick
Item {
// solution 1: remove override and rename
component Base: Item { final property int myFinal; }
Base {
property int myFinal2: 42
}
// solution 2: replace final marker with virtual
component Base2: Item { virtual property int myFinal; }
Base2 {
override property int myFinal: 42
}
}Miembro que enmascara a otro miembro
¿Qué ha pasado?
Has ocultado una propiedad « virtual » o « override » sin utilizar « final » o « override ».
¿Por qué es un problema?
Las propiedades que ocultan propiedades de virtual deben llevar el marcador override o final. El motor de QML lanza una advertencia en tiempo de ejecución cuando encuentra una propiedad de este tipo.
Ejemplo
import QtQuick
Item {
component Base: Item { virtual property int myProperty; }
Base {
property int myProperty: 42
}
}Para solucionar esta advertencia, haz que la propiedad que se superpone sea override o final.
import QtQuick
Item {
component Base: Item { virtual property int myProperty; }
Base {
override property int myProperty: 42 // could also be final
}
}Un miembro sobrescribe a un miembro no virtual
¿Qué ha pasado?
Has sobrescrito una propiedad que no estaba marcada como « virtual » o « override ».
¿Por qué es un error?
Las propiedades que se pueden sobrescribir deben declararse mediante « virtual » o « override ». El motor QML lanza un error de tiempo de ejecución cuando encuentra una propiedad sobrescrita a la que le falta un marcador « virtual » o « override ».
Ejemplo
import QtQuick
Item {
component Base: Item { property int myProperty; }
Base {
override property int myProperty: 42
}
}Para solucionar esta advertencia, cambia el nombre de la propiedad sobrescrita o marca la propiedad sobrescrita como « virtual » o « override ».
import QtQuick
Item {
component Base: Item { virtual property int myProperty; }
Base {
override property int myProperty: 42
}
}La propiedad ya existe en el tipo base
¿Qué ha ocurrido?
Has ocultado una propiedad sin utilizar « virtual », « override » o « final ».
¿Por qué es un error?
Las propiedades que se pueden sobrescribir deben declararse mediante virtual o override. El motor de QML muestra una advertencia en tiempo de ejecución cuando encuentra la propiedad enmascarada.
Ejemplo
import QtQuick
Item {
component Base: Item { property int myProperty; }
Base {
property int myProperty: 42
}
}Para solucionar esta advertencia, cambia el nombre de la propiedad que se sobrescribe o de la que se ve sobrescrita, o añade los marcadores que falten: virtual, override o final.
import QtQuick
Item {
// solution 1: rename one of the properties
component Base: Item { property int myProperty; }
Base {
property int myProperty2: 42
}
// solution 2: add missing markers
component Base2: Item { virtual property int myProperty; }
Base2 {
final property int myProperty: 42 // could also be override
}
}© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.