Map QML Type

Der Kartentyp zeigt eine Karte an. Mehr...

• Liste aller Elemente, einschließlich geerbter Elemente
• „Map“ ist Teil des QML-Maps-Plugins.

Eigenschaften

• activeMapType : mapType
• bearing : real (since QtLocation 5.9)
• center : coordinate
• color : color
• copyrightsVisible : bool
• error : enumeration
• errorString : string
• fieldOfView : real (since QtLocation 5.9)
• mapItems : list<MapItem>
• mapReady : bool
• maximumFieldOfView : real (since QtLocation 5.9)
• maximumTilt : real (since QtLocation 5.9)
• maximumZoomLevel : real
• minimumFieldOfView : real (since QtLocation 5.9)
• minimumTilt : real (since QtLocation 5.9)
• minimumZoomLevel : real
• plugin : Plugin
• supportedMapTypes : list<mapType>
• tilt : real (since QtLocation 5.9)
• visibleArea : rect
• visibleRegion : geoShape
• zoomLevel : real

Signale

• copyrightLinkActivated(string link)

Methoden

• void addMapItem(MapItem item)
• void addMapItemGroup(MapItemGroup itemGroup)
• void addMapItemView(MapItemView itemView)
• void alignCoordinateToPoint(coordinate coordinate, QPointF point)
• void clearData()
• void clearMapItems()
• void fitViewportToGeoShape(geoShape, margins)
• void fitViewportToMapItems(list<MapItems> items)
• void fitViewportToVisibleMapItems()
• point fromCoordinate(coordinate coordinate, bool clipToViewPort)
• void pan(int dx, int dy)
• void prefetchData()
• void removeMapItem(MapItem item)
• void removeMapItemGroup(MapItemGroup itemGroup)
• void removeMapItemView(MapItemView itemView)
• void setBearing(real bearing, coordinate coordinate)
• coordinate toCoordinate(QPointF position, bool clipToViewPort)

Ausführliche Beschreibung

Der Kartentyp dient zur Darstellung einer Karte oder eines Bildes der Erde und bietet zudem die Möglichkeit, interaktive Objekte anzuzeigen, die mit der Kartenoberfläche verknüpft sind.

Es gibt eine Vielzahl verschiedener Möglichkeiten, die Erdoberfläche zweidimensional darzustellen, doch alle basieren auf einer Projektion: einer mathematischen Beziehung zwischen den 3D-Koordinaten (Breitengrad, Längengrad und Höhe) und den 2D-Koordinaten (X und Y in Pixeln) auf dem Bildschirm.

Verschiedene Kartendatenquellen können unterschiedliche Projektionen verwenden, und aus Sicht des Kartentyps behandeln wir diese als eine austauschbare Einheit: das Karten-Plugin. Ein Karten-Plugin besteht aus einer Datenquelle sowie allen weiteren Details, die zur Darstellung der Daten auf dem Bildschirm erforderlich sind.

Das aktuell verwendete Karten-Plugin ist in der Eigenschaft „ plugin “ des Kartenelements enthalten. Um ein beliebiges Bild in einem Kartenelement anzuzeigen, müssen Sie diese Eigenschaft festlegen. Eine Beschreibung, wie Sie ein geeignetes Plugin zum Einsatz abrufen können, finden Sie im Typ „ Plugin “.

Der im „Map“-Element angezeigte geografische Bereich wird als dessen „Viewport“ bezeichnet und durch die Eigenschaften „ center “ sowie „ zoomLevel “ definiert. Die Eigenschaft „ center “ enthält einen „ geoCoordinate “, der den Mittelpunkt des Viewports angibt, während „ zoomLevel “ den Maßstab der Karte steuert. Weitere Details zu den Werten dieser Eigenschaften finden Sie bei den jeweiligen Beschreibungen.

Wenn die Karte angezeigt wird, wird jede sichtbare geografische Koordinate einer Pixel-X- und -Y-Koordinate auf dem Bildschirm zugeordnet. Zur Umrechnung zwischen diesen beiden Koordinatensystemen stellt „Map“ die Funktionen „ toCoordinate “ und „ fromCoordinate “ zur Verfügung, die allgemein nützlich sind.

Kartenobjekte

