Qt Quick Particles Ejemplos - Partículas de imagen

Esta es una colección de pequeños ejemplos QML relacionados con el uso de Afectores en el sistema de partículas. Cada ejemplo es un pequeño archivo QML que enfatiza un tipo o característica particular.

Todos a la vez muestra varias de las características de ImageParticle al mismo tiempo.

sprites: [
    Sprite {
        name: "bear"
        source: "images/bear_tiles.png"
        frameCount: 13
        frameDuration: 120
    }
]
colorVariation: 0.5
rotationVelocityVariation: 360
colorTable: "images/colortable.png"

Colored muestra un simple ImageParticle con alguna variación de color.

ImageParticle {
    anchors.fill: parent
    source: "qrc:///particleresources/star.png"
    alpha: 0
    alphaVariation: 0.2
    colorVariation: 1.0
}

Color Table establece el color sobre la vida en las partículas para proporcionar un efecto de arco iris fijo.

source: "qrc:///particleresources/glowdot.png"
colorTable: "images/colortable.png"
sizeTable: "images/colortable.png"

Deformación gira y aplasta una partícula de estrella de mar.

ImageParticle {
    system: sys
    groups: ["goingLeft", "goingRight"]
    source: "images/starfish_4.png"
    rotation: 90
    rotationVelocity: 90
    autoRotation: true
}
ImageParticle {
    system: sys
    groups: ["goingDown"]
    source: "images/starfish_0.png"
    rotation: 180
    yVector: PointDirection { y: 0.5; yVariation: 0.25; xVariation: 0.25; }
}

Rotación demuestra la propiedad autoRotate, para que las partículas giren en la dirección en la que se desplazan.

Compartir muestra lo que ocurre cuando varias ImageParticles intentan renderizar la misma partícula. El siguiente ImageParticle renderiza las partículas dentro del ListView:

ImageParticle {
    anchors.fill: parent
    system: particles
    source: "images/flower.png"
    alpha: 0.1
    color: "white"
    rotationVariation: 180
    z: -1
}

La siguiente ImageParticle se coloca dentro de la lista resaltada, y renderiza las partículas por encima de la otra ImageParticle.

ImageParticle {
    anchors.fill: parent
    system: particles
    source: "images/flower.png"
    color: "red"
    clip: true
    alpha: 1.0
}

Tenga en cuenta que debido a que establece el color y el alfa en este ImageParticle, renderiza las partículas en un color diferente. Como no especifica nada sobre la rotación, comparte la rotación con el otro ImageParticle de modo que las flores se rotan de la misma manera en ambos. Tenga en cuenta que puede deshacer la rotación en otro ImageParticle, sólo tiene que establecer explícitamente rotationVariation a 0.

Sprites demuestra el uso de una partícula de imagen para renderizar sprites animados en lugar de imágenes estáticas para cada partícula.

Proyecto de ejemplo @ code.qt.io