Type impossible à créer

Cette catégorie d'avertissement est orthographiée « [uncreatable-type] » par qmllint.

L'espace de noms doit commencer par une lettre majuscule

Que s'est-il passé ?

Vous avez utilisé un objet QML provenant d'un espace de noms en minuscules.

Pourquoi est-ce un problème ?

Le langage QML interdit les espaces de noms en minuscules.

Exemple

import QtQuick as quick

quick.Item { ... }

Pour corriger cet avertissement, renommez l'espace de noms afin qu'il commence par une majuscule :

import QtQuick as Quick

Quick.Item { ... }

Le type singleton ne peut pas être créé

Que s'est-il passé ?

Vous avez essayé d'instancier un objet QML à partir d'un type singleton.

Pourquoi est-ce un problème ?

Le langage QML interdit l'instanciation de singletons.

Exemple

import QtQuick

Item {
    Qt { // note: Qt is a singleton type
        id: qt
    }

    property string someProperty: qt.uiLanguage
}

Pour corriger cet avertissement, utilisez directement le singleton sans l'instancier :

import QtQuick

Item {
    property string someProperty: Qt.uiLanguage
}

Le type n'est pas créable

Que s'est-il passé ?

Vous avez essayé d'instancier un objet QML à partir d'une classe de type « uncreatable type ».

Pourquoi est-ce un problème ?

Les types non créables sont spécifiquement marqués pour interdire toute instanciation. Vous utilisez peut-être de manière incorrecte un type qui ne devrait servir que de type attaché ou d'interface.

Exemple

Mauvaise utilisation d’un type attaché

import QtQuick

Item {
    Keys {
        onPressed: function (key) { ... }
    }
}

Pour corriger cet avertissement, utilisez le type attaché Keys au lieu de l'instancier :

import QtQuick

Item {
    Keys.onPressed: function (key) { ... }
}

Utilisation incorrecte d'une interface

import QtQuick

Item {
    property PointerHandler myHandler: PointerHandler {}
}

Pour corriger cet avertissement, utilisez un type dérivé plus spécifique, tel que ` TapHandler` :

import QtQuick

Item {
    property PointerHandler myHandler: TapHandler {}
}