WebEngineAction QML Type

Une action qui représente une WebEngineView::WebAction. Plus....

Import Statement:	`import QtWebEngine`
Since:	QtWebEngine 1.8

Liste de tous les membres, y compris les membres hérités

Propriétés

enabled : bool
iconName : string
text : int

Méthodes

void trigger()

Description détaillée

Une WebEngineAction est renvoyée par la méthode WebEngineView::action(). Elle fournit des informations sur l'action, par exemple si elle est enabled.

Le code suivant utilise la méthode WebEngineView::action() pour vérifier si l'action de copie est activée :

var copyAction = webEngineView.action(WebEngineView.Copy);
if (copyAction.enabled)
    console.log("Copy is enabled.");
else
    console.log("Copy is disabled.");

Un site ToolButton peut être connecté à une WebEngineAction de la manière suivante :

            ToolButton {
                property int itemAction: WebEngineView.Back
                text: webEngineView.action(itemAction).text
                enabled: webEngineView.action(itemAction).enabled
                onClicked: webEngineView.action(itemAction).trigger()
                icon.name: webEngineView.action(itemAction).iconName
                display: AbstractButton.TextUnderIcon
            }

Un menu contextuel pourrait être implémenté comme suit :

        property Menu contextMenu: Menu {
            Repeater {
                model: [
                    WebEngineView.Back,
                    WebEngineView.Forward,
                    WebEngineView.Reload,
                    WebEngineView.SavePage,
                    WebEngineView.Copy,
                    WebEngineView.Paste,
                    WebEngineView.Cut,
                    WebEngineView.ChangeTextDirectionLTR,
                    WebEngineView.ChangeTextDirectionRTL,
                ]
                MenuItem {
                    text: webEngineView.action(modelData).text
                    enabled: webEngineView.action(modelData).enabled
                    onClicked: webEngineView.action(modelData).trigger()
                    icon.name: webEngineView.action(modelData).iconName
                    display: MenuItem.TextBesideIcon
                }
            }
        }

        onContextMenuRequested: function(request) {
            if (customContextMenuOption.checked) {
                request.accepted = true;
                contextMenu.popup();
            }
        }

Documentation sur les propriétés

enabled : bool `[read-only]`

Cette propriété indique si l'action est activée.

iconName : string `[read-only]`

Cette propriété contient le nom de l'icône de l'action. Ce nom peut être utilisé pour sélectionner l'icône dans un thème.

text : int `[read-only]`

Cette propriété contient une description textuelle de l'action.

Documentation de la méthode

void trigger()

Déclenche l'action.

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.