ProceduralTextureData QML Type

Permite crear y poblar TextureData desde QML. Más...

• Lista de todos los miembros, incluidos los heredados

Propiedades

• depth : int
• format : enumeration
• hasTransparency : bool
• height : int
• textureData : ArrayBuffer
• width : int

Descripción detallada

ProceduralTextureData es un tipo helper que permite la creación de TextureData desde QML. El componente TextureData es abstracto, y normalmente se crea a partir de C++. Con ProceduralTextureData, es posible rellenar un TextureData a partir de QML.

ProceduralTextureData {
    id: dynamicTextureData
    property color color1: "red"
    property color color2: "black"
    width: 32
    height: 32
    hasTransparency: false
    format: TextureData.RGBA8
    textureData: generateTextureData(color1, color2)

    function generateTextureData(newColor1: color, newColor2 : color) : ArrayBuffer {
        let dataBuffer = new ArrayBuffer(width * height * 4)
        let data = new Uint8Array(dataBuffer)
        // Create a checkered pattern using newColor1 and newColor2
        for (let x = 0; x < width; x++) {
            for (let y = 0; y < height; y++) {
                let index = (x + y * width) * 4
                let color = (x % 2 === y % 2) ? newColor1 : newColor2
                data[index + 0] = color.r * 255
                data[index + 1] = color.g * 255
                data[index + 2] = color.b * 255
                data[index + 3] = 255
            }
        }
        return dataBuffer
    }
}

En el fragmento de código anterior, la función generateTextureData se utiliza para generar un patrón de tablero de ajedrez utilizando los dos colores color1 y color2. Rellenando un ArrayBuffer con los datos generados, se rellena la propiedad textureData del TextureData.

Documentación de la propiedad

depth : int [default: 0]

Esta propiedad contiene la profundidad de los datos de la textura en píxeles. Establecer la profundidad por encima de 0 significa que la textura se maneja como una textura 3D.

format : enumeration [default: TextureData.RGBA8]

Esta propiedad contiene el formato de los datos de textura.

hasTransparency : bool

Esta propiedad indica si los datos de textura tienen transparencia.

height : int [default: 0]

Esta propiedad contiene la altura de los datos de textura en píxeles.

textureData : ArrayBuffer

Esta propiedad contiene los datos de la textura.

width : int [default: 0]

Esta propiedad contiene el ancho de los datos de textura en píxeles.