Constructeur littéral

Cette catégorie d'avertissement est orthographiée [literal-constructors] par qmllint.

Ne pas utiliser de fonction comme constructeur

Qu'est-ce qui s'est passé ?

Une fonction de construction littérale a été utilisée comme constructeur.

Pourquoi est-ce mauvais ?

L'appel d'une fonction de construction littérale telle que Number en tant que fonction normale transforme la valeur passée en un nombre primitif. Cependant, l'appel à Number en tant que constructeur renvoie un objet dérivé de Number contenant cette valeur. C'est un gaspillage et ce n'est probablement pas le résultat escompté. De plus, cela peut conduire à un comportement inattendu ou déroutant parce que la valeur renvoyée n'est pas primitive.

Exemple

import QtQuick

Item {
    function numberify(x) {
        return new Number(x)
    }
    Component.onCompleted: {
        let n = numberify("1")
        console.log(typeof n)   // object
        console.log(n === 1)    // false

        if (new Boolean(false)) // All objects are truthy!
            console.log("aaa")  // aa
    }
}

Pour corriger cet avertissement, n'appelez pas ces fonctions en tant que constructeurs, mais en tant que fonctions normales :

import QtQuick

Item {
    function numberify(x) {
        return Number(x)
    }
    Component.onCompleted: {
        let n = numberify("1")
        console.log(typeof n)   // number
        console.log(n === 1)    // true

        if (Boolean(false))
            console.log("aaa")  // <not executed>
    }
}