Plugin Open Street Map Mise à jour de Qt 5

Qt Location Plugin de superposition d'éléments

Vue d'ensemble

Ce plugin de services géographiques est un plugin spécial qui ne fournit qu'une carte vide. Ce plugin ne fournit aucun service et est destiné à être utilisé dans les cas où un élément Map ne doit afficher que les éléments cartographiques ajoutés.

Le plugin de géoservices Items Overlay peut être chargé en utilisant la clé de plugin "itemsoverlay".

Exemple d'utilisation

L'extrait suivant montre comment une carte utilisant ce plugin peut être ajoutée en tant que superposition pour afficher des éléments de carte anticrénelés. Notez que pour qu'une telle carte superposée soit transparente, il est également nécessaire de définir sa couleur à une couleur transparente, telle que transparent, comme dans l'exemple.

Window {
    id: win
    visible: true
    width: 640
    height: 640

    Map {
        id: mapBase
        anchors.fill: parent
        plugin: Plugin { name: "osm" }
        center: QtPositioning.coordinate(45,10)
        zoomLevel: 4
        z: parent.z + 1
    }

    Map {
        id: mapOverlay
        anchors.fill: parent
        plugin: Plugin { name: "itemsoverlay" }
        center: mapBase.center
        color: 'transparent' // Necessary to make this map transparent
        minimumFieldOfView: mapBase.minimumFieldOfView
        maximumFieldOfView: mapBase.maximumFieldOfView
        minimumTilt: mapBase.minimumTilt
        maximumTilt: mapBase.maximumTilt
        minimumZoomLevel: mapBase.minimumZoomLevel
        maximumZoomLevel: mapBase.maximumZoomLevel
        zoomLevel: mapBase.zoomLevel
        tilt: mapBase.tilt;
        bearing: mapBase.bearing
        fieldOfView: mapBase.fieldOfView
        z: mapBase.z + 1

        MapCircle {
            id: circle
            center: QtPositioning.coordinate(44, 10)
            radius: 200000
            border.width: 5

            MouseArea {
                anchors.fill: parent
                drag.target: parent
            }
        }

        // The code below enables SSAA
        layer.enabled: true
        layer.smooth: true
        property int w : mapOverlay.width
        property int h : mapOverlay.height
        property int pr: Screen.devicePixelRatio
        layer.textureSize: Qt.size(w  * 2 * pr, h * 2 * pr)
    }
}

Plugin Open Street Map Mise à jour de Qt 5

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.