En esta página

MaskedBlur QML Type

Aplica un efecto de desenfoque con intensidad variable. Más...

Import Statement: import Qt5Compat.GraphicalEffects
Since: QtGraphicalEffects 1.0
Inherits:

Item

Propiedades

Descripción detallada

El efecto «MaskedBlur» suaviza la imagen difuminándola. La intensidad del desenfoque se puede controlar para cada píxel utilizando « maskSource », de modo que algunas partes de la imagen original queden más desenfocadas que otras.

Aplicar el desenfoque en tiempo real es una operación muy exigente. El desenfoque gaussiano a pantalla completa, incluso con un número moderado de muestras, solo se ejecutará a 60 fps en hardware gráfico de gama alta.

FuenteMaskSourceEfecto aplicado

Escarabajo negro sobre una hoja

Máscara de intensidad de desenfoque con degradado

Escarabajo con desenfoque de intensidad variable

Nota: Este efecto está disponible cuando se ejecuta con OpenGL.

Ejemplo

El siguiente ejemplo muestra cómo aplicar el efecto.

import QtQuick
import Qt5Compat.GraphicalEffects

Item {
    width: 300
    height: 300

    Image {
        id: bug
        source: "images/bug.jpg"
        sourceSize: Qt.size(parent.width, parent.height)
        smooth: true
        visible: false
    }

    LinearGradient {
        id: mask
        anchors.fill: bug
        gradient: Gradient {
            GradientStop { position: 0.2; color: "#ffffffff" }
            GradientStop { position: 0.5; color: "#00ffffff" }
        }
        start: Qt.point(0, 0)
        end: Qt.point(300, 0)
        visible: false
    }

    MaskedBlur {
        anchors.fill: bug
        source: bug
        maskSource: mask
        radius: 16
        samples: 24
    }
}

Documentación de propiedades

cached : alias

Esta propiedad permite almacenar en caché los píxeles de salida del efecto con el fin de mejorar el rendimiento del renderizado. Cada vez que se modifican las propiedades de la fuente o del efecto, es necesario actualizar los píxeles de la caché. El consumo de memoria aumenta, ya que se requiere un búfer adicional de memoria para almacenar la salida del efecto.

Se recomienda desactivar la caché cuando las propiedades de la fuente o del efecto estén animadas.

Por defecto, la propiedad está establecida en « false ».

maskSource : alias

Esta propiedad define el elemento que controla la intensidad final del desenfoque. El valor del canal alfa del píxel de maskSource define el radio de desenfoque real que se va a utilizar para desenfocar el píxel de origen correspondiente.

Los píxeles opacos de maskSource producen un desenfoque con el valor especificado en « radius », mientras que los píxeles transparentes suprimen el desenfoque por completo. Los píxeles semitransparentes de maskSource producen un desenfoque con un radio que se interpola en función del nivel de transparencia del píxel.

radius : alias

Esta propiedad define la distancia de los píxeles vecinos que influyen en el desenfoque de un píxel concreto. Un radio mayor aumenta el efecto de desenfoque.

En función del valor del radio, el valor de « samples » debe establecerse en un valor lo suficientemente grande como para garantizar la calidad visual.

El valor oscila entre 0,0 (sin desenfoque) e infinito. Por defecto, la propiedad está establecida en « 0.0 » (sin desenfoque).

Ejemplos de resultados con diferentes valores de radio

No se ha aplicado ningún efecto de desenfoque

Desenfoque moderado con máscara

Desenfoque intenso con máscara

radio: 0 radio: 8 radio: 16
samples: 25samples: 25samples: 25

Nota: La propiedad ` radius ` se utiliza para calcular el tamaño del búfer fuera de pantalla del efecto. Los valores más altos provocarán asignaciones de memoria más grandes.

samples : alias

Esta propiedad define el número de muestras que se toman por píxel al calcular el desenfoque. Un valor mayor ofrece mejor calidad, pero ralentiza el renderizado.

Lo ideal es que este valor sea el doble del valor de radio más alto requerido más 1; por ejemplo, si el radio se anima entre 0,0 y 4,0, el número de muestras debería fijarse en 9.

Por defecto, la propiedad está establecida en 9.

Esta propiedad no está pensada para ser animada. Cambiar esta propiedad puede provocar que se recompilen los shaders de OpenGL subyacentes.

source : alias

Esta propiedad define el elemento de origen al que se le va a aplicar el efecto de desenfoque.

Nota: Noes posible que el efecto se incluya a sí mismo, por ejemplo, estableciendo como origen el elemento padre del efecto.

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.