Kartenbezogene Objekte können im Hauptteil eines Map-Objekts in ` Qt Quick ` deklariert werden und erscheinen automatisch auf der Karte. Um ein Objekt programmgesteuert hinzuzufügen, stellen Sie zunächst sicher, dass es mit der Karte als übergeordnetem Objekt erstellt wurde (beispielsweise in einem Argument für ` Component::createObject`). Rufen Sie anschließend die Methode „ addMapItem “ der Karte auf, sofern der Typ dieses Objekts einer der folgenden ist: „ MapCircle “, „ MapRectangle “, „ MapPolyline “, „ MapPolygon “, „ MapRoute “ oder „ MapQuickItem “. Es gibt auch eine entsprechende Methode „ removeMapItem “, um den umgekehrten Vorgang durchzuführen und beliebige der oben genannten Arten von Kartenobjekten aus der Karte zu entfernen.

Das Verschieben von Map-Objekten, das Ändern ihrer Größe oder ihrer Form erfordert normalerweise keine spezielle Interaktion mit der Map selbst – die Änderung dieser Eigenschaften in einem Map-Objekt führt automatisch zu einer Aktualisierung der Anzeige.

Leistung

Karten werden mithilfe von OpenGL (ES) und dem Qt-Scene-Graph-Stack gerendert und bieten daher eine recht gute Leistung, sofern GL-beschleunigte Hardware verfügbar ist.

Bei „Online“-Karten können Netzwerkbandbreite und Latenz einen wesentlichen Einfluss auf die vom Benutzer wahrgenommene Leistung haben. Um dies abzumildern, wird umfangreiches Caching durchgeführt, doch diese Maßnahmen sind nicht immer perfekt.

Im Allgemeinen können große und komplexe Kartenelemente wie Polygone und Polylinien mit einer großen Anzahl von Eckpunkten die Leistung der Benutzeroberfläche beeinträchtigen.

Anwendungsbeispiel

Der folgende Codeausschnitt zeigt eine einfache Karte und den erforderlichen Plugin-Typ zu deren Verwendung. Die Karte ist auf Oslo, Norwegen, zentriert und auf Zoomstufe 14 eingestellt.

import QtQuick
import QtLocation
import QtPositioning

Window {
    ...
    Plugin {
        id: mapPlugin
        name: "osm"
    }

    Map {
        id: map
        anchors.fill: parent
        plugin: mapPlugin
        center: QtPositioning.coordinate(59.91, 10.75) // Oslo
        zoomLevel: 14
        property geoCoordinate startCentroid

        PinchHandler {
            id: pinch
            target: null
            onActiveChanged: if (active) {
                map.startCentroid = map.toCoordinate(pinch.centroid.position, false)
            }
            onScaleChanged: (delta) => {
                map.zoomLevel += Math.log2(delta)
                map.alignCoordinateToPoint(map.startCentroid, pinch.centroid.position)
            }
            onRotationChanged: (delta) => {
                map.bearing -= delta
                map.alignCoordinateToPoint(map.startCentroid, pinch.centroid.position)
            }
            grabPermissions: PointerHandler.TakeOverForbidden
        }
        WheelHandler {
            id: wheel
            // workaround for QTBUG-87646 / QTBUG-112394 / QTBUG-112432:
            // Magic Mouse pretends to be a trackpad but doesn't work with PinchHandler
            // and we don't yet distinguish mice and trackpads on Wayland either
            acceptedDevices: Qt.platform.pluginName === "cocoa" || Qt.platform.pluginName === "wayland"
                             ? PointerDevice.Mouse | PointerDevice.TouchPad
                             : PointerDevice.Mouse
            rotationScale: 1/120
            property: "zoomLevel"
        }
        DragHandler {
            id: drag
            target: null
            onTranslationChanged: (delta) => map.pan(-delta.x, -delta.y)
        }
        Shortcut {
            enabled: map.zoomLevel < map.maximumZoomLevel
            sequence: StandardKey.ZoomIn
            onActivated: map.zoomLevel = Math.round(map.zoomLevel + 1)
        }
        Shortcut {
            enabled: map.zoomLevel > map.minimumZoomLevel
            sequence: StandardKey.ZoomOut
            onActivated: map.zoomLevel = Math.round(map.zoomLevel - 1)
        }
    }
}

Dokumentation der Eigenschaften

activeMapType : mapType

Zugriff auf die derzeit aktive map type.

Diese Eigenschaft kann festgelegt werden, um das aktive „ map type “ zu ändern. Mögliche Werte finden Sie unter der Eigenschaft „ supportedMapTypes “.

Siehe auch „ mapType “.

bearing : real [since QtLocation 5.9]

