En esta página

IndicatorStyle QML Type

Define el estilo del indicador de un control. Más información...

Import Statement: import Qt.labs.StyleKit
Inherits:

DelegateStyle

Status: Technology preview

Este tipo se encuentra en fase de vista previa tecnológica y está sujeto a cambios.

Propiedades

Descripción detallada

IndicatorStyle amplía DelegateStyle con propiedades específicas para el diseño de un indicador.

El propio IndicatorStyle describe el fondo del indicador, mientras que el foreground describe el contenido que se dibuja en su interior. Por ejemplo, checkBox.indicator aplica estilos al marco de la casilla de selección y checkBox.indicator.foreground aplica estilos a la marca de selección. En el caso de switchControl, slider y progressBar, el indicador aplica estilos a la ranura y el primer plano aplica estilos al relleno.

checkBox {
    background.visible: false
    text.alignment: Qt.AlignVCenter | Qt.AlignLeft
    indicator {
        color: "transparent"
        border.width: 1
        foreground {
            color: "transparent"
            image.source: "qrc:/qt-project.org/imports/QtQuick/Controls/Basic/images/check.png"
            // Hide the checkMark when the CheckBox is unchecked
            visible: false
        }
    }
    checked {
        // Show the checkMark when the CheckBox is checked
        indicator.foreground.visible: true
    }
}

Algunos controles tienen más de un indicador. Por ejemplo, SpinBox tiene un botón de incremento y otro de decremento. Se puede aplicar un estilo a cada uno de forma independiente utilizando los subindicadores first y second, spinBox.indicator.first y spinBox.indicator.second. Para SpinBox, indicator.first aplica el estilo al botón de incremento, y indicator.second al botón de decremento. Las propiedades que no se definan en un subindicador se aplican al propio indicador.

Nota: Las propiedades up y down se mantienen como alias de first y second por motivos de compatibilidad con versiones anteriores. El código nuevo debería utilizar first y second, ya que estos nombres son genéricos y pueden ser utilizados por controles con subindicadores que no representen acciones de subir/bajar. Los alias de compatibilidad podrían eliminarse en una versión futura.

spinBox {
    text.alignment: Qt.AlignHCenter | Qt.AlignVCenter
    padding: 0
    indicator {
        fillHeight: true
        color: "navy"
        opacity: 0.1
        foreground {
            color: "transparent"
            margins: 10
            image.color: "navy"
            image.fillMode: Image.PreserveAspectFit
            image.source: "qrc:/qt-project.org/imports/QtQuick/Controls/Basic/images/arrow-indicator.png"
            width: 10
            height: 10
            alignment: Qt.AlignCenter
        }
        // up button
        first {
            alignment: Qt.AlignRight
            foreground.rotation: -90
        }
        // down button
        second {
            alignment: Qt.AlignLeft
            foreground.rotation: 90
        }
    }
}

Nota: No se garantiza que los tipos de los módulos de Qt.labs sigan siendo compatibles en futuras versiones.

Véase también SubIndicatorStyle, DelegateStyle, ControlStyle, ControlStateStyle y la Referencia de FallbackStyle.

Documentación de propiedades

first : SubIndicatorStyle

Propiedad agrupada para aplicar estilos al primer subindicador de los controles que muestran varios indicadores. En el caso de ` SpinBox`, aplica estilos al botón de incremento. Las propiedades no definidas recurren al propio indicador.

Nota: La propiedad up se mantiene como alias de first por motivos de compatibilidad con versiones anteriores. El código nuevo debería utilizar first, ya que este nombre es genérico y puede ser utilizado por controles con subindicadores que no representen acciones de aumento. Es posible que el alias de compatibilidad se elimine en una versión futura.

Véase también second.

foreground : DelegateStyle

Propiedad agrupada para aplicar estilos al elemento en primer plano de este indicador. Por ejemplo, checkBox.indicator describe el marco de la casilla de selección, mientras que checkBox.indicator.foreground se refiere a la marca de selección.

En el caso de controles como slider, progressBar y switchControl, la propiedad indicator.foreground representa la barra de progreso o el relleno dentro de la ranura, mientras que la propiedad indicator representa la propia ranura.

second : SubIndicatorStyle

Propiedad agrupada para aplicar estilos al segundo subindicador de, por ejemplo, un « SpinBox ». Las propiedades no definidas recurren al propio indicador.

Nota: La propiedad ` down ` se mantiene como alias de ` second ` por motivos de compatibilidad con versiones anteriores. El código nuevo debería utilizar ` second`, ya que este nombre es genérico y puede ser utilizado por controles con subindicadores que no representen acciones de desplazamiento hacia abajo. El alias de compatibilidad podría eliminarse en una versión futura.

Véase también first.

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.