Variables

The fundamental behavior of qmake is influenced by variable declarations that define the build process of each project. Some of these declare resources, such as headers and source files, that are common to each platform. Others are used to customize the behavior of compilers and linkers on specific platforms.

Platform-specific variables follow the naming pattern of the variables which they extend or modify, but include the name of the relevant platform in their name. For example, QMAKE_LIBS can be used to specify a list of libraries that a project needs to link against, and QMAKE_LIBS_X11 can be used to extend or override this list.

CONFIG

Specifies project configuration and compiler options. The values are recognized internally by qmake and have special meaning.

The following CONFIG values control compilation flags:

OptionDescription
releaseThe project is to be built in release mode. If debug is also specified, the last one takes effect.
debugThe project is to be built in debug mode.
debug_and_releaseThe project is prepared to be built in both debug and release modes.
debug_and_release_targetThis option is set by default. If debug_and_release is also set, the debug and release builds end up in separate debug and release directories.
build_allIf debug_and_release is specified, the project is built in both debug and release modes by default.
autogen_precompile_sourceAutomatically generates a .cpp file that includes the precompiled header file specified in the .pro file.
orderedWhen using the subdirs template, this option specifies that the directories listed should be processed in the order in which they are given.
precompile_headerEnables support for the use of precompiled headers in projects.
warn_onThe compiler should output as many warnings as possible. If warn_off is also specified, the last one takes effect.
warn_offThe compiler should output as few warnings as possible.
exceptionsException support is enabled. Set by default.
exceptions_offException support is disabled.
rttiRTTI support is enabled. By default, the compiler default is used.
rtti_offRTTI support is disabled. By default, the compiler default is used.
stlSTL support is enabled. By default, the compiler default is used.
stl_offSTL support is disabled. By default, the compiler default is used.
threadThread support is enabled. This is enabled when CONFIG includes qt, which is the default.
c++11C++11 support is enabled. This option has no effect if the compiler does not support C++11. By default, support is disabled.

When you use the debug_and_release option (which is the default under Windows), the project will be processed three times: one time to produce a "meta" Makefile, and two more times to produce a Makefile.Debug and a Makefile.Release.

During the latter passes, build_pass and the respective debug or release option is appended to CONFIG. This makes it possible to perform build-specific tasks. For example:

build_pass:CONFIG(debug, debug|release) {
    unix: TARGET = $$join(TARGET,,,_debug)
    else: TARGET = $$join(TARGET,,,d)
}

As an alternative to manually writing build type conditionals, some variables offer build-specific variants, for example QMAKE_LFLAGS_RELEASE in addition to the general QMAKE_LFLAGS. These should be used when available.

The meta Makefile makes the sub-builds invokable via the debug and release targets, and a combined build via the all target. When the build_all CONFIG option is used, the combined build is the default. Otherwise, the last specified CONFIG option from the set (debug, release) determines the default. In this case, you can explicitly invoke the all target to build both configurations at once:

make all

Note: The details are slightly different when producing Visual Studio and Xcode projects.

When linking a library, qmake relies on the underlying platform to know what other libraries this library links against. However, if linking statically, qmake will not get this information unless we use the following CONFIG options:

OptionDescription
create_prlThis option enables qmake to track these dependencies. When this option is enabled, qmake will create a file with the extension .prl which will save meta-information about the library (see Library Dependencies for more info).
link_prlWhen this option is enabled, qmake will process all libraries linked to by the application and find their meta-information (see Library Dependencies for more info).

Note: The create_prl option is required when building a static library, while link_prl is required when using a static library.

The following options define the application or library type:

