Qt Location Plugin „Items Overlay“

Übersicht

Dieses Geodienst-Plugin ist ein spezielles Plugin, das lediglich eine leere Karte bereitstellt. Dieses Plugin bietet keine Dienste an und ist für Fälle vorgesehen, in denen ein „ Map “-Element ausschließlich die hinzugefügten Kartenelemente anzeigen soll.

Das Geo-Services-Plugin „Items Overlay“ kann mithilfe des Plugin-Schlüssels „itemsoverlay“ geladen werden.

Anwendungsbeispiel

Der folgende Codeausschnitt zeigt, wie eine Karte, die dieses Plugin verwendet, als Overlay hinzugefügt werden kann, um Kartenelemente mit Anti-Aliasing darzustellen. Beachten Sie, dass eine solche Overlay-Karte nur dann transparent ist, wenn ihre Farbe auf eine transparente Farbe wie „transparent“ gesetzt wird, wie im Beispiel gezeigt.

Window {
    id: win
    visible: true
    width: 640
    height: 640

    Map {
        id: mapBase
        anchors.fill: parent
        plugin: Plugin { name: "osm" }
        center: QtPositioning.coordinate(45,10)
        zoomLevel: 4
        z: parent.z + 1
    }

    Map {
        id: mapOverlay
        anchors.fill: parent
        plugin: Plugin { name: "itemsoverlay" }
        center: mapBase.center
        color: 'transparent' // Necessary to make this map transparent
        minimumFieldOfView: mapBase.minimumFieldOfView
        maximumFieldOfView: mapBase.maximumFieldOfView
        minimumTilt: mapBase.minimumTilt
        maximumTilt: mapBase.maximumTilt
        minimumZoomLevel: mapBase.minimumZoomLevel
        maximumZoomLevel: mapBase.maximumZoomLevel
        zoomLevel: mapBase.zoomLevel
        tilt: mapBase.tilt;
        bearing: mapBase.bearing
        fieldOfView: mapBase.fieldOfView
        z: mapBase.z + 1

        MapCircle {
            id: circle
            center: QtPositioning.coordinate(44, 10)
            radius: 200000
            border.width: 5

            MouseArea {
                anchors.fill: parent
                drag.target: parent
            }
        }

        // The code below enables SSAA
        layer.enabled: true
        layer.smooth: true
        property int w : mapOverlay.width
        property int h : mapOverlay.height
        property int pr: Screen.devicePixelRatio
        layer.textureSize: Qt.size(w  * 2 * pr, h * 2 * pr)
    }
}

OpenStreetMap-Plugin Upgrade von Qt 5

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.