IndicatorStyle QML Type

Définit le style de l'indicateur d'un contrôle. En savoir plus...

Ce type est en préversion technologique et est susceptible d'être modifié.

• Liste de tous les membres, y compris les membres hérités

Propriétés

• first : SubIndicatorStyle
• foreground : DelegateStyle
• second : SubIndicatorStyle

Description détaillée

La classe IndicatorStyle étend la classe DelegateStyle en ajoutant des propriétés spécifiques à la mise en forme d'un indicateur.

L'IndicatorStyle lui-même décrit l'arrière-plan de l'indicateur, tandis que l'foreground décrit le contenu affiché à l'intérieur de celui-ci. Par exemple, checkBox.indicator définit le style du cadre de la case à cocher et checkBox.indicator.foreground définit le style de la coche. Pour switchControl, slider et progressBar, l'indicateur définit le style de la rainure et le premier plan définit le style du remplissage.

checkBox {
    background.visible: false
    text.alignment: Qt.AlignVCenter | Qt.AlignLeft
    indicator {
        color: "transparent"
        border.width: 1
        foreground {
            color: "transparent"
            image.source: "qrc:/qt-project.org/imports/QtQuick/Controls/Basic/images/check.png"
            // Hide the checkMark when the CheckBox is unchecked
            visible: false
        }
    }
    checked {
        // Show the checkMark when the CheckBox is checked
        indicator.foreground.visible: true
    }
}

Certains contrôles comportent plusieurs indicateurs. Par exemple, SpinBox dispose à la fois d’un bouton d’augmentation et d’un bouton de diminution. Ceux-ci peuvent être stylisés indépendamment à l’aide des sous-indicateurs first et second, spinBox.indicator.first et spinBox.indicator.second. Pour SpinBox, indicator.first définit le style du bouton d’augmentation, et indicator.second celui du bouton de diminution. Les propriétés non définies sur un sous-indicateur sont reprises par l’indicateur lui-même.

spinBox {
    text.alignment: Qt.AlignHCenter | Qt.AlignVCenter
    padding: 0
    indicator {
        fillHeight: true
        color: "navy"
        opacity: 0.1
        foreground {
            color: "transparent"
            margins: 10
            image.color: "navy"
            image.fillMode: Image.PreserveAspectFit
            image.source: "qrc:/qt-project.org/imports/QtQuick/Controls/Basic/images/arrow-indicator.png"
            width: 10
            height: 10
            alignment: Qt.AlignCenter
        }
        // up button
        first {
            alignment: Qt.AlignRight
            foreground.rotation: -90
        }
        // down button
        second {
            alignment: Qt.AlignLeft
            foreground.rotation: 90
        }
    }
}

Voir également SubIndicatorStyle, DelegateStyle, ControlStyle, ControlStateStyle et la référence FallbackStyle.

Documentation sur les propriétés

first : SubIndicatorStyle

Propriété groupée permettant de définir le style du premier sous-indicateur des contrôles qui affichent plusieurs indicateurs. Pour ` SpinBox`, cela définit le style du bouton d’incrément. Si la propriété n’est pas définie, le style par défaut de l’indicateur lui-même est utilisé.

Voir également second.

foreground : DelegateStyle

Propriétés regroupées permettant de définir l'apparence de l'élément au premier plan de cet indicateur. Par exemple, checkBox.indicator décrit le cadre de la case à cocher, tandis que checkBox.indicator.foreground correspond à la coche.

Pour les contrôles tels que slider, progressBar et switchControl, la propriété « indicator.foreground » représente la barre de progression ou le remplissage à l'intérieur de la rainure, tandis que la propriété « indicator » représente la rainure elle-même.

second : SubIndicatorStyle

Propriété groupée permettant de styliser le deuxième sous-indicateur, par exemple d’un « SpinBox ». Les propriétés non définies reprennent les valeurs par défaut de l’indicateur lui-même.

Voir également first.