Qt Quick 3D - Ejemplo sencillo de XR con toque
Muestra el seguimiento de las manos en Qt Quick 3D XR.

Este ejemplo muestra cómo utilizar la API de seguimiento de manos en Qt Quick 3D XR para interactuar con objetos 2D y 3D de la escena. Sigue la estructura básica del ejemplo xr_simple.
Comenzamos creando un componente reutilizable ` TouchHand ` que encapsula toda la lógica que necesitamos para cada mano.
// Copyright (C) 2025 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtQuick3D
import QtQuick3D.Xr
Node {
id: root
property color color: "#ddaa88"
required property int touchId
required property int hand
required property XrView view
property alias touchPosition: handController.scenePos
property bool touchActive: false
XrController {
id: handController
controller: root.hand
property vector3d scenePos: view.xrOrigin.mapPositionToScene(pokePosition)
onScenePosChanged: {
const touchOffset = view.processTouch(scenePos, root.touchId)
handModel.position = touchOffset
const touchState = view.touchpointState(root.touchId)
const gadget = touchState.model as XrGadget
if (gadget) {
gadget.handleTouch(touchState.uvPosition, root.touchId, touchState.pressed)
}
}
}
XrHandModel {
id: handModel
hand: root.hand
materials: PrincipledMaterial {
baseColor: root.color
roughness: 0.5
}
}
}El componente contiene un ` XrController`, que nos proporciona la posición 3D del dedo índice, y un ` XrHandModel ` para mostrar dónde se encuentra la mano. El controlador ` onTouchPositionChanged ` es donde ocurre la magia. Llamamos a ` XrView.processTouch()`, que se encarga del trabajo pesado: intenta asignar la posición táctil 3D a una posición 2D en un ` XrItem ` y envía un evento táctil si encuentra un elemento. A continuación, devuelve el desplazamiento desde la posición 3D hasta el punto de contacto en la superficie 2D. Luego utilizamos ese desplazamiento para desplazar la posición del XrHandModel, con el fin de dar la impresión de que la mano se detiene contra la superficie.
Nota: Este efecto no funcionará en el Apple Vision Pro, ya que el sistema muestra las manos reales del usuario y el XrHandModel no se muestra.
Creamos dos instancias del componente «TouchHand» dentro del « XrOrigin », una para cada mano:
XrOrigin {
id: theOrigin
z: 50
TouchHand {
id: rightHandModel
hand: XrHandModel.RightHand
view: xrView
touchId: 0
onTouchPositionChanged: buttons.handleTouch(touchPosition)
}
TouchHand {
id: leftHandModel
hand: XrHandModel.LeftHand
view: xrView
touchId: 1
onTouchPositionChanged: buttons.handleTouch(touchPosition)
}
}
xrOrigin: theOriginEn este caso, « buttons » es un grupo de botones 3D que cuenta con una función « handleTouch ». (La implementación no es específica de XR, por lo que no se documentan aquí los detalles).
Colocamos el « XrOrigin » a 50 centímetros del origen de la escena, lo que debería ser una distancia de contacto cómoda.
El resto de la escena contiene algunos modelos 3D y un « XrItem » que reacciona a los eventos táctiles.
© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.