En esta página

Tutorial 4 sobre ordenación dinámica de vistas en QML: ordenación de elementos

La función de arrastrar y soltar no es la única forma de reordenar los elementos de una vista; mediante un « DelegateModel » también es posible ordenar los elementos en función de los datos del modelo. Para ello, ampliamos nuestra instancia de « DelegateModel » de la siguiente manera:

    DelegateModel {
        id: visualModel
        property var lessThan: [
            function(left, right) { return left.name < right.name },
            function(left, right) { return left.type < right.type },
            function(left, right) { return left.age < right.age },
            function(left, right) {
                if (left.size == "Small")
                    return true
                else if (right.size == "Small")
                    return false
                else if (left.size == "Medium")
                    return true
                else
                    return false
            }
        ]

        property int sortOrder: orderSelector.selectedIndex
        onSortOrderChanged: items.setGroups(0, items.count, "unsorted")

        function insertPosition(lessThan, item) {
            let lower = 0
            let upper = items.count
            while (lower < upper) {
                const middle = Math.floor(lower + (upper - lower) / 2)
                const result = lessThan(item.model, items.get(middle).model)
                if (result) {
                    upper = middle
                } else {
                    lower = middle + 1
                }
            }
            return lower
        }

        function sort(lessThan) {
            while (unsortedItems.count > 0) {
                const item = unsortedItems.get(0)
                const index = insertPosition(lessThan, item)

                item.groups = "items"
                items.move(item.itemsIndex, index)
            }
        }

        items.includeByDefault: false
        groups: DelegateModelGroup {
            id: unsortedItems
            name: "unsorted"

            includeByDefault: true
            onChanged: {
                if (visualModel.sortOrder == visualModel.lessThan.length)
                    setGroups(0, count, "items")
                else
                    visualModel.sort(visualModel.lessThan[visualModel.sortOrder])
            }
        }
        model: PetsModel {}
        delegate: dragDelegate
    }
Guía paso a paso

Los elementos de un « DelegateModel » se filtran en grupos representados por el tipo « DelegateModelGroup »; normalmente, todos los elementos del modelo pertenecen a un grupo predeterminado « items », pero este valor predeterminado se puede cambiar con la propiedad «includeByDefault». Para implementar nuestra ordenación, queremos que los elementos se añadan primero a un grupo sin ordenar, desde donde podamos trasladarlos a una posición ordenada dentro del grupo «items». Para ello, desactivamos la propiedad «includeByDefault» en el grupo «items» y la establecemos en un nuevo nombre de grupo: «unsorted».

        items.includeByDefault: false
        groups: DelegateModelGroup {
            id: unsortedItems
            name: "unsorted"

            includeByDefault: true
        }

Ordenamos los elementos buscando primero la posición en el grupo «items» donde insertar el primer elemento sin ordenar y, a continuación, transferimos el elemento al grupo «items» antes de moverlo al índice predeterminado; repetimos este proceso hasta que el grupo «unsorted» quede vacío.

Para encontrar la posición de inserción de un elemento, solicitamos un identificador para dicho elemento del grupo «sin ordenar» mediante la función ` get()`. A través de la propiedad `model` de este identificador, podemos acceder a los mismos datos del modelo que están disponibles en una instancia delegada de ese elemento y compararlos con otros elementos para determinar la posición relativa.

        function insertPosition(lessThan, item) {
            let lower = 0
            let upper = items.count
            while (lower < upper) {
                const middle = Math.floor(lower + (upper - lower) / 2)
                const result = lessThan(item.model, items.get(middle).model)
                if (result) {
                    upper = middle
                } else {
                    lower = middle + 1
                }
            }
            return lower
        }

        function sort(lessThan) {
            while (unsortedItems.count > 0) {
                const item = unsortedItems.get(0)
                const index = insertPosition(lessThan, item)

                item.groups = "items"
                items.move(item.itemsIndex, index)
            }
        }

El argumento «lessThan» de la función de ordenación es una función de comparación que determinará el orden de la lista. En este ejemplo, puede ser una de las siguientes:

        property var lessThan: [
            function(left, right) { return left.name < right.name },
            function(left, right) { return left.type < right.type },
            function(left, right) { return left.age < right.age },
            function(left, right) {
                if (left.size == "Small")
                    return true
                else if (right.size == "Small")
                    return false
                else if (left.size == "Medium")
                    return true
                else
                    return false
            }
        ]

Se activa una ordenación cada vez que se añaden nuevos elementos al grupo «unsorted» ( DelegateModel ), de lo cual se nos notifica mediante el controlador « DelegateModelGroup » ( onChanged ). Si no hay ninguna función de ordenación seleccionada en ese momento, simplemente transferimos todos los elementos del grupo «unsorted» al grupo «items»; de lo contrario, llamamos a la función «sort» con la función de ordenación seleccionada.

        groups: DelegateModelGroup {
            id: unsortedItems
            name: "unsorted"

            includeByDefault: true
            onChanged: {
                if (visualModel.sortOrder == visualModel.lessThan.length)
                    setGroups(0, count, "items")
                else
                    visualModel.sort(visualModel.lessThan[visualModel.sortOrder])
            }
        }

Por último, cuando cambia el orden de clasificación seleccionado, podemos provocar una reclasificación completa de la lista moviendo todos los elementos del grupo «items» al grupo «unsorted», lo que activará el controlador DelegateModelGroup onChanged y volverá a transferir los elementos al grupo «items» en el orden correcto. Ten en cuenta que el controlador DelegateModelGroup onChanged no se invocará de forma recursiva, por lo que no hay ningún problema en que se invoque durante una ordenación.

        property int sortOrder: orderSelector.selectedIndex
        onSortOrderChanged: items.setGroups(0, items.count, "unsorted")

Proyecto de ejemplo en code.qt.io

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.