Back to Qt.io
Contact Us Blog Download Qt

FileDialog QML Type

Ein Dateidialog. Mehr...

Import Statement: import QtQuick.Dialogs
Since: Qt 6.2
Inherits:

Dialog

Eigenschaften

Detaillierte Beschreibung

Der Typ FileDialog bietet eine QML-API für Dateidialoge.

Um einen Dateidialog anzuzeigen, konstruieren Sie eine Instanz von FileDialog, setzen die gewünschten Eigenschaften und rufen open() auf. Die Eigenschaft currentFolder kann verwendet werden, um den Ordner zu bestimmen, in dem der Dialog geöffnet wird. Die Eigenschaften selectedFile und selectedFiles können verwendet werden, um zu bestimmen, welche Datei(en) ausgewählt werden, wenn der Dialog geöffnet wird, und werden auch aktualisiert, wenn der Benutzer eine Datei im Dialog auswählt und wenn der Dialog akzeptiert wird.

import QtCore
import QtQuick
import QtQuick.Controls
import QtQuick.Dialogs

ApplicationWindow {
    width: 640
    height: 480
    visible: true

    header: ToolBar {
        Button {
            text: qsTr("Choose Image...")
            onClicked: fileDialog.open()
        }
    }

    Image {
        id: image
        anchors.fill: parent
        fillMode: Image.PreserveAspectFit
    }

    FileDialog {
        id: fileDialog
        currentFolder: StandardPaths.standardLocations(StandardPaths.PicturesLocation)[0]
        onAccepted: image.source = selectedFile
    }
}

Verfügbarkeit

Ein plattformeigener Dateidialog ist derzeit auf den folgenden Plattformen verfügbar:

  • Android
  • iOS
  • Linux (wenn mit dem GTK+-Plattformthema ausgeführt)
  • macOS
  • Windows

Qt Quick Dialogs verwendet eine Qt Quick -Implementierung als Fallback auf Plattformen, für die keine native Implementierung verfügbar ist.

Siehe auch FolderDialog und StandardPaths.

Eigenschaft Dokumentation

acceptLabel : string

Diese Eigenschaft enthält den Beschriftungstext, der auf der Schaltfläche angezeigt wird, die den Dialog akzeptiert.

Wenn sie auf eine leere Zeichenfolge gesetzt ist, wird die Standardbeschriftung der zugrunde liegenden Plattform verwendet. Die Standardbeschriftung ist in der Regel Open oder Save, je nachdem, in welchem fileMode das Dialogfeld verwendet wird.

Der Standardwert ist eine leere Zeichenkette.

Siehe auch rejectLabel.


currentFolder : url

Diese Eigenschaft enthält den Ordner, in dem die Dateien ausgewählt werden. Sie kann eingestellt werden, um das Anfangsverzeichnis zu steuern, das beim Öffnen des Dialogs angezeigt wird.

Für die Auswahl eines Ordners verwenden Sie stattdessen FolderDialog.


defaultSuffix : string

Diese Eigenschaft enthält ein Suffix, das den ausgewählten Dateien hinzugefügt wird, für die kein Suffix angegeben wurde. Das Suffix wird normalerweise verwendet, um den Dateityp anzugeben (z. B. "txt" steht für eine Textdatei).

Wenn das erste Zeichen ein Punkt ('.') ist, wird er entfernt.


fileMode : enumeration

Diese Eigenschaft enthält den Modus des Dialogs.

Verfügbare Werte:

KonstanteBeschreibung
FileDialog.OpenFileDas Dialogfeld wird verwendet, um eine vorhandene Datei auszuwählen (Standard).
FileDialog.OpenFilesDas Dialogfeld wird verwendet, um mehrere vorhandene Dateien auszuwählen.
FileDialog.SaveFileDer Dialog wird verwendet, um eine beliebige Datei auszuwählen. Die Datei muss nicht existieren.

nameFilters : list<string>

Diese Eigenschaft enthält die Filter, die die Arten von Dateien einschränken, die ausgewählt werden können.

FileDialog {
    nameFilters: ["Text files (*.txt)", "HTML files (*.html *.htm)"]
}

Verschiedene Plattformen können die auswählbaren Dateien auf unterschiedliche Weise einschränken. Unter macOS werden beispielsweise Dateieinträge deaktiviert, die nicht mit den Filtern übereinstimmen, während sie unter Windows ausgeblendet werden.

Hinweis: *.* ist kein portabler Filter, da die historische Annahme, dass die Dateierweiterung den Dateityp bestimmt, nicht auf allen Betriebssystemen gleich ist. Es ist möglich, eine Datei ohne Punkt in ihrem Namen zu haben (z. B. Makefile). In einem Windows-eigenen Dateidialog wird *.* mit solchen Dateien übereinstimmen, während dies in anderen Dateidialogen möglicherweise nicht der Fall ist. Es ist also besser, * zu verwenden, wenn Sie eine beliebige Datei auswählen wollen.