Diese Eigenschaft enthält die Peilung für die Karte. Der Standardwert ist 0. Wenn das für die Karte verwendete Plugin Peilungen unterstützt, liegt der gültige Wertebereich zwischen 0 und 360. Wenn das für die Karte verwendete Plugin keine Peilungen unterstützt, hat eine Änderung dieser Eigenschaft keine Auswirkung.

Diese Eigenschaft wurde in QtLocation 5.9 eingeführt.

center : coordinate

Diese Eigenschaft enthält die Koordinaten, die den Mittelpunkt des Abbildungs-Ansichtsbereichs bilden. Ungültige Mittelpunktkoordinaten werden ignoriert.

Der Standardwert ist eine beliebige gültige Koordinate.

color : color

Diese Eigenschaft legt die Hintergrundfarbe des Kartenelements fest.

copyrightsVisible : bool

Diese Eigenschaft legt fest, ob der Copyright-Hinweis angezeigt wird. Der Hinweis wird in der Regel in der unteren linken Ecke angezeigt. Standardmäßig ist diese Eigenschaft auf „ true “ gesetzt.

error : enumeration [read-only]

Diese schreibgeschützte Eigenschaft enthält den zuletzt aufgetretenen Fehler des Mapping-Service-Anbieters.

• Map.NoError – Es ist kein Fehler aufgetreten.
• Map.NotSupportedError – Die Eigenschaft des Karten-Plugins wurde nicht festgelegt oder dem Plugin ist kein Mapping-Manager zugeordnet.
• Map.UnknownParameterError – Das Plugin hat einen der übergebenen Parameter nicht erkannt.
• Map.MissingRequiredParameterError – Das Plugin hat einen der erwarteten Parameter nicht gefunden.
• Map.ConnectionError – Das Plugin konnte keine Verbindung zu seinem Backend-Dienst oder seiner Datenbank herstellen.

Siehe auch QGeoServiceProvider::Error.

errorString : string [read-only]

Diese schreibgeschützte Eigenschaft enthält die textuelle Darstellung des letzten Fehlers des Mapping-Anbieters. Wenn kein Fehler aufgetreten ist, wird eine leere Zeichenkette zurückgegeben.

Eine leere Zeichenkette kann auch zurückgegeben werden, wenn ein Fehler aufgetreten ist, für den keine textuelle Darstellung vorhanden ist.

Siehe auch ` QGeoServiceProvider::errorString()`.

fieldOfView : real [since QtLocation 5.9]

Diese Eigenschaft gibt das Sichtfeld der Kamera an, mit der die Karte betrachtet wird, in Grad. Wenn die Plugin-Eigenschaft der Karte nicht festgelegt ist oder das Plugin keine Kartendarstellung unterstützt, beträgt der Wert 45 Grad.

Beachten Sie, dass eine Änderung dieses Werts implizit auch den Abstand zwischen der Kamera und der Karte verändert, sodass bei einem Neigungswinkel von 0 Grad das resultierende Bild für jeden für diese Eigenschaft verwendeten Wert identisch ist.

Weitere Informationen zu diesem Parameter finden Sie in den Wikipedia-Artikeln zu „Sichtfeld “ und „Blickwinkel“.

Diese Eigenschaft wurde in QtLocation 5.9 eingeführt.

Siehe auch minimumFieldOfView und maximumFieldOfView.

mapItems : list<MapItem> [read-only]

Gibt die Liste aller Map-Elemente in beliebiger Reihenfolge zurück. Zu diesen Elementen gehören sowohl statisch im Rahmen der Typdeklaration deklarierte Elemente als auch dynamische Elemente (addMapItem, MapItemView).

Siehe auch addMapItem, removeMapItem und clearMapItems.

mapReady : bool [read-only]

Diese Eigenschaft gibt an, ob die Karte erfolgreich initialisiert wurde und einsatzbereit ist. Einige Methoden, wie beispielsweise „ fromCoordinate “ und „ toCoordinate “, funktionieren erst, wenn die Karte einsatzbereit ist. Aufgrund der Architektur des „ Map “ wird empfohlen, anstelle von „ Component.onCompleted “ das für diese Eigenschaft ausgegebene Signal zu verwenden, um sicherzustellen, dass sich alles wie erwartet verhält.

maximumFieldOfView : real [since QtLocation 5.9]

Diese Eigenschaft gibt das maximale gültige Sichtfeld der Karte in Grad an.

