Utilisation de bibliothèques tierces

qmake vous permet d’utiliser des bibliothèques tierces avec Qt. Supposons que vous connaissiez une bibliothèque multiplateforme capable de reconnaître des échantillons audio de miaulements de chat et de les traduire en mots anglais. Cette bibliothèque s’appelle CatWhisperer et comprend plusieurs fichiers fournis dans le cadre de la bibliothèque. Votre projet, MyQtApp, stocke ces fichiers dans un dossier nommé 3rdparty:

• MyQtApp/
  • MyQtApp.pro
  • src/
    • main.cpp
  • 3rdparty/
    • CatWhisperer
      • include/
        • CatWhisperer.h
      • lib/
        • libCatWhisperer.so
        • CatWhisperer.lib
      • bin/
        • CatWhisperer.dll

Pour utiliser la bibliothèque CatWhisperer dans MyQtApp, qmake, vous devez indiquer l'emplacement et les noms des bibliothèques CatWhisperer. Vous pouvez également, si vous le souhaitez :

• Indiquer l’emplacement du code source de CatWhisperer afin de ne pas avoir à saisir le chemin d’accès complet de chaque fichier lorsque vous les incluez dans votre propre code.
• Choisir le répertoire de destination dans lequel l’exécutable MyQtApp sera créé.

Les informations ci-dessus sont fournies dans le fichier « .pro », afin que « qmake » puisse les analyser et générer des fichiers « makefile ». Les fichiers « makefile » contiennent toutes les informations nécessaires à votre compilateur et à votre éditeur de liens pour produire le résultat final, qu’il s’agisse d’un exécutable, d’un autre fichier de bibliothèque, etc. Les sections suivantes expliquent la syntaxe selon laquelle « qmake » attend de vous que vous fournissiez ces informations.

Code source

Pour pouvoir écrire

#include <CatWhisperer.h>

au lieu de

#include <3rdparty/CatWhisperer/include/CatWhisperer.h>

, vous pouvez indiquer le chemin d’accès au répertoire CatWhisperer de include à l’aide de la variable INCLUDEPATH:

INCLUDEPATH += 3rdparty/CatWhisperer/include

Fichiers de bibliothèque

Pour indiquer à qmake où trouver les fichiers de bibliothèque CatWhisperer, utilisez la variable LIBS:

LIBS += -L"3rdparty/CatWhisperer/lib" -lCatWhisperer

La première partie de l’expression indique à l’éditeur de liens dans quel répertoire il doit rechercher les fichiers de bibliothèque. Les guillemets doubles ne sont nécessaires que lorsque le chemin d’accès contient des espaces ; nous aurions donc pu les omettre dans cet exemple.

La deuxième partie indique à l’éditeur de liens quelles bibliothèques lier. Nous disposons de deux fichiers de bibliothèque distincts, respectivement pour les plateformes UNIX et Windows : libCatWhisperer.so et CatWhisperer.lib. Il n’est pas nécessaire de spécifier l’extension .lib, ni le préfixe lib (sur les plateformes UNIX).

Répertoire de destination

Par défaut, qmake crée l’exécutable dans le même répertoire que le fichier .pro. Vous pouvez choisir votre propre répertoire à l’aide de la variable DESTDIR:

DESTDIR = bin

Et voilà ! Vous pouvez désormais utiliser la bibliothèque CatWhisperer dans votre projet. Le fichier .pro final se présente comme suit :

TARGET = MyQtApp

TEMPLATE = app

INCLUDEPATH += 3rdparty/CatWhisperer/include

SOURCES += src/main.cpp

LIBS += -L"3rdparty/CatWhisperer/lib" -lCatWhisperer