Affichage de texte

Pour afficher du texte, le type Text est fourni par le Qt Quick module. Pour des utilisations connexes, les types « TextInput » et « TextEdit » fournissent des contrôles de texte modifiables. Pour le balisage HTML complet, consultez le module « Qt WebEngine ».

Affichage et mise en forme du texte

Pour afficher du texte en QML, créez un élément « Text » et définissez la propriété « text » sur le texte que vous souhaitez afficher. L’élément « Text » affichera alors ce texte.

Plusieurs propriétés peuvent être définies sur l’élément « Text » pour styliser l’ensemble du bloc de texte. Il s’agit notamment de la couleur, de la famille de polices, de la taille de police, du gras et de l’italique. Pour obtenir la liste complète des propriétés, consultez la documentation relative au type « Text ».

Du texte enrichi, tel que du balisage, peut être utilisé pour styliser de manière sélective des sections spécifiques de texte avec un élément « Text ». Définissez la propriété « Text::textFormat » sur « Text.StyledText » pour utiliser cette fonctionnalité. Vous trouverez plus de détails dans la documentation du type « Text ».

Mise en page du texte

Par défaut, l’élément Text affiche le texte sur une seule ligne, sauf s’il contient des sauts de ligne intégrés. Pour forcer le retour à la ligne, définissez la propriété wrapMode et attribuez au texte une largeur explicite à ne pas dépasser. Si la largeur ou la hauteur n’est pas explicitement définie, la lecture de ces propriétés renverra les paramètres du rectangle de délimitation du texte (si vous avez explicitement défini la largeur ou la hauteur, vous pouvez toujours utiliser paintedWidth et paintedHeight). En tenant compte de ces paramètres, le Text peut être positionné comme n’importe quel autre Item.

Exemple de code

import QtQuick

Item {
    id: root
    width: 480
    height: 320

    Rectangle {
        color: "#272822"
        width: 480
        height: 320
    }

    Column {
        spacing: 20

        Text {
            text: 'I am the very model of a modern major general!'

            // color can be set on the entire element with this property
            color: "yellow"

        }

        Text {
            // For text to wrap, a width has to be explicitly provided
            width: root.width

            // This setting makes the text wrap at word boundaries when it goes
            // past the width of the Text object
            wrapMode: Text.WordWrap

            // You can use \ to escape quotation marks, or to add new lines (\n).
            //  Use \\ to get a \ in the string
            text: 'I am the very model of a modern major general. I\'ve information \
                  vegetable, animal and mineral. I know the kings of england and I \
                  quote the fights historical; from Marathon to Waterloo in order categorical.'

            // color can be set on the entire element with this property
            color: "white"

        }

        Text {
            text: 'I am the very model of a modern major general!'

            // color can be set on the entire element with this property
            color: "yellow"

            // font properties can be set effciently on the whole string at once
            font { family: 'Courier'; pixelSize: 20; italic: true; capitalization: Font.SmallCaps }

        }

        Text {
            // HTML like markup can also be used
            text: '<font color="white">I am the <b>very</b> model of a modern <i>major general</i>!</font>'

            // This could also be written font { pointSize: 14 }. Both syntaxes are valid.
            font.pointSize: 14

            // StyledText format supports fewer tags, but is more efficient than RichText
            textFormat: Text.StyledText
        }
    }
}

Internationalisation et évolutivité

Lorsqu’elles traitent des textes, les applications doivent prendre en compte divers aspects tels que l’orientation de l’appareil et les paramètres linguistiques.

Les pages suivantes abordent ces différents aspects en détail.

• Interfaces utilisateur de droite à gauche
• Internationalisation avec Qt
• Évolutivité