Das vom verwendeten „ plugin “ angegebene minimale Neigungssichtfeld stellt eine Obergrenze für diese Eigenschaft dar. Wenn die Eigenschaft „ plugin “ nicht festgelegt ist oder das Plugin keine Kartierung unterstützt, ist diese Eigenschaft „ 179 “.

Diese Eigenschaft wurde in QtLocation 5.9 eingeführt.

Siehe auch „ fieldOfView “ und „ minimumFieldOfView “.

maximumTilt : real [since QtLocation 5.9]

Diese Eigenschaft gibt die maximal zulässige Neigung der Karte in Grad an.

Die vom verwendeten „ plugin “ definierte maximale Neigung stellt eine Obergrenze für diese Eigenschaft dar. Wenn die Eigenschaft „ plugin “ nicht festgelegt ist oder das Plugin keine Kartendarstellung unterstützt, ist diese Eigenschaft „ 89.5 “.

Seit „ QtLocation “ 5.12 können Plugins diesen Wert zusätzlich in Abhängigkeit von der aktuellen Zoomstufe einschränken.

Diese Eigenschaft wurde in QtLocation 5.9 eingeführt.

Siehe auch „ tilt “ und „ minimumTilt “.

maximumZoomLevel : real

Diese Eigenschaft gibt die höchste gültige Zoomstufe für die Karte an.

Die maximale Zoomstufe wird durch das verwendete „ plugin “ definiert. Wenn die Eigenschaft „ plugin “ nicht festgelegt ist oder das Plugin keine Kartendarstellung unterstützt, ist diese Eigenschaft „ 30 “.

minimumFieldOfView : real [since QtLocation 5.9]

Diese Eigenschaft gibt das kleinste gültige Sichtfeld der Karte in Grad an.

Das vom verwendeten „ plugin “ verwendete minimale Neigungssichtfeld stellt eine Untergrenze für diese Eigenschaft dar. Wenn die Eigenschaft „ plugin “ nicht festgelegt ist oder das Plugin keine Kartierung unterstützt, ist diese Eigenschaft „ 1 “.

Diese Eigenschaft wurde in QtLocation 5.9 eingeführt.

Siehe auch „ fieldOfView “ und „ maximumFieldOfView “.

minimumTilt : real [since QtLocation 5.9]

Diese Eigenschaft gibt die minimale gültige Neigung der Karte in Grad an.

Die vom verwendeten „ plugin “ definierte minimale Neigung stellt eine Untergrenze für diese Eigenschaft dar. Wenn die Eigenschaft „ plugin “ nicht festgelegt ist oder das Plugin keine Kartendarstellung unterstützt, ist diese Eigenschaft „ 0 “.

Seit „ QtLocation “ 5.12 können Plugins diesen Wert zusätzlich in Abhängigkeit von der aktuellen Zoomstufe einschränken.

Diese Eigenschaft wurde in QtLocation 5.9 eingeführt.

Siehe auch „ tilt “ und „ maximumTilt “.

minimumZoomLevel : real

Diese Eigenschaft gibt die niedrigste gültige Zoomstufe für die Karte an.

Die vom verwendeten „ plugin “ definierte Mindestzoomstufe stellt eine Untergrenze für diese Eigenschaft dar. Der zurückgegebene Wert ist jedoch auch von der Leinwandgröße abhängig und kann höher sein als der vom Benutzer angegebene Wert oder als die vom verwendeten Plugin definierte Mindestzoomstufe, um zu verhindern, dass die Karte in einer der beiden Dimensionen kleiner als der Darstellungsbereich ist.

Wenn die Eigenschaft „ plugin “ nicht festgelegt ist oder das Plugin keine Kartendarstellung unterstützt, ist diese Eigenschaft „ 0 “.

plugin : Plugin

Diese Eigenschaft enthält das Plugin, das die Zuordnungsfunktion bereitstellt.

Dies ist eine einmal beschreibbare Eigenschaft. Sobald der Karte ein Plugin zugeordnet ist, werden alle Versuche, das Plugin zu ändern, ignoriert.

supportedMapTypes : list<mapType> [read-only]

Diese schreibgeschützte Eigenschaft enthält die Menge der von dieser Karte unterstützten map types.

Siehe auch „ activeMapType “.

tilt : real [since QtLocation 5.9]

Diese Eigenschaft speichert die Neigung der Karte in Grad. Der Standardwert ist 0. Der gültige Wertebereich für diese Eigenschaft liegt zwischen [ minimumTilt und maximumTilt ]. Falls das für die Karte verwendete Plugin keine Neigungsfunktion unterstützt, hat eine Änderung dieser Eigenschaft keine Auswirkung.

