En esta página

Qt Quick 3D - Ejemplo de sombreadores personalizados

Muestra el uso de sombreadores de vértices y de fragmentos personalizados.

Este ejemplo muestra cómo utilizar un material con código de sombreadores de vértices y fragmentos totalmente personalizados.

Esfera con los colores del arcoíris, con deformación ondulada y ajustes de sombreado

Este ejemplo es el complemento del ejemplo «custommaterials», que muestra el otro grupo de materiales personalizados: los materiales « shaded », en los que el fragmento de código del sombreador complementa un « PrincipledMaterial », en lugar de sustituirlo.

Implementación de un material personalizado

En este ejemplo, el sombreador de vértices deforma una malla según una función sinusoidal. El resultado final se controla mediante dos controles deslizantes que corresponden a los valores de tiempo y amplitud de la función sinusoidal.

El sombreador de fragmentos se utiliza para colorear la malla según los valores de posición de los vértices. Se incluyen dos sombreadores de fragmentos: uno con texturizado y otro sin él. La versión texturizada toma muestras de una textura procedente de un archivo de imagen o de una capa en tiempo real de Qt Quick.

El material no participa en el sistema predeterminado de iluminación ni de sombras, por lo que su propiedad « shadingMode » está establecida en « CustomMaterial.Unshaded ».

Consulte CustomMaterial para obtener una descripción detallada de las capacidades de los materiales personalizados.

CustomMaterial {
    id: root
    property real time: 0.0
    property real amplitude: 5.0
    property real alpha: 1.0

    property bool texturing: false
    property bool textureFromItem: false
    property Item texSrc
    Texture {
        id: texFromFile
        source: "qt_logo.png"
    }
    Texture {
        id: texFromItem
        sourceItem: root.texSrc
    }
    property TextureInput tex: TextureInput {
        enabled: root.texturing
        texture: root.textureFromItem ? texFromItem : texFromFile
    }

    shadingMode: CustomMaterial.Unshaded
    sourceBlend: root.alpha < 1.0 ? CustomMaterial.SrcAlpha : CustomMaterial.NoBlend
    destinationBlend: root.alpha < 1.0 ? CustomMaterial.OneMinusSrcAlpha : CustomMaterial.NoBlend
    cullMode: CustomMaterial.BackFaceCulling

    vertexShader: "example.vert"
    fragmentShader: root.texturing ? "example_tex.frag" : "example.frag"
}

Uso de un material personalizado

Un material personalizado que utilice sombreadores personalizados se utiliza de la misma manera que cualquier otro material. Las variables uniformes del sombreador se pueden actualizar fácilmente mediante enlaces de propiedades QML.

Model {
    position: Qt.vector3d(0, 0, 0)
    NumberAnimation on eulerRotation.y {
        from: 0
        to: 360
        duration: 3000
        loops: -1
        running: control.animateRotation
    }
    scale: Qt.vector3d(2, 2, 2)
    source: "#Sphere"
    materials: [
        ExampleMaterial {
            id: exampleMaterial
            time: control.time
            amplitude: control.amplitude
            alpha: control.alpha
            texturing: control.texturing
            textureFromItem: control.textureFromItem
            texSrc: Rectangle {
                layer.enabled: true
                layer.textureMirroring: ShaderEffectSource.NoMirroring
                visible: false
                SequentialAnimation on color {
                    ColorAnimation { from: "black"; to: "yellow"; duration: 2000 }
                    ColorAnimation { from: "yellow"; to: "cyan"; duration: 1000 }
                    ColorAnimation { from: "cyan"; to: "black"; duration: 500 }
                    loops: -1
                }
                width: 512
                height: 512
                Image {
                    source: "qt_logo.png"
                    anchors.centerIn: parent
                }
            }
        }
    ]
}

Proyecto de ejemplo en @ code.qt.io

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.