Constructeur littéral

Cette catégorie d'avertissement est désignée par qmllint sous le nom « [literal-constructors] ».

N’utilisez pas une fonction comme constructeur

Que s'est-il passé ?

Une fonction de construction littérale a été utilisée comme constructeur.

Pourquoi est-ce un problème ?

Appeler une fonction de construction littérale telle que ` Number ` comme une fonction ordinaire convertit de force la valeur transmise en un nombre primitif. En revanche, appeler ` Number ` en tant que constructeur renvoie un objet dérivé de ` Number ` contenant cette valeur. Cela constitue un gaspillage et n’est probablement pas le résultat escompté. De plus, cela peut entraîner un comportement inattendu ou prêtant à confusion, car la valeur renvoyée n’est pas primitive.

Exemple

import QtQuick

Item {
    function numberify(x) {
        return new Number(x)
    }
    Component.onCompleted: {
        let n = numberify("1")
        console.log(typeof n)   // object
        console.log(n === 1)    // false

        if (new Boolean(false)) // All objects are truthy!
            console.log("aaa")  // aa
    }
}

Pour corriger cet avertissement, n'appelez pas ces fonctions en tant que constructeurs, mais en tant que fonctions classiques :

import QtQuick

Item {
    function numberify(x) {
        return Number(x)
    }
    Component.onCompleted: {
        let n = numberify("1")
        console.log(typeof n)   // number
        console.log(n === 1)    // true

        if (Boolean(false))
            console.log("aaa")  // <not executed>
    }
}

La sémantique de `Array` prête à confusion

Que s’est-il passé ?

Un constructeur de type « Array » a été utilisé avec plusieurs arguments.

Pourquoi est-ce un problème ?

Le constructeur ` Array ` présente une sémantique prêto-à-confusion :

• new Array() crée un tableau vide.
• new Array(42) crée un tableau de 42 éléments.
• new Array(42, 43) crée un tableau comportant deux éléments, 42 et 43.

Exemple

import QtQuick

Item {
    function createArray() {
        return new Array(1, 2, 3)
    }
}

Pour corriger cet avertissement, utilisez ` [...] ` au lieu de ` new Array(...)`.

fonctions :

import QtQuick

Item {
    function createArray() {
        return [1, 2, 3]
    }
}