ServerDiscovery QML Type

Provides information about available servers. More...

Import Statement: import QtOpcUa .
Since: QtOpcUa 5.13

Properties

Methods

  • ApplicationDescription at(index)

Detailed Description

Allows to fetch and access information about servers known to a server or discovery server.

QtOpcUa.Connection {
    id: connection
    backend: availableBackends[0]
    defaultConnection: true
}

QtOpcUa.ServerDiscovery {
    discoveryUrl: "opc.tcp://127.0.0.1:43344"
    onServersChanged: {
        if (status.isGood) {
            if (status.status == QtOpcUa.Status.GoodCompletesAsynchronusly)
                return; // wait until finished
            if (count > 0) {
                // choose right server
                endpointDiscovery.serverUrl = at(0).discoveryUrls[0];
                console.log("Using server URL:", endpointDiscovery.serverUrl);
            } else {
                // no servers retrieved
            }
        } else {
            // Fetching servers failed
            console.log("Error fetching server:", servers.status.status);
        }
    }
}

QtOpcUa.EndpointDiscovery {
    id: endpointDiscovery
    onEndpointsChanged: {
        if (status.isGood) {
            if (status.status == QtOpcUa.Status.GoodCompletesAsynchronusly)
                return; // wait until finished
            if (count > 0) {
                // choose right endpoint
                console.log("Using endpoint", at(0).endpointUrl, at(0).securityPolicy);
                connection.connectToEndpoint(at(0));
            } else {
                // no endpoints retrieved
            }
        } else {
            // Fetching endpoints failed
            console.log("Error fetching endpoints:", status.status);
        }
    }
}

Property Documentation

connection : Connection

The connection to be used for requesting information.

If this property is not set, the default connection will be used, if any.

See also Connection and Connection::defaultConnection.


count : int

Current number of servers in this element. Before using any data from this server discovery, you should check status if retrieval of the information was successful.

See also status and Status.


discoveryUrl : string

URL of the server to retrieve the list of servers from. Every time the URL is changed, a request to the given server is started.

When starting the request, the list of available servers is cleared and the status is set to Status.GoodCompletesAsynchronously. Once the request is finished, status changes. Make sure to check the status before acessing the list of servers.

onServersChanged: {
        if (status.isGood) {
            if (status.status == QtOpcUa.Status.GoodCompletesAsynchronusly)
                return; // wait until finished
            if (count > 0) {
                var serverUrl = at(0).serverUrl();
                console.log(serverUrl);
            }
        } else {
            // handle error
        }
}

See also ApplicationDescription, status, at, count, and Status.


status : Status

The current status of this element. In case the last retrieval of servers was successful, the status should be Status.Good.

if (status.isGood) {
    // Choose endpoint to connect to
} else {
    // handle error
}

See also Status.


Method Documentation

Returns the application description at given index. In case there are no servers available or the index is invalid, an invalid application description is returned. Before using any returned data, you should check status if retrieval of the information was successful.

if (servers.status.isGood) {
    if (servers.count > 0)
        var serverUrl = at(0).serverUrl();
        console.log(serverUrl);
        // Choose endpoint to connect to
} else {
    // handle error
}

See also count, status, and ApplicationDescription.


© 2023 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.