Application QML Type (Singleton)

Bietet Zugriff auf globale Eigenschaften des Anwendungszustands, die von vielen QML-Komponenten gemeinsam genutzt werden. Mehr...

Hinweis: Dieser Typ ist ein QML-Singleton. Es gibt nur eine Instanz dieses Typs in der QML-Engine.

• Liste aller Mitglieder, einschließlich geerbter Mitglieder
• Veraltete Mitglieder

Eigenschaften

• arguments : list<string>
• displayName : string
• domain : string
• font : font
• layoutDirection : enumeration
• name : string
• organization : string
• screens : list<Screen>
• state : enumeration
• styleHints : StyleHints
• supportsMultipleWindows : bool
• version : string

Signale

• aboutToQuit()

Ausführliche Beschreibung

Das Application-Singleton stellt QML-Anwendungen eine Teilmenge der Eigenschaften von „ QApplication “ zur Verfügung.

Außerdem stellt es das Signal „ aboutToQuit()“ bereit, das dem Signal „ QCoreApplication::aboutToQuit()“ entspricht.

import QtQuick

Window {
    id: root
    visible: true
    width: 800
    height: 680

    title: `${Application.name} (${Application.version})`

    Connections {
        target: Application
        function onAboutToQuit() {
            console.log("Bye!")
        }
    }
}

Siehe auch „ SystemPalette “.

Dokumentation zu den Eigenschaften

arguments : list<string>

Dies ist eine Liste von Zeichenfolgen, die die Argumente enthält, mit denen die ausführbare Datei aufgerufen wurde.

displayName : string

Diese Eigenschaft gibt den für die Instanz von „ QGuiApplication “ festgelegten Anzeigenamen der Anwendung an. Diese Eigenschaft kann beschrieben werden, um den Anzeigenamen der Anwendung festzulegen.

Binding {
    target: Application
    property: "displayName"
    value: "My Awesome Application"
}

domain : string

Dies ist die Organisationsdomäne, die für die Instanz „ QCoreApplication “ festgelegt wurde. Diese Eigenschaft kann beschrieben werden, um die Organisationsdomäne festzulegen.

font : font [read-only]

Gibt die Standardschriftart der Anwendung zurück, wie sie von der Funktion „ QGuiApplication::font()“ zurückgegeben wird.

layoutDirection : enumeration [read-only]

Diese schreibgeschützte Eigenschaft kann verwendet werden, um die Standard-Layout-Richtung der Anwendung abzufragen. Beim Systemstart hängt die Standard-Layout-Richtung von der Sprache der Anwendung ab. Die Eigenschaft hat den Wert „ Qt.RightToLeft “ in Sprachumgebungen, in denen Text und grafische Elemente von rechts nach links gelesen werden, und den Wert „ Qt.LeftToRight “, wenn die Leserichtung von links nach rechts verläuft. Sie können eine Bindung an diese Eigenschaft herstellen, um die Layouts Ihrer Anwendung so anzupassen, dass beide Layoutrichtungen unterstützt werden.

Mögliche Werte finden Sie in der C++-Enumeration ` Qt::LayoutDirection `.

RowLayout {
    layoutDirection: Application.layoutDirection
}

name : string

Dies ist der Anwendungsname, der für die Instanz „ QCoreApplication “ festgelegt wurde. Diese Eigenschaft kann beschrieben werden, um den Anwendungsnamen festzulegen.

organization : string

Dies ist der Name der Organisation, der in der Instanz „ QCoreApplication “ festgelegt ist. Diese Eigenschaft kann beschrieben werden, um den Namen der Organisation festzulegen.

screens : list<Screen> [read-only]

Ein Array, das die Beschreibungen aller verbundenen Bildschirme enthält. Die Elemente des Arrays sind Objekte mit denselben Eigenschaften wie das an „ Screen “ angehängte Objekt. In der Praxis entspricht das Array der Bildschirmliste, die von „ QGuiApplication::screens()“ zurückgegeben wird. Neben der Überprüfung von Eigenschaften wie Name, Breite, Höhe usw. können die Array-Elemente auch der Eigenschaft „screen“ von „Window“-Elementen zugewiesen werden und dienen somit als Alternative zur C++-Funktion „ QWindow::setScreen()“.

Siehe auch „ Screen “, „ Window “ und „ Window.screen “.

state : enumeration [read-only]

Diese Eigenschaft gibt den aktuellen Zustand der Anwendung wieder.

Mögliche Werte finden Sie in der C++-Enumeration „ Qt::ApplicationState “.

Timer {
    interval: 1000; repeat: true
    active: Application.state === Qt.ApplicationActive
    onTriggered: imageFetcher.fetchLatestImages()
}

styleHints : StyleHints [read-only]

Die Eigenschaft „ styleHints “ stellt plattformspezifische Stilhinweise und Einstellungen bereit. Weitere Informationen finden Sie in der Dokumentation zu „ QStyleHints “.

Im folgenden Beispiel wird mithilfe von „ styleHints “ festgelegt, ob ein Element beim Klicken mit der Maus oder beim Loslassen der Berührung den Fokus erhalten soll:

import QtQuick

MouseArea {
    id: button

    onPressed: {
        if (!Application.styleHints.setFocusOnTouchRelease)
            button.forceActiveFocus()
    }
    onReleased: {
        if (Application.styleHints.setFocusOnTouchRelease)
            button.forceActiveFocus()
    }
}

supportsMultipleWindows : bool [read-only]

Gibt „ true “ zurück, wenn die Plattform mehrere Fenster unterstützt. Einige Embedded-Plattformen unterstützen beispielsweise keine mehreren Fenster.

version : string

Dies ist die auf der Instanz „ QCoreApplication “ festgelegte Anwendungsversion. Diese Eigenschaft kann beschrieben werden, um die Anwendungsversion festzulegen.

Signal-Dokumentation

aboutToQuit()

Dieses Signal wird ausgesendet, wenn die Anwendung im Begriff ist, die Haupt-Ereignisschleife zu verlassen. Das Signal ist besonders nützlich, wenn Ihre Anwendung in letzter Sekunde noch Aufräumarbeiten durchführen muss. In diesem Zustand ist keine Benutzerinteraktion möglich. Weitere Informationen finden Sie unter Window.closing.

Siehe auch QCoreApplication::aboutToQuit.