MaskedBlur QML Type

Applique un effet de flou dont l'intensité varie. En savoir plus...

• Liste de tous les membres, y compris les membres hérités

Propriétés

• cached : alias
• maskSource : alias
• radius : alias
• samples : alias
• source : alias

Description détaillée

L'effet MaskedBlur adoucit l'image en la rendant floue. L'intensité du flou peut être contrôlée pour chaque pixel à l'aide d'maskSource, de sorte que certaines parties de l'image source soient plus floues que d'autres.

L'application d'un flou en temps réel est une opération très gourmande en ressources. Un flou gaussien en plein écran, même avec un nombre modéré d'échantillons, ne fonctionnera qu'à 60 images par seconde sur du matériel graphique haut de gamme.

Exemple

L'exemple suivant montre comment appliquer l'effet.

import QtQuick
import Qt5Compat.GraphicalEffects

Item {
    width: 300
    height: 300

    Image {
        id: bug
        source: "images/bug.jpg"
        sourceSize: Qt.size(parent.width, parent.height)
        smooth: true
        visible: false
    }

    LinearGradient {
        id: mask
        anchors.fill: bug
        gradient: Gradient {
            GradientStop { position: 0.2; color: "#ffffffff" }
            GradientStop { position: 0.5; color: "#00ffffff" }
        }
        start: Qt.point(0, 0)
        end: Qt.point(300, 0)
        visible: false
    }

    MaskedBlur {
        anchors.fill: bug
        source: bug
        maskSource: mask
        radius: 16
        samples: 24
    }
}

Documentation des propriétés

cached : alias

Cette propriété permet de mettre en cache les pixels de sortie de l'effet afin d'améliorer les performances de rendu. Chaque fois que les propriétés de la source ou de l'effet sont modifiées, les pixels du cache doivent être mis à jour. La consommation de mémoire augmente, car un tampon de mémoire supplémentaire est nécessaire pour stocker la sortie de l'effet.

Il est recommandé de désactiver le cache lorsque les propriétés de la source ou de l’effet sont animées.

Par défaut, la propriété est définie sur « false ».

maskSource : alias

Cette propriété définit l'élément qui détermine l'intensité finale du flou. La valeur du canal alpha du pixel provenant de `maskSource` définit le rayon de flou réel qui sera utilisé pour appliquer le flou au pixel source correspondant.

Les pixels opaques de `maskSource` produisent un flou avec l'radius spécifiée, tandis que les pixels transparents suppriment complètement le flou. Les pixels semi-transparents de `maskSource` produisent un flou dont le rayon est interpolé en fonction du niveau de transparence du pixel.

radius : alias

Cette propriété définit la distance entre les pixels voisins qui influencent le flou d'un pixel donné. Un rayon plus grand accentue l'effet de flou.

En fonction de la valeur du rayon, la valeur de la propriété « samples » doit être suffisamment élevée pour garantir la qualité visuelle.

La valeur est comprise entre 0,0 (pas de flou) et inf. Par défaut, la propriété est définie sur « 0.0 » (pas de flou).

samples : alias

Cette propriété définit le nombre d'échantillons prélevés par pixel lors du calcul du flou. Une valeur plus élevée offre une meilleure qualité, mais ralentit le rendu.

Idéalement, cette valeur devrait être deux fois plus grande que la valeur maximale requise pour le rayon, plus 1. Par exemple, si le rayon est animé entre 0,0 et 4,0, le nombre d'échantillons devrait être défini sur 9.

Par défaut, la propriété est définie sur 9.

Cette propriété n’est pas destinée à être animée. La modification de cette propriété peut entraîner la recompilation des shaders OpenGL sous-jacents.

source : alias

Cette propriété définit l'élément source qui va être flouté.