Siehe auch selectedNameFilter.


options : flags

Diese Eigenschaft enthält die verschiedenen Optionen, die das Aussehen des Dialogs beeinflussen.

Standardmäßig sind alle Optionen deaktiviert.

Die Optionen sollten eingestellt werden, bevor das Dialogfeld angezeigt wird. Wenn sie gesetzt werden, während das Dialogfeld sichtbar ist, ist nicht garantiert, dass sie eine unmittelbare Auswirkung auf das Dialogfeld haben (abhängig von der Option und der Plattform).

Verfügbare Optionen:

KonstantBeschreibung
FileDialog.DontResolveSymlinksSymlinks im Dateidialog nicht auflösen. Standardmäßig werden Symlinks aufgelöst.
FileDialog.DontConfirmOverwriteNicht nach einer Bestätigung fragen, wenn eine vorhandene Datei ausgewählt wird. Standardmäßig wird eine Bestätigung angefordert.
FileDialog.ReadOnlyZeigt an, dass der Dialog das Erstellen von Verzeichnissen nicht zulässt.
FileDialog.HideNameFilterDetailsGibt an, ob die Details des Filters für den Dateinamen verborgen sind oder nicht.
FileDialog.DontUseNativeDialogErzwingt, dass der Dialog eine nicht-native Quick-Implementierung verwendet.

rejectLabel : string

Diese Eigenschaft enthält den Beschriftungstext, der auf der Schaltfläche angezeigt wird, die den Dialog ablehnt.

Wenn sie auf eine leere Zeichenfolge gesetzt ist, wird die Standardbeschriftung der zugrunde liegenden Plattform verwendet. Die Standardbeschriftung ist normalerweise Cancel.

Der Standardwert ist eine leere Zeichenkette.

Siehe auch acceptLabel.


selectedFile : url

Diese Eigenschaft enthält die zuletzt im Dialog ausgewählte Datei.

Sie kann festgelegt werden, um die Datei zu steuern, die ausgewählt wird, wenn das Dialogfeld geöffnet wird.

Wenn es mehrere ausgewählte Dateien gibt, bezieht sich diese Eigenschaft auf die erste Datei.

Der Wert dieser Eigenschaft wird jedes Mal aktualisiert, wenn der Benutzer eine Datei im Dialogfeld auswählt, und wenn das Dialogfeld akzeptiert wird. Verarbeiten Sie das Signal accepted(), um die endgültige Auswahl zu erhalten.

Siehe auch selectedFiles, accepted(), und currentFolder.


selectedFiles : list<url>

Diese Eigenschaft enthält die zuletzt im Dialog ausgewählten Dateien.

Der Wert dieser Eigenschaft wird jedes Mal aktualisiert, wenn der Benutzer Dateien im Dialogfeld auswählt, und wenn das Dialogfeld akzeptiert wird. Behandeln Sie das Signal accepted(), um die endgültige Auswahl zu erhalten.

Siehe auch accepted() und currentFolder.


selectedNameFilter group

selectedNameFilter.extensions : list<string>

selectedNameFilter.globs : list<string>

selectedNameFilter.index : int

selectedNameFilter.name : string

Diese Eigenschaften enthalten den aktuell ausgewählten Namensfilter.

NameBeschreibung
index: intDiese Eigenschaft bestimmt, welcher name filter ausgewählt ist. Der angegebene Filter wird ausgewählt, wenn der Dialog geöffnet wird. Der Wert wird aktualisiert, wenn der Benutzer einen anderen Filter auswählt.
[Nur-Lesezugriff] name: stringDiese Eigenschaft enthält den Namen des ausgewählten Filters. Im folgenden Beispiel lautet der Name des ersten Filters "Text files" und der des zweiten "HTML files".
[schreibgeschützt] extensions: list<string>Diese Eigenschaft enthält die Liste der Erweiterungen des ausgewählten Filters. Im folgenden Beispiel lautet die Liste der Erweiterungen des ersten Filters ["txt"] und die des zweiten ["html", "htm"].
[nur Lesezugriff] globs: list<string>Diese Eigenschaft enthält die Liste der Globs des ausgewählten Filters. Im folgenden Beispiel lautet die Liste der Globs des ersten Filters ["*.txt"] und die des zweiten ["*.html", "*.htm"].

Diese Eigenschaft ist z. B. in Verbindung mit der Eigenschaft nameFilters von FolderListModel nützlich.

FileDialog {
    id: fileDialog
    selectedNameFilter.index: 1
    nameFilters: ["Text files (*.txt)", "HTML files (*.html *.htm)"]
}

MyDocument {
    id: document
    fileType: fileDialog.selectedNameFilter.extensions[0]
}

Siehe auch nameFilters.


© 2025 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.