En esta página

Glow QML Type

Genera una imagen desenfocada y coloreada de la fuente y la coloca detrás de la original, dando la impresión de que la fuente brilla. Más...

Import Statement: import Qt5Compat.GraphicalEffects
Since: QtGraphicalEffects 1.0
Inherits:

Item

Propiedades

Descripción detallada

FuenteEfecto aplicado

Mariposa blanca sobre fondo negro

Mariposa con bordes brillantes

Ejemplo

El siguiente ejemplo muestra cómo aplicar el efecto.

import QtQuick
import Qt5Compat.GraphicalEffects

Item {
    width: 300
    height: 300

    Rectangle {
        anchors.fill: parent
        color: "black"
    }

    Image {
        id: butterfly
        source: "images/butterfly.png"
        sourceSize: Qt.size(parent.width, parent.height)
        smooth: true
        visible: false
    }

    Glow {
        anchors.fill: butterfly
        radius: 8
        color: "white"
        source: butterfly
    }
}

Documentación de propiedades

cached : alias

Esta propiedad permite almacenar en caché los píxeles de salida del efecto con el fin de mejorar el rendimiento del renderizado.

Cada vez que se modifican las propiedades de la fuente o del efecto, es necesario actualizar los píxeles de la caché. El consumo de memoria aumenta, ya que se requiere un búfer de memoria adicional para almacenar la salida del efecto.

Se recomienda desactivar la caché cuando se animen las propiedades de la fuente o del efecto.

Por defecto, la propiedad está establecida en « false ».

color : alias

Esta propiedad define el valor de color RGBA que se utiliza para el resplandor.

Por defecto, la propiedad está establecida en « "white" ».

Ejemplos de resultados con diferentes valores de color

Efecto de resplandor blanco

Efecto de brillo verde

Resplandor verde semitransparente

color: #ffffff color: #00ff00 color: #aa00ff00
radius: 8radius: 8radius: 8
samples: 17samples: 17samples: 17
spread: 0,5spread: 0,5spread: 0,5

radius : alias

El radio define la suavidad del resplandor. Un radio mayor hace que los bordes del resplandor parezcan más difuminados.

En función del valor del radio, el valor de « samples » debe establecerse en un valor lo suficientemente grande como para garantizar la calidad visual.

El desenfoque ideal se consigue seleccionando « samples » y « radius » de tal forma que samples = 1 + radius * 2, por ejemplo:

RadioMuestras
0 (sin desenfoque)1
13
25
37

Por defecto, la propiedad está establecida en « floor(samples/2) ».

Ejemplos de resultados con diferentes valores de radio

Sin efecto de resplandor

Radio de brillo moderado

Gran radio de luminosidad

radio: 0 radio: 6 radio: 12
samples: 25samples: 25samples: 25
color: #ffffffcolor: #ffffffcolor: #ffffff
spread: 0spread: 0spread: 0

Nota: La propiedad « radius » se utiliza para calcular el tamaño del búfer fuera de pantalla del efecto. Los valores más altos provocarán asignaciones de memoria más grandes.

samples : alias

Esta propiedad define el número de muestras que se toman por píxel al calcular el desenfoque de suavizado de bordes. Un valor más alto ofrece mejor calidad, pero ralentiza el renderizado.

Lo ideal es que este valor sea el doble del valor de radio más alto requerido más uno, por ejemplo:

RadioMuestras
0 (sin desenfoque)1
13
25
37

Por defecto, la propiedad está establecida en « 9 ».

Esta propiedad no está pensada para ser animada. Si se modifica esta propiedad, se volverán a compilar los shaders de OpenGL subyacentes.

source : alias

Esta propiedad define el elemento de origen que se va a utilizar como fuente para el resplandor generado.

Nota: Noes posible que el efecto se incluya a sí mismo, por ejemplo, estableciendo como fuente el elemento padre del efecto.

spread : alias

Esta propiedad define en qué medida se intensifica el color del resplandor cerca de los bordes de la fuente.

Los valores oscilan entre 0,0 y 1,0. Por defecto, la propiedad está establecida en 0.5.

Nota: La implementación está optimizada para valores de dispersión medios y bajos. Dependiendo de la fuente, los valores de dispersión más cercanos a 1,0 pueden dar lugar a resultados visualmente asimétricos.

Ejemplos de resultados con diferentes valores de dispersión

Brillo sin difuminarse

Brillo con cobertura media

Brilla con todo su esplendor

dispersión: 0,0 dispersión: 0,5 spread: 1,0
radius: 8radius: 8radius: 8
samples: 17samples: 17samples: 17
color: #ffffffcolor: #ffffffcolor: #ffffff

transparentBorder : alias

Esta propiedad determina si el efecto tiene o no un borde transparente.

Cuando se establece en « true », el exterior del elemento se rellena con un borde transparente, lo que hace que el muestreo fuera de la textura de origen utilice transparencia en lugar de los píxeles del borde. Sin esta propiedad, una imagen con bordes opacos no obtendrá un borde desenfocado.

Por defecto, la propiedad está configurada en « true ». Establece el valor en «false» si la fuente ya tiene un borde transparente para que el desenfoque sea un poco más rápido.

En el fragmento de código siguiente, el rectángulo de la izquierda tiene bordes transparentes y está desenfocado, mientras que el rectángulo de la derecha no.

import QtQuick
import Qt5Compat.GraphicalEffects

Rectangle {
    width: 180
    height: 100

    Row {
        anchors.centerIn: parent
        spacing: 16

        Rectangle {
            id: normalRect
            width: 60
            height: 60
            color: "black"
            radius: 10
            layer.enabled: true
            layer.effect: Glow {
                samples: 15
                color: "blue"
                transparentBorder: false
            }
        }

        Rectangle {
            id: transparentBorderRect
            width: 60
            height: 60
            color: "black"
            radius: 10
            layer.enabled: true
            layer.effect: Glow {
                samples: 15
                color: "blue"
                transparentBorder: true
            }
        }
    }
}

Rectángulos que muestran la diferencia entre los ajustes de borde transparente

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.