EndpointDiscovery QML Type

Proporciona información sobre los extremos disponibles en un servidor. Más...

Este tipo está obsoleto desde QtOpcUa 6.9. Desaconsejamos su uso en código nuevo.

• Lista de todos los miembros, incluyendo los heredados

Propiedades

• connection : Connection
• count : int
• serverUrl : string
• status : Status

Señales

• endpointsChanged()

Métodos

• EndpointDescription at(index)

Descripción detallada

Permite obtener y acceder a información sobre los puntos finales disponibles en un servidor.

QtOpcUa.Connection {
    id: connection
    backend: availableBackends[0]
    defaultConnection: true
}

QtOpcUa.ServerDiscovery {
    discoveryUrl: "opc.tcp://127.0.0.1:43344"
    onServersChanged: {
        if (status.isGood) {
            if (status.status == QtOpcUa.Status.GoodCompletesAsynchronusly)
                return; // wait until finished
            if (count > 0) {
                // choose right server
                endpointDiscovery.serverUrl = at(0).discoveryUrls[0];
                console.log("Using server URL:", endpointDiscovery.serverUrl);
            } else {
                // no servers retrieved
            }
        } else {
            // Fetching servers failed
            console.log("Error fetching server:", servers.status.status);
        }
    }
}

QtOpcUa.EndpointDiscovery {
    id: endpointDiscovery
    onEndpointsChanged: {
        if (status.isGood) {
            if (status.status == QtOpcUa.Status.GoodCompletesAsynchronusly)
                return; // wait until finished
            if (count > 0) {
                // choose right endpoint
                console.log("Using endpoint", at(0).endpointUrl, at(0).securityPolicy);
                connection.connectToEndpoint(at(0));
            } else {
                // no endpoints retrieved
            }
        } else {
            // Fetching endpoints failed
            console.log("Error fetching endpoints:", status.status);
        }
    }
}

Documentación de propiedades

connection : Connection

La conexión que se utilizará para solicitar información.

Si no se establece esta propiedad, se utilizará la conexión por defecto, si existe.

Véase también Connection y Connection::defaultConnection.

count : int

Número actual de endpoints en este elemento. Antes de utilizar cualquier dato de un descubrimiento de endpoints, debe comprobar status si la información se ha recuperado correctamente.

Véase también status y Status.

serverUrl : string

URL de descubrimiento del servidor desde el que obtener los puntos finales. Cada vez que se cambia la URL, se inicia una petición al servidor dado.

Al iniciar la solicitud, la lista de puntos finales disponibles se borra y el estado se establece en Status.GoodCompletesAsynchronously. Una vez finalizada la solicitud, cambia status.

Asegúrese de comprobar status antes de acceder a la lista de puntos finales.

Véase también endpointsChanged.

status : Status

Estado actual de este elemento. En caso de que la última recuperación de puntos finales se haya realizado correctamente, el estado es Status.Good.

if (endpoints.status.isGood) {
    // do something
} else {
    // handle error
}

Véase también Status.

Documentación de señales

endpointsChanged()

Se emite cuando se inicia, finaliza o falla una solicitud de recuperación. En una función llamada, primero se debe comprobar el status del objeto. Si el estado es Status.GoodCompletesAsynchronously, la solicitud sigue en curso. Si el estado es Status.Good, la solicitud ha finalizado y se pueden leer las descripciones de los extremos. Si el estado no es bueno, se ha producido un error y status contiene el código de error devuelto.

onEndpointsChanged: {
        if (endpoints.status.isGood) {
            if (endpoints.status.status == QtOpcua.Status.GoodCompletesAsynchronusly)
                return; // wait until finished
            if (endpoints.count > 0) {
                var endpointUrl = endpoints.at(0).endpointUrl();
                console.log(endpointUrl);
            }
        } else {
            // handle error
        }
}

Véase también status, count, at, Status, y EndpointDescription.

Documentación del método

EndpointDescription at(index)

Devuelve la descripción del punto final en la dirección index. En caso de que no haya puntos finales disponibles o el índice no sea válido, se devolverá una descripción de punto final no válida. Antes de utilizar cualquier dato de esto, debe comprobar status si la recuperación de la información se ha realizado correctamente.

if (endpoints.status.isGood) {
    if (endpoints.count > 0)
        var endpointUrl = endpoints.at(0).endpointUrl();
        console.log(endpointUrl);
} else {
    // handle error
}

Véase también count, status y EndpointDescription.