Diese Eigenschaft wurde in QtLocation 5.9 eingeführt.

Siehe auch minimumTilt und maximumTilt.

visibleArea : rect

Diese Eigenschaft enthält den sichtbaren Bereich innerhalb des Map-QML-Elements. Es handelt sich um ein Rechteck, dessen Koordinaten relativ zum Map-Element sind. Seine Größe wird auf die Größe des Map-Elements begrenzt. Ein Wert von null für „visibleArea“ bedeutet, dass die gesamte Karte sichtbar ist.

visibleRegion : geoShape

Diese Eigenschaft enthält den Bereich, der den Ansichtsbereich der Karte einnimmt. Die Kamera ist in der Mitte der Form positioniert und auf die höchstmögliche ganzzahlige Zoomstufe eingestellt, bei der die gesamte Form auf dem Bildschirm sichtbar ist. Das bedeutet, dass beim Abrufen dieser Eigenschaft kurz nach ihrer Festlegung der zurückgegebene Bereich gleich groß oder größer ist als der festgelegte Bereich.

Das Setzen dieser Eigenschaft ändert implizit die Eigenschaften „ center “ und „ zoomLevel “ der Karte. Zuvor für diese Eigenschaften festgelegte Werte werden überschrieben.

zoomLevel : real

Diese Eigenschaft gibt die Zoomstufe der Karte an.

Größere Werte für die Zoomstufe bieten mehr Details. Zoomstufen sind immer nicht-negativ. Der Standardwert ist 8,0. Je nach verwendetem Plugin können Werte außerhalb des Bereichs [minimumZoomLevel, maximumZoomLevel], der den Bereich darstellt, für den Kacheln verfügbar sind, akzeptiert oder begrenzt werden.

Signal-Dokumentation

copyrightLinkActivated(string link)

Dieses Signal wird ausgelöst, wenn der Benutzer in dem Copyright-Hinweis auf einen link klickt. Die Anwendung sollte den Link in einem Browser öffnen oder dessen Inhalt dem Benutzer anzeigen.

Methodendokumentation

void addMapItem(MapItem item)

Fügt die angegebene URL „ item “ zur Karte hinzu (zum Beispiel MapQuickItem, MapCircle). Befindet sich das Objekt bereits auf der Karte, wird es nicht erneut hinzugefügt.

Betrachten Sie als Beispiel den Fall, in dem Sie eine „ MapCircle “ haben, die Ihre aktuelle Position angibt:

import QtQuick
import QtPositioning
import QtLocation

PositionSource {
    id: positionSource
}

Map {
    id: map
    property MapCircle circle

    Component.onCompleted: {
        circle = Qt.createQmlObject('import QtLocation; MapCircle {}', page)
        circle.center = positionSource.position.coordinate
        circle.radius = 5000.0
        circle.color = 'green'
        circle.border.width = 3
        map.addMapItem(circle)
    }
}

Siehe auch „ mapItems “, „ removeMapItem “ und „ clearMapItems “.

void addMapItemGroup(MapItemGroup itemGroup)

Fügt die in der angegebenen itemGroup enthaltenen Kartenelemente zur Karte hinzu (zum Beispiel MapQuickItem, MapCircle).

Siehe auch MapItemGroup und removeMapItemGroup.

void addMapItemView(MapItemView itemView)

Fügt itemView zur Karte hinzu.

Siehe auch MapItemView und removeMapItemView.

void alignCoordinateToPoint(coordinate coordinate, QPointF point)

Richtet „ coordinate “ auf „ point “ aus. Diese Methode erweitert die Funktionalität der QML-Eigenschaft „ center “ und ermöglicht es, eine Koordinate auf einen anderen Punkt des „Map“-Elements als dessen Mittelpunkt auszurichten. Dies ist in Anwendungen nützlich, in denen der Mittelpunkt der Szene (z. B. ein Cursor) nicht genau in der Mitte der Karte platziert werden soll.

Wenn die Karte geneigt ist und sich „ coordinate “ zufällig hinter der Kamera befindet oder wenn die Karte noch nicht bereit ist (siehe mapReady), hat der Aufruf dieser Methode keine Auswirkung.

Die Veröffentlichung dieser API mit Qt 5.10 ist eine Technology Preview.

Siehe auch center.

void clearData()

Löscht die vom aktuell ausgewählten Plugin gesammelten Kartendaten.

