qt_generate_deploy_script

Générer un script de déploiement personnalisé.

La commande est définie dans le composant « Core » du paquet « Qt6 », qui peut être chargé comme suit :

find_package(Qt6 REQUIRED COMPONENTS Core)

Cette commande a été introduite dans Qt 6.5.

Syntaxe

qt_generate_deploy_script(
    OUTPUT_SCRIPT <var>
    [TARGET target]
    [NAME script_name]
    [CONTENT content]
)

Si les commandes sans version sont désactivées, utilisez plutôt qt6_generate_deploy_script(). Elle prend en charge le même ensemble d'arguments que cette commande.

Description

La commande génère un script dont le chemin d'accès complet sera stocké dans la variable nommée par l'option OUTPUT_SCRIPT. Ce script n'est écrit qu'au moment de la génération CMake. Il est destiné à être utilisé avec la commande install(SCRIPT), qui doit intervenir après l'installation de la cible de l'application à l'aide de install(TARGETS).

La commande se charge de générer un fichier dont le nom est adapté aux générateurs multi-configuration. Les inclusions nécessaires sont ajoutées afin que les fonctions et variables de déploiement CMake de Qt soient accessibles.

L’argument ` TARGET ` spécifie la cible qui sera déployée par le script. Cela influe sur le nom du fichier du script généré, sauf si l’argument ` NAME ` est spécifié.

L’argument ` NAME ` contrôle une partie identifiable du nom généré automatiquement pour le script de déploiement. L’argument ` NAME ` prend par défaut la valeur ` custom ` si ni ` NAME ` ni ` TARGET ` ne sont fournis.

L’argument CONTENT spécifie le code qui sera écrit dans le script de déploiement. Le contenu peut contenir des expressions de générateur.

Cette commande est destinée à générer des scripts de déploiement personnalisés qui appellent directement les fonctions de l’API de déploiement de Qt. Pour des besoins de déploiement moins complexes, il est plus pratique d’utiliser qt_generate_deploy_app_script() ou qt_generate_deploy_qml_app_script().

Exemple

cmake_minimum_required(VERSION 3.16...3.22)
project(MyThings)

find_package(Qt6 REQUIRED COMPONENTS Core)
qt_standard_project_setup()

qt_add_executable(MyApp main.cpp)

install(TARGETS MyApp
    BUNDLE  DESTINATION .
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

qt_generate_deploy_script(
    TARGET MyApp
    OUTPUT_SCRIPT deploy_script
    CONTENT "
qt_deploy_runtime_dependencies(
    EXECUTABLE $<TARGET_FILE:MyApp>
)
")
install(SCRIPT ${deploy_script})