MapQuickItem QML Type

El tipo MapQuickItem muestra un objeto arbitrario Qt Quick en un Mapa. Más...

• Lista de todos los miembros, incluyendo los heredados
• MapQuickItem es parte de QML Maps Plugin.

Propiedades

• anchorPoint : point
• autoFadeIn : bool
• coordinate : coordinate
• sourceItem : object
• zoomLevel : real

Descripción detallada

El tipo MapQuickItem se utiliza para colocar un objeto arbitrario Qt Quick sobre un Mapa en una ubicación y tamaño especificados. A diferencia de un elemento flotante sobre el mapa, MapQuickItem seguirá la panorámica (y, opcionalmente, el zoom) del mapa como si estuviera sobre su superficie.

La propiedad sourceItem contiene el elemento Qt Quick que se dibujará, que puede ser de cualquier tipo visible.

Posicionamiento y tamaño

El posicionamiento del MapQuickItem en el Mapa se controla mediante dos propiedades: coordinate y anchorPoint. Si sólo se establece coordinate, se especifica una coordenada de longitud/latitud en la que se colocará el elemento. La coordenada establecida se alineará con la esquina superior izquierda del elemento contenido cuando se muestre en la pantalla.

La propiedad anchorPoint proporciona una forma de alinear la coordenada con otras partes del elemento además de la esquina superior izquierda, estableciendo un número de píxeles por los que el elemento se desplazará. Una forma sencilla de pensar en ello es observar que el punto dado por anchorPoint en el propio elemento es el punto que se alineará con el coordinate dado cuando se muestre.

Además de estar anclado al mapa, el MapQuickItem puede seguir opcionalmente la escala del mapa y cambiar de tamaño cuando el mapa se amplía o se reduce. Este comportamiento se controla mediante la propiedad zoomLevel. El comportamiento predeterminado si no se establece zoomLevel es que el elemento se dibuje "en la pantalla" en lugar de "en el mapa", de modo que su tamaño sigue siendo el mismo independientemente del nivel de zoom del Mapa.

Rendimiento

El rendimiento de un elemento MapQuickItem suele ser similar al del elemento Qt Quick por sí solo. Los gastos generales añadidos equivalen a una traslación y (posiblemente) escalado del elemento original, así como una transformación de longitud y latitud a posición en pantalla.

Limitaciones

Ejemplo de uso

El siguiente fragmento muestra un MapQuickItem que contiene un objeto Image, para mostrar un Marcador en el Mapa. Esta estrategia se utiliza para mostrar los marcadores del mapa en el ejemplo MapViewer.

MapQuickItem {
    id: marker
    anchorPoint.x: image.width/4
    anchorPoint.y: image.height

    HoverHandler {
        id: hoverHandler
    }
    TapHandler {
        id: tapHandler
        acceptedButtons: Qt.RightButton
        gesturePolicy: TapHandler.WithinBounds
        onTapped: {
            mapview.currentMarker = -1
            for (var i = 0; i< mapview.markers.length; i++){
                if (marker == mapview.markers[i]){
                    mapview.currentMarker = i
                    break
                }
            }
            mapview.showMarkerMenu(marker.coordinate)
        }
    }
    DragHandler {
        id: dragHandler
        grabPermissions: PointerHandler.CanTakeOverFromItems | PointerHandler.CanTakeOverFromHandlersOfDifferentType
    }

    sourceItem: Image {
        id: image
    }
}

Documentación de Propiedades

anchorPoint : point

Esta propiedad determina qué punto de sourceItem se alineará con la coordenada en el mapa.

autoFadeIn : bool

Esta propiedad establece si el elemento se desvanece automáticamente al hacer zoom en el mapa a partir de niveles de zoom muy bajos. Por defecto es true. Establecer esta propiedad a false hace que el elemento del mapa tenga siempre la opacidad especificada con la propiedad QtQuick::Item::opacity, que por defecto es 1.0.

coordinate : coordinate

Esta propiedad contiene la coordenada de anclaje de MapQuickItem. El punto de sourceItem especificado por anchorPoint se mantiene alineado con esta coordenada cuando se dibuja en el mapa.

En la imagen de abajo, hay 3 MapQuickItems que son idénticos excepto por el valor de sus propiedades anchorPoint. Los valores de anchorPoint para cada uno están escritos en la parte superior del elemento.

sourceItem : object

Esta propiedad contiene el elemento fuente que se dibujará en el mapa.

zoomLevel : real

Esta propiedad controla el comportamiento de la escala de los contenidos de MapQuickItem. En particular, estableciendo esta propiedad es posible elegir entre los objetos que se dibujan en la pantalla (y cuyo tamaño se expresa en píxeles de pantalla), y los que se dibujan en la superficie del mapa (cuyo tamaño cambia con el nivel de zoom del mapa).

El valor por defecto de esta propiedad es 0.0, que corresponde a dibujar el objeto en la superficie de la pantalla. Si se establece en otro valor, el objeto se dibujará en la superficie del mapa en su lugar. El valor (si no es cero) especifica el zoomLevel en el que el objeto será visible a una escala de 1:1 (es decir, donde los píxeles del objeto y los píxeles de la pantalla son iguales). A niveles de zoom inferiores a éste, el objeto aparecerá más pequeño, y a niveles de zoom superiores, aparecerá más grande. Esto contrasta con cuando esta propiedad se establece en cero, donde el objeto permanece del mismo tamaño en la pantalla en todos los niveles de zoom.