Inkompatibler Typ

Diese Warnungskategorie wird von qmllint als „ [incompatible-type] “ bezeichnet.

Zuweisung an Standard-Eigenschaft eines inkompatiblen Typs nicht möglich

Was ist passiert?

Sie haben ein Objekt einer Standard-Eigenschaft eines inkompatiblen Typs zugewiesen.

Warum ist das ein Problem?

Die QML-Engine kann das Objekt zur Laufzeit nicht zuweisen.

Beispiel

import QtQuick

Item {
    component MyType: QtObject {
        default property list<Item> myDefaultProperty
    }

    MyType {
        QtObject {} // note: QtObject does not inherit from Item
    }
}

Um diese Warnung zu beheben, binden Sie einen kompatiblen Typ an die Eigenschaft oder ändern Sie, falls Sie der Autor der Standard-Eigenschaft sind, den Typ in der Definition:

import QtQuick

Item {
    component MyType: QtObject {
        default property list<Item> myDefaultProperty
    }

    MyType {
        Item {}
    }

    component AlternativeMyType: QtObject {
        default property list<QtObject> myDefaultProperty
    }

    AlternativeMyType {
        QtObject {} // is ok for AlternativeMyType
    }
}

Die On-Binding-Funktion für die Eigenschaft hat einen falschen Typ

Was ist passiert?

Sie haben einen ungültigen Eigenschaftsmodifikator-Typ verwendet.

Warum ist das ein Problem?

Die QML-Engine kann den Eigenschaftsmodifikator-Typ zur Laufzeit nicht verwenden.

Beispiel

import QtQuick

Item {
    property int xxx
    Item on xxx { ... }
}

Um diese Warnung zu beheben, entfernen Sie den „ on “ oder verwenden Sie einen gültigen Eigenschaftsmodifikator-Typ:

import QtQuick

Item {
    property int xxx
    Item { ... }

    // Alternative: use a valid property modifier type
    NumberAnimation on xxx { ... }
}

Die Konstruktion aus einer Zeichenkette ist veraltet; verwende stattdessen die Konstruktion mit strukturierten Werttypen

Was ist passiert?

Sie haben eine „ QML_STRUCTURED_VALUE “ mithilfe einer Zeichenkette erstellt.

Warum ist das schlecht?

Dies ist veraltet und anfällig für Tippfehler.

Beispiel

import QtQuick

Item {
    property point p: "5, 6"
}

Um diese Warnung zu beheben, füllen Sie den strukturierten Werttyp wie in der Beschreibung von „ QML_STRUCTURED_VALUE “ erläutert aus, anstatt eine Zeichenfolge an die Eigenschaft zu binden:

import QtQuick

Item {
    property point p: ({ x: 5, y: 6 })
}

Funktion ohne Angabe des Rückgabetyps gibt einen Wert zurück

Was ist passiert?

Sie haben einen Wert aus einer Funktion ohne Angabe des Rückgabetyps zurückgegeben.

Warum ist das problematisch?

Sie haben die Funktion so gekennzeichnet, dass sie nichts zurückgibt, daher sollte die Funktion auch nichts zurückgeben. Die QML-Tools können die Methode nicht verarbeiten, und die QML-Engine wird den zurückgegebenen Wert in einer zukünftigen Qt-Version ignorieren.

Beispiel

import QtQuick

Item {
    function f(x: int) {
        ...
        return x
    }
}

Um diese Warnung zu beheben, passen Sie die Funktionssignatur an den neuen Rückgabetyp an oder entfernen Sie den Rückgabewert:

import QtQuick

Item {
    function f(x: int): int {
        ...
        return x
    }
    function alternativeF(x: int) {
        ...
        return
    }
}

Bindung/Objekt/Literal kann nicht zugewiesen werden

Was ist passiert?

Sie haben ein Objekt, ein Literal oder einen Ausdruck an eine Eigenschaft eines inkompatiblen Typs gebunden.

Warum ist das ein Problem?

Die QML-Engine kann das Objekt, den Literal oder den Ausdruck zur Laufzeit nicht zuweisen.

Beispiel

import QtQuick

Item {
    property date xxx: 42
}

Um diese Warnung zu beheben, binden Sie ein Objekt, einen Wert oder einen Ausdruck eines kompatiblen Typs:

import QtQuick

Item {
    property date xxx: new Date()
}