PathAttribute QML Type

Indique comment définir un attribut à une position donnée dans un chemin. Plus d'informations...

• Liste de tous les membres, y compris les membres hérités

Propriétés

• name : string
• value : real

Description détaillée

L'objet PathAttribute permet de spécifier des attributs composés d'un nom et d'une valeur pour différents points le long d'un chemin. Les attributs sont exposés au délégué en tant que propriétés attachées. La valeur d'un attribut en un point donné du chemin est interpolée à partir des PathAttributes délimitant ce point.

L'exemple ci-dessous montre un chemin dont les éléments sont mis à l'échelle à 30 % avec une opacité de 50 % en haut du chemin et mis à l'échelle à 100 % avec une opacité de 100 % en bas du chemin. Notez l'utilisation des propriétés jointes PathView.iconScale et PathView.iconOpacity pour définir l'échelle et l'opacité du délégué.

import QtQuick

Rectangle {
    width: 240; height: 200

    Component {
        id: delegate
        Item {
            width: 80; height: 80
            scale: PathView.iconScale
            opacity: PathView.iconOpacity
            Column {
                Image { anchors.horizontalCenter: nameText.horizontalCenter; width: 64; height: 64; source: icon }
                Text { id: nameText; text: name; font.pointSize: 16 }
            }
        }
    }

    PathView {
        anchors.fill: parent
        model: ContactModel {}
        delegate: delegate
        path: Path {
            startX: 120; startY: 100
            PathAttribute { name: "iconScale"; value: 1.0 }
            PathAttribute { name: "iconOpacity"; value: 1.0 }
            PathQuad { x: 120; y: 25; controlX: 260; controlY: 75 }
            PathAttribute { name: "iconScale"; value: 0.3 }
            PathAttribute { name: "iconOpacity"; value: 0.5 }
            PathQuad { x: 120; y: 100; controlX: -20; controlY: 75 }
        }
    }
}

Voir également Path.

Documentation sur les propriétés

name : string

Cette propriété contient le nom de l'attribut à modifier.

Cet attribut sera disponible pour le délégué sous la forme suivante : PathView.<name>

Il est à noter que l'utilisation d'un nom de propriété d'élément existant tel que "opacity" en tant qu'attribut est autorisée. En effet, les attributs de chemin d'accès ajoutent une nouvelle propriété attachée qui n'entre en aucun cas en conflit avec les propriétés existantes.

value : real

Cette propriété contient la valeur de l'attribut.

La valeur spécifiée peut être utilisée pour influencer l'apparence visuelle d'un élément le long du chemin. Par exemple, le chemin suivant spécifie un attribut nommé itemRotation, qui a la valeur 0 au début du chemin, et la valeur 90 à la fin du chemin.

Path {
    startX: 0
    startY: 0
    PathAttribute { name: "itemRotation"; value: 0 }
    PathLine { x: 100; y: 100 }
    PathAttribute { name: "itemRotation"; value: 90 }
}

Dans notre délégué, nous pouvons alors lier la propriété de rotation à la propriété attachée PathView.itemRotation créée pour cet attribut.

Rectangle {
    width: 10; height: 10
    rotation: PathView.itemRotation
}

Lorsque chaque élément est positionné le long du chemin, il est pivoté en conséquence : un élément au début du chemin n'est pas pivoté, un élément à la fin du chemin est pivoté de 90 degrés et un élément à mi-chemin du chemin est pivoté de 45 degrés.