qt_import_plugins

가져오거나 제외할 사용자 정의 플러그인 세트를 지정합니다.

이 명령은 Qt6 패키지의 Core 컴포넌트에 정의되어 있으며, 다음과 같이 로드할 수 있습니다:

find_package(Qt6 REQUIRED COMPONENTS Core)

이 명령은 Qt 5.14에 도입되었습니다.

개요

qt_import_plugins(target
                  [INCLUDE plugin ...]
                  [EXCLUDE plugin ...]
                  [INCLUDE_BY_TYPE plugin_type plugin ...]
                  [EXCLUDE_BY_TYPE plugin_type]
                  [NO_DEFAULT]
)

버전 없는 명령을 사용할 수 없는 경우 qt6_import_plugins() 을 대신 사용합니다. 이 명령은 이 명령과 동일한 인수 집합을 지원합니다.

설명

가져올 사용자 정의 플러그인 집합을 지정합니다. 선택적 인수는 INCLUDE, EXCLUDE, INCLUDE_BY_TYPE, EXCLUDE_BY_TYPE 는 두 번 이상 사용할 수 있습니다.

• INCLUDE - 는 가져올 플러그인 목록을 지정하는 데 사용할 수 있습니다.
• EXCLUDE - 제외할 플러그인 목록을 지정하는 데 사용할 수 있습니다.
• INCLUDE_BY_TYPE - 특정 플러그인 유형에 대해 가져올 플러그인 목록을 재정의하는 데 사용할 수 있습니다.
• EXCLUDE_BY_TYPE - 제외할 플러그인 유형을 지정하는 데 사용하면 해당 유형의 플러그인을 가져오지 않습니다.
• NO_DEFAULT - 기본 플러그인(예: 기본 플랫폼 플러그인)이 자동으로 포함되지 않도록 합니다.

Qt는 imageformats, platforms, sqldrivers 와 같은 플러그인 유형을 제공합니다.

동적 플러그인

플러그인이 동적 라이브러리인 경우, 이 함수는 플러그인 배포를 제어합니다. 예를 들어 이 함수를 사용하면 특정 플러그인 유형을 안드로이드 APK에 패키징하는 것을 제외할 수 있습니다:

qt_add_executable(MyApp ...)
...
qt_import_plugins(MyApp EXCLUDE_BY_TYPE imageformats)

위의 스니펫에서는 MyApp 을 배포할 때 imageformats 유형이 있는 모든 플러그인이 제외됩니다. 결과 Android APK에는 imageformats 플러그인이 포함되지 않습니다.

이 명령을 사용하지 않으면 대상은 대상이 링크된 Qt 모듈에 속한 모든 플러그인을 자동으로 배포합니다.

정적 플러그인

이 명령을 사용하지 않으면 대상은 대상이 링크되는 각 Qt 모듈에 대해 정상적인 기본 정적 플러그인 세트에 자동으로 링크됩니다. 자세한 내용은 target_link_libraries를 참조하십시오.

각 플러그인에는 정적 플러그인을 자동으로 초기화하는 C++ 스텁 파일이 함께 제공됩니다. 따라서 플러그인에 대해 링크하는 모든 대상에는 이 C++ 파일이 해당 대상의 SOURCES 에 추가됩니다.

예시

qt_add_executable(myapp main.cpp)
target_link_libraries(myapp Qt6::Gui Qt6::Sql)
qt_import_plugins(myapp
    INCLUDE Qt6::QCocoaIntegrationPlugin
    EXCLUDE Qt6::QMinimalIntegrationPlugin
    INCLUDE_BY_TYPE imageformats Qt6::QGifPlugin Qt6::QJpegPlugin
    EXCLUDE_BY_TYPE sqldrivers
)

위의 스니펫에서는 myapp 실행 파일에서 다음이 발생합니다:

• Qt6::QCocoaIntegrationPlugin 을 myapp으로 가져옵니다.
• Qt6::QMinimalIntegrationPlugin 플러그인은 myapp로 자동 가져오기에서 제외됩니다.
• imageformats 의 기본 플러그인 목록은 Qt6::QGifPlugin 과 Qt6::QJpegPlugin 만 포함하도록 재정의됩니다.
• 모든 sqldrivers 플러그인은 자동 가져오기에서 제외됩니다.