PathAttribute QML Type

Especifica cómo establecer un atributo en una posición determinada de una ruta. Más...

• Lista de todos los miembros, incluidos los heredados

Propiedades

• name : string
• value : real

Descripción detallada

El objeto PathAttribute permite especificar atributos consistentes en un nombre y un valor para varios puntos a lo largo de un recorrido. Los atributos se muestran al delegado como propiedades adjuntas. El valor de un atributo en un punto concreto del recorrido se interpola a partir de los PathAttributes que delimitan ese punto.

El siguiente ejemplo muestra una ruta con los elementos escalados al 30% con una opacidad del 50% en la parte superior de la ruta y escalados al 100% con una opacidad del 100% en la parte inferior. Observe el uso de las propiedades adjuntas PathView.iconScale y PathView.iconOpacity para establecer la escala y la opacidad del delegado.

import QtQuick

Rectangle {
    width: 240; height: 200

    Component {
        id: delegate
        Item {
            width: 80; height: 80
            scale: PathView.iconScale
            opacity: PathView.iconOpacity
            Column {
                Image { anchors.horizontalCenter: nameText.horizontalCenter; width: 64; height: 64; source: icon }
                Text { id: nameText; text: name; font.pointSize: 16 }
            }
        }
    }

    PathView {
        anchors.fill: parent
        model: ContactModel {}
        delegate: delegate
        path: Path {
            startX: 120; startY: 100
            PathAttribute { name: "iconScale"; value: 1.0 }
            PathAttribute { name: "iconOpacity"; value: 1.0 }
            PathQuad { x: 120; y: 25; controlX: 260; controlY: 75 }
            PathAttribute { name: "iconScale"; value: 0.3 }
            PathAttribute { name: "iconOpacity"; value: 0.5 }
            PathQuad { x: 120; y: 100; controlX: -20; controlY: 75 }
        }
    }
}

Véase también Path.

Documentación de propiedades

name : string

Esta propiedad contiene el nombre del atributo a cambiar.

Este atributo estará disponible para el delegado como PathView.<nombre>.

Tenga en cuenta que está permitido utilizar como atributo un nombre de propiedad de elemento existente, como "opacidad". Esto se debe a que los atributos de ruta añaden una nueva propiedad adjunta que de ninguna manera entra en conflicto con las propiedades existentes.

value : real

Esta propiedad contiene el valor del atributo.

El valor especificado puede utilizarse para influir en la apariencia visual de un elemento a lo largo de la ruta. Por ejemplo, la siguiente ruta especifica un atributo llamado itemRotation, que tiene el valor 0 al principio de la ruta, y el valor 90 al final de la ruta.

Path {
    startX: 0
    startY: 0
    PathAttribute { name: "itemRotation"; value: 0 }
    PathLine { x: 100; y: 100 }
    PathAttribute { name: "itemRotation"; value: 90 }
}

En nuestro delegado, podemos vincular la propiedad de rotación a la propiedad adjunta PathView.itemRotation creada para este atributo.

Rectangle {
    width: 10; height: 10
    rotation: PathView.itemRotation
}

A medida que cada ítem es posicionado a lo largo del camino, será rotado en consecuencia: un ítem al principio del camino no será rotado, un ítem al final del camino será rotado 90 grados, y un ítem a mitad del camino será rotado 45 grados.