TreeModel QML Type
Encapsula un modelo de árbol sencillo. Más...
| Import Statement: | import Qt.labs.qmlmodels |
| Since: | Qt 6.10 |
Propiedades
- columnCount : int
- rows : var
Métodos
- void appendRow(var treeRow)
- void appendRow(parent, var treeRow)
- void clear()
- variant data(index, string role)
- var getRow(rowIndex)
- QModelIndex index(list<int> treeIndex, int column)
- QModelIndex index(int row, int column, var parent)
- void insertRow(int rowIndex, object row)
(since 6.12) - void insertRow(int rowIndex, QModelIndex parent, object row)
(since 6.12) - bool moveRows(QModelIndex sourceParent, int sourceRow, int count, QModelIndex destinationParent, int destinationChild)
(since 6.12) - void removeRow(rowIndex)
- bool setData(index, variant value, string role)
- void setRow(rowIndex, var treeRow)
Descripción detallada
El tipo TreeModel almacena objetos JavaScript/JSON como datos para un modelo de árbol que se puede utilizar con TreeView. Está pensado para admitir modelos muy sencillos sin necesidad de crear una subclase personalizada de QAbstractItemModel en C++.
import QtQuick
import QtQuick.Controls
import Qt.labs.qmlmodels
ApplicationWindow {
visible: true
width: 500
height: 500
TreeView {
id: treeView
anchors.fill: parent
selectionModel: ItemSelectionModel {}
model: TreeModel {
id: treeModel
TableModelColumn {
display: "checked"
}
TableModelColumn {
display: "size"
}
TableModelColumn {
display: "type"
}
TableModelColumn {
display: "name"
}
TableModelColumn {
display: "lastModified"
}
rows: [{
checked: false,
size: "—",
type: "folder",
name: "Documents",
lastModified: "2025-07-01",
rows: [{
checked: true,
size: "24 KB",
type: "file",
name: "Resume.pdf",
lastModified: "2025-06-20",
}, {
checked: false,
size: "2 MB",
type: "folder",
name: "Reports",
lastModified: "2025-06-10",
rows: [{
checked: true,
size: "850 KB",
type: "file",
name: "Q2_Report.docx",
lastModified: "2025-06-15",
}, {
checked: false,
size: "1.2 MB",
type: "file",
name: "Q3_Plan.xlsx",
lastModified: "2025-06-18",
}]
}]
},
{
checked: false,
size: "—",
type: "folder",
name: "Pictures",
lastModified: "2025-05-30",
rows: [{
checked: true,
size: "3.5 MB",
type: "file",
name: "Vacation.jpg",
lastModified: "2025-05-15",
}, {
checked: false,
size: "2.1 MB",
type: "file",
name: "Family.png",
lastModified: "2025-05-20",
}]
}
]
}
delegate: TreeViewDelegate {}
}
}Los datos iniciales del modelo se establecen mediante la propiedad « rows » o llamando a « appendRow()». Cada columna del modelo se especifica declarando una instancia de « TableModelColumn », donde el orden de cada instancia determina su índice de columna. Una vez que se ha emitido la señal « Component::completed()» del modelo, las columnas y los roles quedarán establecidos y serán fijos durante toda la vida útil del modelo.
Estructuras de datos de filas compatibles
Cada fila representa un nodo del árbol. Cada nodo tiene el mismo tipo de columnas. El TreeModel está diseñado para trabajar con datos JavaScript/JSON, por lo que cada fila es una lista de pares clave-valor simples:
{
checked: false,
size: "—",
type: "folder",
name: "Pictures",
lastModified: "2025-05-30",
rows: [{
checked: true,
size: "3.5 MB",
type: "file",
name: "Vacation.jpg",
lastModified: "2025-05-15",
}, {
checked: false,
size: "2.1 MB",
type: "file",
name: "Family.png",
lastModified: "2025-05-20",
}]
}Un nodo puede tener nodos hijos, que se almacenarán en un array asociado a la clave «rows». «rows» está reservada para este fin: solo la lista de nodos hijos debe estar asociada a esta clave.
El modelo se manipula mediante QModelIndices. Para acceder a una fila o nodo específico, se puede utilizar la función getRow(). También es posible acceder directamente a los datos JavaScript del modelo a través de la propiedad rows, pero no es posible modificar los datos del modelo de esta manera.
Para añadir nuevas filas, utiliza appendRow(). Para modificar filas existentes, utiliza setRow(), removeRow() y clear().
Uso de TreeModel con fuentes JSON externas
Aunque el uso previsto de TreeModel es definir los datos JSON directamente en el archivo QML, puedes utilizar cualquier objeto JSON con el modelo siempre que su estructura coincida con la definida por TreeModel. Si todas las filas del objeto JSON se ajustan a las columnas definidas por el modelo, puedes asignarlo directamente a través de la propiedad `rows`.
La fuente del objeto JSON puede ser un archivo. Por ejemplo, si el modelo se define como
TreeModel {
id: treeModel
objectName: "testModel"
TableModelColumn { display: "checked" }
TableModelColumn { display: "size" }
TableModelColumn { display: "type" }
TableModelColumn { display: "name" }
TableModelColumn { display: "lastModified" }
}y el objeto JSON almacenado en el archivo tiene el siguiente aspecto
let folders = [
{
"checked": false,
"size": "—",
"type": "folder",
"name": "Documents",
"lastModified": "2025-07-01",
"rows": [
{
"checked": true,
"size": "24 KB",
"type": "file",
"name": "Resume.pdf",
"lastModified": "2025-06-20"
}
]
},
{
"checked": false,
"size": "—",
"type": "folder",
"name": "Pictures",
"lastModified": "2025-05-30",
"rows": [
{
"checked": true,
"size": "3.5 MB",
"type": "file",
"name": "Vacation.jpg",
"lastModified": "2025-05-15"
}
]
}
]entonces este objeto se puede proporcionar importando el archivo JavaScript como un
módulo
import "TreeData.js" as JsonDatay, a continuación, se puede asignar directamente
Component.onCompleted: treeView.model.rows = JsonData.foldersAdvertencia: Asegúrate de que los datos JSON procedan de una fuente fiable. Dado que el modelo rellena dinámicamente sus filas en función de la entrada, un JSON mal formado o no fiable puede provocar un comportamiento inesperado o problemas de rendimiento.
Consulte TableModel para ver otro ejemplo en el que un objeto JSON se analiza y se asigna como una matriz de JavaScript.
Véase también TableModelColumn y TreeView.
Documentación sobre propiedades
columnCount : int [read-only]
Esta propiedad de solo lectura contiene el número de columnas del modelo.
El número de columnas queda fijado durante toda la vida útil del modelo una vez que se ha establecido la propiedad « rows » o se ha llamado a « appendRow()» por primera vez.
rows : var
Esta propiedad almacena los datos del modelo en forma de una matriz de filas.
Véase también getRow(), setRow(), appendRow(), clear() y columnCount.
Documentación del método
void appendRow(var treeRow)
Añade « treeRow » al nodo raíz.
Véase también setRow() y removeRow().
void appendRow(parent, var treeRow)
Añade una nueva fila de árbol (treeRow) a parent, con los valores (celdas) de treeRow.
treeModel.appendRow(index, {
checked: false,
size: "-",
type: "folder",
name: "Orders",
lastModified: "2025-07-02",
rows: [
{
checked: true,
size: "38 KB",
type: "file",
name: "monitors.xlsx",
lastModified: "2025-07-02"
},
{
checked: true,
size: "54 KB",
type: "file",
name: "notebooks.xlsx",
lastModified: "2025-07-02"
}
]
});parent Es un tipo QML anónimo respaldado por ` QModelIndex`. Si ` parent ` no es válido, se añade ` treeRow ` al nodo raíz.
Véase también setRow() y removeRow().
void clear()
Elimina todas las filas del modelo.
Véase también removeRow().
variant data(index, string role)
Devuelve los datos de la « TreeModel » en la « index » indicada, que pertenece a la « role » indicada.
index Es un tipo QML anónimo respaldado por QModelIndex.
Véase también index() y setData().
var getRow(rowIndex)
Devuelve el `treeRow` del índice especificado en el modelo. ` rowIndex ` es un tipo QML anónimo basado en ` QModelIndex`.
Nota: el objeto devuelto no se puede utilizar para modificar el contenido del modelo; en su lugar, utilice setTreeRow().
Véase también setRow(), appendRow() y removeRow().
QModelIndex index(list<int> treeIndex, int column)
Devuelve un objeto que hace referencia a los elementos treeIndex y column especificados, que pueden pasarse a la función data() para obtener los datos de esa celda, o a setData() para editar el contenido de esa celda.
El objeto devuelto es de un tipo QML anónimo respaldado por QModelIndex.
El primer parámetro, treeIndex, representa una ruta de números de fila que va desde la raíz hasta la fila deseada y se utiliza para navegar por el árbol. Esto se explica mejor con un ejemplo.
|
Con esta sobrecarga es posible obtener un « QModelIndex » de un nodo sin disponer de un « QModelIndex » de su nodo padre.
Si no se encuentra ningún nodo en la lista especificada, se devuelve un índice de modelo no válido. Ten en cuenta que un índice de modelo no válido hace referencia a la raíz del nodo.
Véase también QModelIndex y las clases relacionadas en QML, así como data().
QModelIndex index(int row, int column, var parent)
Devuelve un objeto que hace referencia a los campos « row » y « column » de una celda « parent » determinada, el cual puede pasarse a la función « data()» para obtener los datos de dicha celda, o a « setData()» para editar el contenido de dicha celda.
El objeto devuelto es de un tipo QML anónimo respaldado por QModelIndex.
Véase también QModelIndex y las clases relacionadas en QML, así como data().
[since 6.12] void insertRow(int rowIndex, object row)
Inserta una nueva fila en el elemento raíz en la posición rowIndex, con los valores (celdas) de row.
Este método se introdujo en Qt 6.12.
Véase también appendRow(), setRow() y removeRow().
[since 6.12] void insertRow(int rowIndex, QModelIndex parent, object row)
Inserta una nueva fila en el objeto ` parent ` en la posición ` rowIndex`, con los valores (celdas) de ` row`.
model.insertRow(2, parentIndex, {
checkable: true, checked: false,
amount: 1,
fruitType: "Pear",
fruitName: "Williams",
fruitPrice: 1.50,
})Este método se introdujo en Qt 6.12.
Véase también appendRow(), setRow() y removeRow().
[since 6.12] bool moveRows(QModelIndex sourceParent, int sourceRow, int count, QModelIndex destinationParent, int destinationChild)
Mueve las filas count, que comienzan en sourceRow, desde sourceParent a destinationParent, insertándolas antes de destinationChild.
El destinationChild hace referencia a la posición en el destinationParent antes del traslado (índice previo al traslado), de acuerdo con QAbstractItemModel::beginMoveRows().
Los rangos de origen y destino deben existir, y sourceParent y destinationParent no deben solaparse de tal forma que un elemento padre se mueva por debajo de su propio elemento hijo.
Devuelve true si las filas se han movido correctamente; en caso contrario, devuelve false.
Este método se introdujo en Qt 6.12.
Véase también appendRow(), insertRow() y removeRow().
void removeRow(rowIndex)
Elimina del modelo el TreeRow al que hace referencia rowIndex. rowIndex es un tipo QML anónimo respaldado por QModelIndex.
treeModel.removeTreeRow(rowIndex)Véase también clear().
bool setData(index, variant value, string role)
Inserta o actualiza el campo de datos indicado en role en el TreeRow, en la posición especificada index con value. Devuelve «true» si se realiza correctamente; «false» en caso contrario.
index Es un tipo QML anónimo respaldado por ` QModelIndex`.
Véase también data() y index().
void setRow(rowIndex, var treeRow)
Sustituye el TreeRow de rowIndex en el modelo por treeRow. rowIndex es un tipo QML anónimo respaldado por QModelIndex.
Se rechazará cualquier fila que contenga filas secundarias.
Todas las columnas y celdas deben estar presentes en treeRow, y en el orden correcto. Las filas secundarias de la fila no se ven afectadas.
treeModel.setRow(rowIndex, {
checked: true,
size: "-",
type: "folder",
name: "Subtitles",
lastModified: "2025-07-07",
iconColor: "blue"
});Véase también appendRow().
© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.