ContactDetails QML Type (Uncreatable)

Le type `ContactDetails` contient les coordonnées d'un Place. En savoir plus...

Remarque : il s'agit d'un type non instanciable. Il ne peut pas être instancié en QML.

• Liste de tous les membres, y compris les membres hérités

Méthodes

• variant keys()

Description détaillée

Le type ContactDetails est une table associative d'objets contactDetail. Pour accéder aux coordonnées contenues dans la table associative, utilisez la méthode keys() afin d'obtenir la liste des clés stockées dans la table, puis utilisez l'opérateur [] pour accéder aux éléments contactDetail.

Les clés suivantes sont définies dans l'API. Les implémentations de ` Plugin ` sont libres de définir des clés supplémentaires.

• phone
• fax
• email
• site web

Les instances `ContactDetails` ne sont utilisées que dans le contexte de ` Places`. Il n'est pas possible de créer directement une instance `ContactDetails` ni de réaffecter des instances `ContactDetails` à ` Places`. La modification de `ContactDetails` ne peut s'effectuer que via JavaScript.

Exemples

L'exemple suivant montre comment accéder à toutes les instances contact details et les afficher dans la console :

import QtPositioning
import QtLocation

function printContactDetails(contactDetails) {
    var keys = contactDetails.keys();
    for (var i = 0; i < keys.length; ++i) {
        var contactList = contactDetails[keys[i]];
        for (var j = 0; j < contactList.length; ++j) {
            console.log(contactList[j].label + ": " + contactList[j].value);
        }
    }
}

La liste des coordonnées renvoyée est une liste d’objets et peut donc être utilisée directement comme modèle de données. Par exemple, le code suivant montre comment afficher une liste de numéros de téléphone dans une vue de liste :

import QtQuick
import QtPositioning
import QtLocation

ListView {
    model: place.contactDetails.phone;
    delegate: Text { text: modelData.label + ": " + modelData.value }
}

L'exemple suivant montre comment attribuer un seul numéro de téléphone à un lieu en JavaScript :

function writeSingle() {
    var phoneNumber = Qt.createQmlObject('import QtLocation; ContactDetail {}', place);
    phoneNumber.label = "Phone";
    phoneNumber.value = "555-5555"
    place.contactDetails.phone = phoneNumber;
}

L'exemple suivant montre comment attribuer plusieurs numéros de téléphone à un lieu en JavaScript :

function writeMultiple() {
    var bob = Qt.createQmlObject('import QtLocation; ContactDetail {}', place);
    bob.label = "Bob";
    bob.value = "555-5555"

    var alice = Qt.createQmlObject('import QtLocation; ContactDetail {}', place);
    alice.label = "Alice";
    alice.value = "555-8745"

    var numbers = new Array();
    numbers.push(bob);
    numbers.push(alice);

    place.contactDetails.phone = numbers;
}

Documentation des méthodes

variant keys()

Renvoie un tableau contenant les clés des coordonnées actuellement stockées dans la table.