構文

この警告カテゴリは、qmllint では「[syntax] 」と表記されます。

ネストされたインラインコンポーネントはサポートされていません

何が起きたのか？

別のインラインコンポーネントの内部でインラインコンポーネントを定義しました。

なぜ問題なのですか？

QML 言語では、インラインコンポーネントのネストは許可されていません。インラインコンポーネントは、常に QML ファイルのルートアイテム内で定義してください。

例

import QtQuick

Item {
    component Correct: Item {
        component Evil: Item { ... }
        ...
    }
}

この警告を解消するには、すべてのコンポーネントをQMLファイルのルートアイテムに移動してください。

import QtQuick

Item {
    component NotEvilAnymore: Item { ... }
    component Correct: Item {
        ...
    }
}

インラインコンポーネントの宣言の後には、型名が続く必要があります

何が起きたのですか？

無効な基底型を使用してインラインコンポーネントを定義しました。

なぜこれが問題なのでしょうか？

インラインコンポーネントには、継承元のベース型が必要です。

例

import QtQuick

Item {
    property Item someProperty
    component InlineComponent: someProperty {}
}

この場合、「someProperty 」はプロパティ名であるため、有効な型名ではありません。この警告を解消するには、コンポーネントの基底型として有効な型を使用してください：

import QtQuick

Item {
    property Item someProperty
    component InlineComponent: Item { ... }
}

無効なエイリアス式：初期化子が必要です

何が起きたのですか？

エイリアス対象のプロパティを定義せずに、プロパティエイリアスを定義しました。

なぜ問題なのでしょうか？

エイリアスプロパティの定義には、常にエイリアスの対象となるプロパティまたは ID を指定する必要があります。

例

import QtQuick

Item {
    id: root
    property int someProperty
    property alias aliasProperty
}

この警告を解消するには、エイリアスを通常のプロパティに置き換えるか、欠落しているエイリアスの対象となるプロパティを追加してください：

import QtQuick

Item {
    id: root
    property int someProperty
    property alias withAliasedProperty: root.someProperty
}

無効なエイリアス式：エイリアスに指定できるのは ID およびフィールドメンバー式のみです

何が起きたのですか？

ID またはフィールドメンバー式以外の式をエイリアスするプロパティエイリアスを定義しました。

フィールドメンバ式とは、someId.someProperty という形式の式のことです。

なぜこれが問題なのでしょうか？

エイリアスプロパティは、その定義にエイリアスされるプロパティを常に含める必要があり、ID およびフィールドメンバ式以外の式にはバインドできません。

例

import QtQuick

Item {
    property int p
    property alias someProperty: p + 1
}

この警告を解消するには、エイリアスを通常のプロパティに置き換えるか、ID またはフィールドメンバ式にバインドしてください。

import QtQuick

Item {
    id: root
    property int p
    property int someProperty: p + 1
    property alias alternative: root.p
}

ID の後には識別子が続く必要があります

何が起きたのでしょうか？

値を指定せずにIDを定義しました。

なぜこれが問題なのでしょうか？

QML 言語では、空の ID は許可されていません。

例

import QtQuick

Item {
    id:;
}

この警告を解消するには、ID を有効な名前にバインドしてください：

import QtQuick

Item {
    id: root;
}

ID の解析に失敗しました

何が起きたのですか？

IDを名前以外の式にバインドしました。

なぜ問題なのでしょうか？

QML言語では、IDへのバインディングとして名前のみが許可されており、より複雑な式は使用できません。

例

import QtQuick

Item {
    property int a
    property int b
    function f() {
        if (true)
            return a
        return b
    }

    id: f()
}

この警告を解消するには、IDを有効な名前にバインドするか、プロパティを宣言してバインディングを設定してください:

import QtQuick

Item {
    property int a
    property int b
    function f() {
        if (true)
            return a
        return b
    }

    id: someItem // it would be confusing to call it `f` like the function
    property int alternative: f()
}

QML オブジェクトではないオブジェクトをリストのメンバーとして宣言しています

何が起きたのでしょうか？

オブジェクト以外の式を、オブジェクトのリストに追加してしまいました。

なぜこれが問題なのでしょうか？

QML 言語では、オブジェクトのリストにはオブジェクトのみを含めることができます。

例

import QtQuick

Item {
    property int hello
    property list<Item> myList: [
        Item {}, hello{}
    ]
}

この警告を解消するには、有効なオブジェクト型を使用するか、リストからその項目を削除してください：

import QtQuick

Item {
    component Hello: Item {}
    property list<Item> myList: [
        Item {}, Hello{}
    ]
}

pragma に対する引数が不明です

何が起きたのですか？

pragma に対して無効な引数を指定しました。

なぜ問題なのでしょうか？

そのプラグマは効果を発揮しません。

例

pragma ComponentBehavior: Buond
import QtQuick

Item {
}

この警告は、プラグマを削除するか、タイプミスを修正することで解消できます：

pragma ComponentBehavior: Bound
import QtQuick

Item {
}

シグナルハンドラのパラメータ IDの重複

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.