OptionDescription
qtThe target is a Qt application or library and requires the Qt library and header files. The proper include and library paths for the Qt library will automatically be added to the project. This is defined by default, and can be fine-tuned with the \l{#qt}{QT} variable.
x11The target is a X11 application or library. The proper include paths and libraries will automatically be added to the project.
testcaseThe target is an automated test. A check target will be added to the generated Makefile to run the test. Only relevant when generating Makefiles.
insignificant_testThe exit code of the automated test will be ignored. Only relevant if testcase is also set.
windowsThe target is a Win32 window application (app only). The proper include paths, compiler flags and libraries will automatically be added to the project.
consoleThe target is a Win32 console application (app only). The proper include paths, compiler flags and libraries will automatically be added to the project.
sharedThe target is a shared object/DLL. The proper include paths, compiler flags and libraries will automatically be added to the project. Note that dll can also be used on all platforms; a shared library file with the appropriate suffix for the target platform (.dll or .so) will be created.
dll
staticThe target is a static library (lib only). The proper compiler flags will automatically be added to the project.
staticlib
pluginThe target is a plugin (lib only). This enables dll as well.
designerThe target is a plugin for Qt Designer.
no_lflags_mergeEnsures that the list of libraries stored in the LIBS variable is not reduced to a list of unique values before it is used.

These options define specific features on Windows only:

OptionDescription
flatWhen using the vcapp template this will put all the source files into the source group and the header files into the header group regardless of what directory they reside in. Turning this option off will group the files within the source/header group depending on the directory they reside. This is turned on by default.
embed_manifest_dllEmbeds a manifest file in the DLL created as part of a library project.
embed_manifest_exeEmbeds a manifest file in the DLL created as part of an application project.

See Platform Notes for more information about the options for embedding manifest files.

The following options take an effect only on OS X:

OptionDescription
app_bundlePuts the executable into a bundle (this is the default).
lib_bundlePuts the library into a library bundle.

The build process for bundles is also influenced by the contents of the QMAKE_BUNDLE_DATA variable.

The following options take an effect only on Linux/Unix platforms:

OptionDescription
largefileIncludes support for large files.
separate_debug_infoPuts debugging information for libraries in separate files.

The CONFIG variable will also be checked when resolving scopes. You may assign anything to this variable.

For example:

CONFIG += console newstuff
...
newstuff {
    SOURCES += new.cpp
    HEADERS += new.h
}

DEFINES

qmake adds the values of this variable as compiler C preprocessor macros (-D option).

For example:

DEFINES += USE_MY_STUFF

DEF_FILE

Note: This variable is used only on Windows when using the app template.

Specifies a .def file to be included in the project.

DEPENDPATH

Specifies a list of all directories to look in to resolve dependencies. This variable is used when crawling through included files.

DEPLOYMENT

Note: This variable is used only on the Windows CE platform.

Specifies which additional files will be deployed. Deployment means the transfer of files from the development system to the target device or emulator.

Files can be deployed by either creating a Visual Studio project or using the cetest executable.

For example, the following definition uploads all PNG images in path to the directory where the build target is deployed:

myFiles.files = path\*.png
DEPLOYMENT += myFiles

The default deployment target path for Windows CE is %CSIDL_PROGRAM_FILES%\target, which usually gets expanded to \Program Files\target.

It is also possible to specify multiple sources to be deployed on target paths. In addition, different variables can be used for deployment to different directories.

For example:

myFiles.files = path\file1.ext1 path2\file2.ext1 path3\*
myFiles.path = \some\path\on\device
someother.files = C:\additional\files\*
someother.path = \myFiles\path2
DEPLOYMENT += myFiles someother

Note: In Windows CE all linked Qt libraries will be deployed to the path specified by myFiles.path.

DEPLOYMENT_PLUGIN

Note: This variable is used only on the Windows CE platform.

Specifies the Qt plugins that will be deployed. All plugins available in Qt can be explicitly deployed to the device. See Static Plugins for a complete list.

Note: No plugins will be deployed automatically to Windows CE devices. If the application depends on plugins, these plugins have to be specified manually.

For example, the following definition uploads the jpeg imageformat plugin to the plugins directory on the Windows CE device:

DEPLOYMENT_PLUGIN += qjpeg

DESTDIR

Specifies where to put the target file.

For example:

DESTDIR = ../../lib

DISTFILES

Specifies a list of files to be included in the dist target. This feature is supported by UnixMake specs only.

For example:

DISTFILES += ../program.txt

DLLDESTDIR

Note: This variable applies only to Windows targets.

Specifies where to copy the target dll.

FORMS

Specifies the UI files (see Qt Designer Manual) to be processed by uic before compiling. All dependencies, headers and source files required to build these UI files will automatically be added to the project.

For example:

FORMS = mydialog.ui \
    mywidget.ui \
        myconfig.ui

GUID

Specifies the GUID that is set inside a .vcproj file. The GUID is usually randomly determined. However, should you require a fixed GUID, it can be set using this variable.

This variable is specific to .vcproj files only; it is ignored otherwise.

HEADERS

Defines the header files for the project.

qmake automatically detects whether moc is required by the classes in the headers, and adds the appropriate dependencies and files to the project for generating and linking the moc files.

For example:

HEADERS = myclass.h \
          login.h \
          mainwindow.h

See also SOURCES.

ICON

This variable is used only on Mac OS to set the application icon. Please see the application icon documentation for more information.

INCLUDEPATH

Specifies the #include directories which should be searched when compiling the project.

For example:

INCLUDEPATH = c:/msdev/include d:/stl/include

To specify a path containing spaces, quote the path using the technique described in Whitespace.

win32:INCLUDEPATH += "C:/mylibs/extra headers"
unix:INCLUDEPATH += "/home/user/extra headers"

INSTALLS

Specifies a list of resources that will be installed when make install or a similar installation procedure is executed. Each item in the list is typically defined with attributes that provide information about where it will be installed.

For example, the following target.path definition describes where the build target will be installed, and the INSTALLS assignment adds the build target to the list of existing resources to be installed:

target.path += $$[QT_INSTALL_PLUGINS]/imageformats
INSTALLS += target

For more information, see Installing Files.

LEXIMPLS

Specifies a list of Lex implementation files. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

LEXOBJECTS

Specifies the names of intermediate Lex object files.The value of this variable is typically handled by qmake and rarely needs to be modified.

LEXSOURCES

Specifies a list of Lex source files. All dependencies, headers and source files will automatically be added to the project for building these lex files.

For example:

LEXSOURCES = lexer.l

LIBS

Specifies a list of libraries to be linked into the project. If you use the Unix -l (library) and -L (library path) flags, qmake handles the libraries correctly on Windows (that is, passes the full path of the library to the linker). The library must exist for qmake to find the directory where a -l lib is located.

For example:

unix:LIBS += -L/usr/local/lib -lmath
win32:LIBS += c:/mylibs/math.lib

To specify a path containing spaces, quote the path using the technique described in Whitespace.

win32:LIBS += "C:/mylibs/extra libs/extra.lib"
unix:LIBS += "-L/home/user/extra libs" -lextra

By default, the list of libraries stored in LIBS is reduced to a list of unique names before it is used. To change this behavior, add the no_lflags_merge option to the CONFIG variable:

CONFIG += no_lflags_merge

LITERAL_HASH

This variable is used whenever a literal hash character (#) is needed in a variable declaration, perhaps as part of a file name or in a string passed to some external application.

For example:

# To include a literal hash character, use the $$LITERAL_HASH variable:
urlPieces = http://qt-project.org/doc/qt-5.0/qtgui/qtextdocument.html pageCount
message($$join(urlPieces, $$LITERAL_HASH))

By using LITERAL_HASH in this way, the # character can be used to construct a URL for the message() function to print to the console.

MAKEFILE

Specifies the name of the generated Makefile. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

MAKEFILE_GENERATOR

Specifies the name of the Makefile generator to use when generating a Makefile. The value of this variable is typically handled internally by qmake and rarely needs to be modified.

MOC_DIR

Specifies the directory where all intermediate moc files should be placed.

For example:

unix:MOC_DIR = ../myproject/tmp
win32:MOC_DIR = c:/myproject/tmp

OBJECTS

This variable is automatically populated from the SOURCES variable. The extension of each source file is replaced by .o (Unix) or .obj (Win32). You can add objects to the list.

OBJECTS_DIR

Specifies the directory where all intermediate objects should be placed.

For example:

unix:OBJECTS_DIR = ../myproject/tmp
win32:OBJECTS_DIR = c:/myproject/tmp

POST_TARGETDEPS

Lists the libraries that the target depends on. Some backends, such as the generators for Visual Studio and Xcode project files, do not support this variable. Generally, this variable is supported internally by these build tools, and it is useful for explicitly listing dependent static libraries.

This list is placed after all builtin (and $$PRE_TARGETDEPS) dependencies.

PRE_TARGETDEPS

Lists libraries that the target depends on. Some backends, such as the generators for Visual Studio and Xcode project files, do not support this variable. Generally, this variable is supported internally by these build tools, and it is useful for explicitly listing dependent static libraries.

This list is placed before all builtin dependencies.

PRECOMPILED_HEADER

Indicates the header file for creating a precompiled header file, to increase the compilation speed of a project. Precompiled headers are currently only supported on some platforms (Windows - all MSVC project types, Apple - Xcode, Makefile, Unix - gcc 3.3 and up).

PWD

Specifies the full path leading to the directory containing the current file being parsed. This can be useful to refer to files within the source tree when writing project files to support shadow builds.

See also _PRO_FILE_PWD_.

Note: Do not attempt to overwrite the value of this variable.

OUT_PWD

Specifies the full path leading to the directory where qmake places the generated Makefile.

Note: Do not attempt to overwrite the value of this variable.

QMAKE

Specifies the name of the qmake program itself and is placed in generated Makefiles. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKESPEC

A system variable that contains the full path of the qmake configuration that is used when generating Makefiles. The value of this variable is automatically computed.

Note: Do not attempt to overwrite the value of this variable.

QMAKE_AR_CMD

Note: This variable is used on Unix platforms only.

Specifies the command to execute when creating a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_BUNDLE_DATA

Note: This variable is used on OS X and iOS only.

Specifies the data that will be installed with a library bundle, and is often used to specify a collection of header files.

For example, the following lines add path/to/header_one.h and path/to/header_two.h to a group containing information about the headers supplied with the framework:

FRAMEWORK_HEADERS.version = Versions
FRAMEWORK_HEADERS.files = path/to/header_one.h path/to/header_two.h
FRAMEWORK_HEADERS.path = Headers
QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS

The last line adds the information about the headers to the collection of resources that will be installed with the library bundle.

Library bundles are created when the lib_bundle option is added to the CONFIG variable.

See Platform Notes for more information about creating library bundles.

QMAKE_BUNDLE_EXTENSION

Note: This variable is used on OS X and iOS only.

Specifies the extension to be used for library bundles. This allows frameworks to be created with custom extensions instead of the standard .framework directory name extension.

For example, the following definition will result in a framework with the .myframework extension:

QMAKE_BUNDLE_EXTENSION = .myframework

QMAKE_CC

Specifies the C compiler that will be used when building projects containing C source code. Only the file name of the compiler executable needs to be specified as long as it is on a path contained in the PATH variable when the Makefile is processed.

QMAKE_CFLAGS_DEBUG

Specifies the C compiler flags for debug builds. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_RELEASE

Specifies the C compiler flags for release builds. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_SHLIB

Note: This variable is used on Unix platforms only.

Specifies the compiler flags for creating a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_THREAD

Specifies the compiler flags for creating a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_WARN_OFF

This variable is used only when the warn_off CONFIG option is set. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_WARN_ON

This variable is used only when the warn_on CONFIG option is set. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CLEAN

Specifies a list of generated files (by moc and uic, for example) and object files to be removed by make clean.

QMAKE_CXX

Specifies the C++ compiler that will be used when building projects containing C++ source code. Only the file name of the compiler executable needs to be specified as long as it is on a path contained in the PATH variable when the Makefile is processed.

QMAKE_CXXFLAGS

Specifies the C++ compiler flags for building a project. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified. The flags specific to debug and release modes can be adjusted by modifying the QMAKE_CXXFLAGS_DEBUG and QMAKE_CXXFLAGS_RELEASE variables, respectively.

QMAKE_CXXFLAGS_DEBUG

Specifies the C++ compiler flags for debug builds. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_RELEASE

Specifies the C++ compiler flags for release builds. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_SHLIB

Specifies the C++ compiler flags for creating a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_THREAD

Specifies the C++ compiler flags for creating a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_WARN_OFF

Specifies the C++ compiler flags for suppressing compiler warnings. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_WARN_ON

Specifies C++ compiler flags for generating compiler warnings. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_DISTCLEAN

Specifies a list of files to be removed by make distclean.

QMAKE_EXTENSION_SHLIB

Contains the extension for shared libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

Note: Platform-specific variables that change the extension override the contents of this variable.

QMAKE_EXT_MOC

Contains the extension used on included moc files.

See also File Extensions.

QMAKE_EXT_UI

Contains the extension used on Qt Designer UI files.

See also File Extensions.

QMAKE_EXT_PRL

Contains the extension used on created PRL files.

See also File Extensions, Library Dependencies.

QMAKE_EXT_LEX

Contains the extension used on files given to Lex.

See also File Extensions, LEXSOURCES.

QMAKE_EXT_YACC

Contains the extension used on files given to Yacc.

See also File Extensions, YACCSOURCES.

QMAKE_EXT_OBJ

Contains the extension used on generated object files.

See also File Extensions.

QMAKE_EXT_CPP

Contains suffixes for files that should be interpreted as C++ source code.

See also File Extensions.

QMAKE_EXT_H

Contains suffixes for files which should be interpreted as C header files.

See also File Extensions.

QMAKE_EXTRA_COMPILERS

Specifies a list of additional compilers or preprocessors.

See also Adding Compilers.

QMAKE_EXTRA_TARGETS

Specifies a list of additional qmake targets.

See also Adding Custom Targets.

QMAKE_FAILED_REQUIREMENTS

Contains the list of failed requirements. The value of this variable is set by qmake and cannot be modified.

See also requires() and REQUIRES.

QMAKE_FRAMEWORK_BUNDLE_NAME

Note: This variable is used on OS X and iOS only.

In a framework project, this variable contains the name to be used for the framework that is built.

By default, this variable contains the same value as the TARGET variable.

See Creating Frameworks for more information about creating frameworks and library bundles.

QMAKE_FRAMEWORK_VERSION

Note: This variable is used on OS X and iOS only.

For projects where the build target is an OS X or iOS framework, this variable is used to specify the version number that will be applied to the framework that is built.

By default, this variable contains the same value as the VERSION variable.

See Creating Frameworks for more information about creating frameworks.

QMAKE_INCDIR

Specifies the list of system header paths that are appended to INCLUDEPATH. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INCDIR_EGL

Specifies the location of EGL header files to be added to INCLUDEPATH when building a target with OpenGL/ES or OpenVG support. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INCDIR_OPENGL

Specifies the location of OpenGL header files to be added to INCLUDEPATH when building a target with OpenGL support. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

If the OpenGL implementation uses EGL (most OpenGL/ES systems), then QMAKE_INCDIR_EGL may also need to be set.

QMAKE_INCDIR_OPENGL_ES2

This variable specifies the location of OpenGL header files to be added to INCLUDEPATH when building a target with OpenGL ES 2 support.

The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

If the OpenGL implementation uses EGL (most OpenGL/ES systems), then QMAKE_INCDIR_EGL may also need to be set.

QMAKE_INCDIR_OPENVG

Specifies the location of OpenVG header files to be added to INCLUDEPATH when building a target with OpenVG support. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

If the OpenVG implementation uses EGL then QMAKE_INCDIR_EGL may also need to be set.

QMAKE_INCDIR_X11

Note: This variable is used on Unix platforms only.

Specifies the location of X11 header file paths to be added to INCLUDEPATH when building a X11 target. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INFO_PLIST

Note: This variable is used on OS X and iOS platforms only.

Specifies the name of the property list file, .plist, you would like to include in your OS X and iOS application bundle.

In the .plist file, you can define some variables, e.g., @EXECUTABLE@, which qmake will replace with the actual executable name. Other variables include @ICON@, @TYPEINFO@, @LIBRARY@, and @SHORT_VERSION@.

Note: Most of the time, the default Info.plist is good enough.

QMAKE_LFLAGS

Specifies a general set of flags that are passed to the linker. If you need to change the flags used for a particular platform or type of project, use one of the specialized variables for that purpose instead of this variable.

QMAKE_LFLAGS_CONSOLE

Note: This variable is used on Windows only.

Specifies the linker flags for building console programs. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_DEBUG

Specifies the linker flags for debug builds. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_PLUGIN

Specifies the linker flags for building plugins. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_RPATH

Note: This variable is used on Unix platforms only.

Specifies the linker flags needed to use the values from QMAKE_RPATHDIR.

The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

Specifies the linker flags needed to use the values from QMAKE_RPATHLINKDIR.

The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_RELEASE

Specifies the linker flags for release builds. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_APP

Specifies the linker flags for building applications. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_SHLIB

Specifies the linker flags used for building shared libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_SONAME

Specifies the linker flags for setting the name of shared objects, such as .so or .dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_THREAD

Specifies the linker flags for building multi-threaded projects. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_WINDOWS

Note: This variable is used on Windows only.

Specifies the linker flags for building Windows GUI projects (that is, non-console applications). The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR

Specifies a list of system library paths. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR_FLAGS

Note: This variable is used on Unix platforms only.

Specifies the location of all library directories with -L prefixed. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR_EGL

Specifies the location of the EGL library directory, when EGL is used with OpenGL/ES or OpenVG. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR_OPENGL

Specifies the location of the OpenGL library directory. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

If the OpenGL implementation uses EGL (most OpenGL/ES systems), then QMAKE_LIBDIR_EGL may also need to be set.

QMAKE_LIBDIR_OPENVG

Specifies the location of the OpenVG library directory. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

If the OpenVG implementation uses EGL, then QMAKE_LIBDIR_EGL may also need to be set.

QMAKE_LIBDIR_X11

Note: This variable is used on Unix platforms only.

Specifies the location of the X11 library directory. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS

Specifies all project libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_EGL

Specifies all EGL libraries when building Qt with OpenGL/ES or OpenVG. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified. The usual value is -lEGL.

QMAKE_LIBS_OPENGL

Specifies all OpenGL libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

If the OpenGL implementation uses EGL (most OpenGL/ES systems), then QMAKE_LIBS_EGL may also need to be set.

QMAKE_LIBS_OPENGL_ES1, QMAKE_LIBS_OPENGL_ES2

These variables specify all the OpenGL libraries for OpenGL ES 1 and OpenGL ES 2.

The value of these variables is typically handled by qmake or qmake.conf and rarely needs to be modified.

If the OpenGL implementation uses EGL (most OpenGL/ES systems), then QMAKE_LIBS_EGL may also need to be set.

QMAKE_LIBS_OPENVG

Specifies all OpenVG libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified. The usual value is -lOpenVG.

Some OpenVG engines are implemented on top of OpenGL. This will be detected at configure time and QMAKE_LIBS_OPENGL will be implicitly added to QMAKE_LIBS_OPENVG wherever the OpenVG libraries are linked.

If the OpenVG implementation uses EGL, then QMAKE_LIBS_EGL may also need to be set.

QMAKE_LIBS_THREAD

Note: This variable is used on Unix platforms only.

Specifies all libraries that need to be linked against when building a multi-threaded target. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_X11

Note: This variable is used on Unix platforms only.

Specifies all X11 libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIB_FLAG

This variable is not empty if the lib template is specified. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

Specifies the command to execute when creating a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LN_SHLIB

Specifies the command to execute when creating a link to a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_POST_LINK

Specifies the command to execute after linking the TARGET together. This variable is normally empty and therefore nothing is executed.

Note: This variable takes no effect on Xcode projects.

Specifies the command to execute before linking the TARGET together. This variable is normally empty and therefore nothing is executed.

Note: This variable takes no effect on Xcode projects.

QMAKE_PROJECT_NAME

Note: This variable is used for Visual Studio project files only.

Determines the name of the project when generating project files for IDEs. The default value is the target name. The value of this variable is typically handled by qmake and rarely needs to be modified.

QMAKE_MAC_SDK

This variable is used on OS X when building universal binaries.

QMAKE_MACOSX_DEPLOYMENT_TARGET

This variable only takes effect when building on OS X. On that platform, the variable will be forwarded to the MACOSX_DEPLOYMENT_TARGET environment variable, which is interpreted by the compiler or linker. For more information, see the Deploying an Application on OS X document.

QMAKE_MAKEFILE

Specifies the name of the Makefile to create. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_QMAKE

Contains the abosolute path of the qmake executable.

Note: Do not attempt to overwrite the value of this variable.

QMAKE_RESOURCE_FLAGS

This variable is used to customize the list of options passed to the Resource Compiler in each of the build rules where it is used. For example, the following line ensures that the -threshold and -compress options are used with particular values each time that rcc is invoked:

QMAKE_RESOURCE_FLAGS += -threshold 0 -compress 9

QMAKE_RPATHDIR

Note: This variable is used on Unix platforms only.

Specifies a list of library paths that are added to the executable at link time so that the paths will be preferentially searched at runtime.

QMAKE_RPATHLINKDIR

Specifies a list of library paths for the static linker to search for implicit dependencies of shared libraries. For more information, see the manual page for ld(1).

QMAKE_RUN_CC

Specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_RUN_CC_IMP

Specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_RUN_CXX

Specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_RUN_CXX_IMP

Specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_SONAME_PREFIX

If defined, the value of this variable is used as a path to be prepended to the built shared library's SONAME identifier. The SONAME is the identifier that the dynamic linker will later use to reference the library. In general this reference may be a library name or full library path. On OS X and iOS, the path may be specified relatively using the following placeholders:

PlaceholderEffect
@rpathExpands to paths defined by LC_RPATH mach-o commands in the current process executable or the referring libraries.
@executable_pathExpands to the current process executable location.
@loader_pathExpands to the referring executable or library location.

In most cases, using @rpath is sufficient and recommended:

# <project root>/project.pro
QMAKE_SONAME_PREFIX = @rpath

However, the prefix may be also specified using different placeholders, or an absolute path, such as one of the following:

# <project root>/project.pro
QMAKE_SONAME_PREFIX = @executable_path/../Frameworks
QMAKE_SONAME_PREFIX = @loader_path/Frameworks
QMAKE_SONAME_PREFIX = /Library/Frameworks

For more information, see dyld documentation on dynamic library install names.

QMAKE_TARGET

Specifies the name of the project target. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QT

Specifies the Qt modules that are used by your project.

The table below shows the options that can be used with the QT variable and the Qt modules that are associated with each of them:

OptionModule Enabled
axcontainerQAxContainer, which is part of the Active Qt framework
axserverQAxServer, which is part of the Active Qt framework
concurrentQt Concurrent
core (included by default)Qt Core
dbusQt D-Bus
declarativeQt Quick 1 (deprecated)
designerQt Designer
gui (included by default)Qt GUI
helpQt Help
multimediaQt Multimedia
multimediawidgetsQt Multimedia Widgets
networkQt Network
openglQt OpenGL (deprecated)
printsupportQt Print Support
qmlQt QML
qmltestQt QML Test
x11extrasQt X11 Extras
quickQt Quick
scriptQt Script (deprecated)
scripttoolsQt Script Tools (deprecated)
sensorsQt Sensors
serialportQt Serial Port
sqlQt SQL
svgQt SVG
testlibQt Test
uitoolsQt UI Tools
webkitQt WebKit
webkitwidgetsQt WebKit Widgets
widgetsQt Widgets
winextrasQt Windows Extras
xmlQt XML (deprecated)
xmlpatternsQt XML Patterns

By default, QT contains both core and gui, ensuring that standard GUI applications can be built without further configuration.

If you want to build a project without the Qt GUI module, you need to exclude the gui value with the "-=" operator. The following line will result in a minimal Qt project being built:

QT -= gui # Only the core module is used.

QTPLUGIN

Specifies a list of names of static Qt plugins that are to be linked with an application so that they are available as built-in resources.

qmake automatically adds the plugins that are typically needed by the used Qt modules (see QT). The defaults are tuned towards an optimal out-of-the-box experience. See Static Plugins for a list of available plugins, and ways to override the automatic linking.

This variable currently has no effect when linking against a shared/dynamic build of Qt, or when linking libraries. It may be used for deployment of dynamic plugins at a later time.

QT_VERSION

Contains the current version of Qt.

QT_MAJOR_VERSION

Contains the current major version of Qt.

QT_MINOR_VERSION

Contains the current minor version of Qt.

QT_PATCH_VERSION

Contains the current patch version of Qt.

RC_FILE

Specifies the name of the resource file for the application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

RC_INCLUDEPATH

Specifies include paths that are passed to the Windows Resource Compiler.

RCC_DIR

Specifies the directory for Qt Resource Compiler output files.

For example:

unix:RCC_DIR = ../myproject/resources
win32:RCC_DIR = c:/myproject/resources

REQUIRES

Specifies a list of values that are evaluated as conditions. If any of the conditions is false, qmake skips this project (and its SUBDIRS) when building.

Note: We recommend using the requires() function instead if you want to skip projects or subprojects when building.

RESOURCES

Specifies the name of the resource collection files (qrc) for the target. For more information about the resource collection file, see The Qt Resource System.

RES_FILE

Specifies the name of the compiled Windows resource file for the target. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

SIGNATURE_FILE

Note: This variable is only used on Windows CE.

Specifies which signature file should be used to sign the project target.

Note: This variable will overwrite the setting you have specified in configure, with the -signature option.

SOURCES

Specifies the names of all source files in the project.

For example:

SOURCES = myclass.cpp \
      login.cpp \
      mainwindow.cpp

See also HEADERS.

SUBDIRS

This variable, when used with the subdirs template specifies the names of all subdirectories or project files that contain parts of the project that need to be built. Each subdirectory specified using this variable must contain its own project file.

It is recommended that the project file in each subdirectory has the same base name as the subdirectory itself, because that makes it possible to omit the file name. For example, if the subdirectory is called myapp, the project file in that directory should be called myapp.pro.

Alternatively, you can specify a relative path to a .pro file in any directory. It is strongly recommended that you specify only paths in the current project's parent directory or its subdirectories.

For example:

SUBDIRS = kernel \
          tools \
          myapp

If you need to ensure that the subdirectories are built in the order in which they are specified, update the CONFIG variable to include the ordered option:

CONFIG += ordered

It is possible to modify this default behavior of SUBDIRS by giving additional modifiers to SUBDIRS elements. Supported modifiers are:

ModifierEffect
.subdirUse the specified subdirectory instead of SUBDIRS value.
.fileSpecify the subproject pro file explicitly. Cannot be used in conjunction with .subdir modifier.
.dependsThis subproject depends on specified subproject. Available only on platforms that use makefiles.
.makefileThe makefile of subproject. Available only on platforms that use makefiles.
.targetBase string used for makefile targets related to this subproject. Available only on platforms that use makefiles.

For example, define two subdirectories, both of which reside in a different directory than the SUBDIRS value, and one of the subdirectories must be built before the other:

SUBDIRS += my_executable my_library
my_executable.subdir = app
my_executable.depends = my_library
my_library.subdir = lib

TARGET

Specifies the name of the target file. Contains the base name of the project file by default.

For example:

TEMPLATE = app
TARGET = myapp
SOURCES = main.cpp

The project file above would produce an executable named myapp on unix and myapp.exe on Windows.

TARGET_EXT

Specifies the extension of TARGET. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

TARGET_x

Specifies the extension of TARGET with a major version number. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

TARGET_x.y.z

Specifies the extension of TARGET with version number. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

TEMPLATE

Specifies the name of the template to use when generating the project. The allowed values are:

OptionDescription
appCreates a Makefile for building applications (the default). See Building an Application for more information.
libCreates a Makefile for building libraries. See Building a Library for more information.
subdirsCreates a Makefile for building targets in subdirectories. The subdirectories are specified using the SUBDIRS variable.
auxCreates a Makefile for not building anything. Use this if no compiler needs to be invoked to create the target, for instance because your project is written in an interpreted language.

Note: This template type is only available for Makefile-based generators. In particular, it will not work with the vcxproj and Xcode generators.

vcappWindows only. Creates an application project for Visual Studio. See Creating Visual Studio Project Files for more information.
vclibWindows only. Creates a library project for Visual Studio.

For example:

TEMPLATE = lib
SOURCES = main.cpp
TARGET = mylib

The template can be overridden by specifying a new template type with the -t command line option. This overrides the template type after the .pro file has been processed. With .pro files that use the template type to determine how the project is built, it is necessary to declare TEMPLATE on the command line rather than use the -t option.

TRANSLATIONS

Specifies a list of translation (.ts) files that contain translations of the user interface text into non-native languages.

See the Qt Linguist Manual for more information about internationalization (i18n) and localization (l10n) with Qt.

UI_DIR

Specifies the directory where all intermediate files from uic should be placed.

For example:

unix:UI_DIR = ../myproject/ui
win32:UI_DIR = c:/myproject/ui

VERSION

Specifies the version number of the application if the app template is specified or the version number of the library if the lib template is specified.

For example:

VERSION = 1.2.3

VER_MAJ

Specifies the major version number of the library if the lib template is specified.

VER_MIN

Specifies the minor version number of the library if the lib template is specified.

VER_PAT

Specifies the patch version number of the library if the lib template is specified.

VPATH

Tells qmake where to search for files it cannot open. For example, if qmake looks for SOURCES and finds an entry that it cannot open, it looks through the entire VPATH list to see if it can find the file on its own.

See also DEPENDPATH.

WINRT_MANIFEST

Specifies parameters to be passed to the application manifest on Windows Runtime. The allowed values are:

MemberDescription
architectureThe target architecture. Defaults to VCPROJ_ARCH.
backgroundTile background color. Defaults to green.
capabilitiesSpecifies capabilities to add to the capability list.
capabilities_deviceSpecifies device capabilities to add to the capability list (location, webcam, and so on).
default_languageThe default language code of the application. Defaults to "en".
dependenciesSpecifies dependencies required by the package.
descriptionPackage description. Defaults to Default package description.
foregroundTile foreground (text) color. Defaults to light. This option is only available for Windows Store apps on Windows 8 and Windows RT.
iconic_tile_iconImage file for the iconic tile template icon. Default provided by the mkspec.
iconic_tile_smallImage file for the small iconic tile template logo. Default provided by the mkspec.
identityThe unique ID of the app. Defaults to reusing the existing generated manifest's UUID, or generates a new UUID if none is present.
logo_largeLarge logo image file. Default provided by the mkspec.
logo_mediumMedium logo image file. Default provided by the mkspec.
logo_smallSmall logo image file. Default provided by the mkspec.
logo_storeLogo image file for Windows Store. Default provided by the mkspec.
nameThe name of the package as displayed to the user. Defaults to TARGET.
phone_product_idThe GUID of the product. Defaults to the value of WINRT_MANIFEST.identity. (Windows Phone only)
phone_publisher_idThe GUID of the publisher. Defaults to an invalid GUID. (Windows Phone only)
publisherDisplay name of the publisher. Defaults to Default publisher display name.
publisher_idThe publisher's distinguished name (default: CN=MyCN).
splash_screenSplash screen image file. Default provided by the mkspec.
targetThe name of the target (.exe). Defaults to TARGET.
versionThe version number of the package. Defaults to 1.0.0.0.

You can use any combination of those values.

For example:

WINRT_MANIFEST.publisher = MyCompany
WINRT_MANIFEST.logo_store = someImage.png
WINRT_MANIFEST.capabilities += internetClient
WINRT_MANIFEST.device_capabilities += location

Additionally, an input manifest file can be specified by using WINRT_MANIFEST.

For example:

WINRT_MANIFEST = someManifest.xml.in

YACCSOURCES

Specifies a list of Yacc source files to be included in the project. All dependencies, headers and source files will automatically be included in the project.

For example:

YACCSOURCES = moc.y

_PRO_FILE_

Contains the path to the project file in use.

For example, the following line causes the location of the project file to be written to the console:

message($$_PRO_FILE_)

Note: Do not attempt to overwrite the value of this variable.

_PRO_FILE_PWD_

Contains the path to the directory containing the project file in use.

For example, the following line causes the location of the directory containing the project file to be written to the console:

message($$_PRO_FILE_PWD_)

Note: Do not attempt to overwrite the value of this variable.

© 2014 Digia Plc and/or its subsidiaries. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Digia, Qt and their respective logos are trademarks of Digia Plc in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.