Siehe auch plugin.

void clearMapItems()

Entfernt alle Elemente und Elementgruppen aus der Karte.

Siehe auch mapItems, addMapItem, removeMapItem, addMapItemGroup und removeMapItemGroup.

void fitViewportToGeoShape(geoShape, margins)

Passt den Ansichtsbereich an eine bestimmte geometrische Form an geoShape. Die Werte für „ margins “ sind in Bildschirmpixeln angegeben.

Siehe auch visibleRegion.

void fitViewportToMapItems(list<MapItems> items = {})

Wird kein Argument angegeben, wird der aktuelle Ansichtsbereich an die Grenzen aller Kartenelemente angepasst. Die Kamera wird in der Mitte der Kartenelemente positioniert und auf die höchstmögliche ganzzahlige Zoomstufe eingestellt, bei der alle Kartenelemente auf dem Bildschirm sichtbar sind. Wird „ items “ angegeben, wird der aktuelle Ansichtsbereich ausschließlich an die Grenzen der angegebenen Kartenelemente angepasst.

Siehe auch fitViewportToVisibleMapItems.

void fitViewportToVisibleMapItems()

Passt den aktuellen Ansichtsbereich an die Grenzen aller sichtbaren Kartenelemente an. Die Kamera wird in der Mitte der Kartenelemente positioniert und auf die höchstmögliche ganzzahlige Zoomstufe eingestellt, bei der alle Kartenelemente auf dem Bildschirm sichtbar sind.

Siehe auch fitViewportToMapItems.

point fromCoordinate(coordinate coordinate, bool clipToViewPort)

Gibt die Position relativ zum Kartenelement zurück, die dem Parameter „ coordinate “ entspricht.

Wenn „ clipToViewPort “ den Wert „ true “ hat oder nicht angegeben wurde, wird ein ungültiger „ QPointF “ zurückgegeben, sofern „ coordinate “ nicht innerhalb des aktuellen Ansichtsbereichs liegt.

void pan(int dx, int dy)

Die Karte wird um dx Pixel entlang der x-Achse und um dy Pixel entlang der y-Achse verschoben.

Positive Werte für „ dx “ verschieben die Karte nach rechts, negative Werte nach links. Positive Werte für „ dy “ verschieben die Karte nach unten, negative Werte nach oben.

Während des Schwenkens können sich die Werte von ` center` und ` zoomLevel ` ändern.

void prefetchData()

Optionaler Hinweis, der es der Karte ermöglicht, während dieser Leerlaufphase Daten vorab abzurufen

void removeMapItem(MapItem item)

Entfernt das angegebene „ item “ aus der Map (z. B. MapQuickItem, MapCircle). Wenn das „MapItem“ nicht existiert oder zuvor nicht zur Map hinzugefügt wurde, führt die Methode keine Aktion aus.

Siehe auch „ mapItems “, „ addMapItem “ und „ clearMapItems “.

void removeMapItemGroup(MapItemGroup itemGroup)

Entfernt „ itemGroup “ und die darin enthaltenen Elemente aus der Karte.

Siehe auch „ MapItemGroup “ und „ addMapItemGroup “.

void removeMapItemView(MapItemView itemView)

Entfernt „ itemView “ und die von ihm instanziierten Elemente aus dem Map.

Siehe auch „ MapItemView “ und „ addMapItemView “.

void setBearing(real bearing, coordinate coordinate)

Legt die Ausrichtung der Karte auf „ bearing “ fest und dreht sie um „ coordinate “. Wenn das für die Karte verwendete Plugin die Ausrichtung unterstützt, liegt der gültige Bereich für „ bearing “ zwischen 0 und 360. Wenn das für die Karte verwendete Plugin die Peilung nicht unterstützt, wenn die Karte geneigt ist und sich „ coordinate “ zufällig hinter der Kamera befindet oder wenn die Karte noch nicht bereit ist (siehe mapReady), hat der Aufruf dieser Methode keine Wirkung.

Die Veröffentlichung dieser API mit Qt 5.10 ist eine Technology Preview.

coordinate toCoordinate(QPointF position, bool clipToViewPort)

Gibt die Koordinate zurück, die dem „ position “ relativ zum Kartenelement entspricht.

Wenn „ clipToViewPort “ den Wert „ true “ hat oder nicht angegeben ist, wird eine ungültige Koordinate zurückgegeben, sofern „ position “ nicht innerhalb des aktuellen Ansichtsbereichs liegt.