qt_generate_deploy_script

Genera un script de despliegue personalizado.

El comando está definido en el componente Core del paquete Qt6, que puede cargarse de este modo:

find_package(Qt6 REQUIRED COMPONENTS Core)

Este comando se introdujo en Qt 6.5.

Sinopsis

qt_generate_deploy_script(
    OUTPUT_SCRIPT <var>
    [TARGET target]
    [NAME script_name]
    [CONTENT content]
)

Si los comandos sin versión están deshabilitados, utilice qt6_generate_deploy_script() en su lugar. Admite el mismo conjunto de argumentos que este comando.

Descripción

El comando genera un script cuya ruta de archivo completa se almacenará en la variable nombrada por la opción OUTPUT_SCRIPT. Ese script sólo se escribe en el momento de generar CMake. Está pensado para usarse con el comando install(SCRIPT), que debe venir después de que el objetivo de la aplicación se haya instalado usando install(TARGETS).

El comando se encarga de generar un archivo con el nombre adecuado para los generadores multi-config. Se añaden los includes necesarios para que las funciones y variables de despliegue de Qt en CMake sean accesibles.

El argumento TARGET especifica el objetivo que será desplegado por el script. Esto afecta al nombre de archivo del script generado, a menos que se especifique NAME.

El argumento NAME controla una parte identificable dentro del nombre generado automáticamente por el script de despliegue. El argumento NAME es por defecto custom si no se indica NAME ni TARGET.

El argumento CONTENT especifica el código que se escribe en el script de despliegue. El contenido puede contener expresiones del generador.

Este comando está pensado para generar scripts de despliegue personalizados que llamen directamente a funciones de la API de despliegue de Qt. Para propósitos de despliegue menos complejos, es más conveniente usar qt_generate_deploy_app_script () o qt_generate_deploy_qml_app_script().

Ejemplo

cmake_minimum_required(VERSION 3.16...3.22)
project(MyThings)

find_package(Qt6 REQUIRED COMPONENTS Core)
qt_standard_project_setup()

qt_add_executable(MyApp main.cpp)

install(TARGETS MyApp
    BUNDLE  DESTINATION .
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

qt_generate_deploy_script(
    TARGET MyApp
    OUTPUT_SCRIPT deploy_script
    CONTENT "
qt_deploy_runtime_dependencies(
    EXECUTABLE $<TARGET_FILE:MyApp>
)
")
install(SCRIPT ${deploy_script})