Back to Qt.io
Contact Us Blog Download Qt
이 페이지에서

Ubuntu 호스트에서 Qt 빌드하기 모놀리식 프로젝트 빌드하기

Ubuntu에서 Qualcomm Snapdragon 8155P 보드용 Qt 빌드하기

진행하기 전에 Green Hills INTEGRITY 및 Qualcomm 개발 환경을 설정해야 합니다. ‘플랫폼 종속성 설치’를 참조하십시오.

환경 설정 셸 스크립트 생성

Qt for INTEGRITY용 개발 환경을 설정하려면 Qualcomm Snapdragon 8155P 보드용 소스 코드를 사용하여 Qt를 빌드하십시오. Qt for INTEGRITY를 빌드하기 전에 빌드 환경을 설정해야 합니다. 이 작업은 매번 빌드 전에 수행되어야 하므로, 이를 자동화하는 배치 스크립트를 다음과 같이 제공합니다.

새로운 셸 스크립트 setEnvironment.sh를 생성하여 홈 폴더에 저장하십시오. 스크립트에 다음 export 명령을 추가하십시오:

export PATH=$PATH:/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/comp
export INTEGRITY_DIR=/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/integrity
export INTEGRITY_BSP=platform-sa8155
export INTEGRITY_BUILD_TARGET=chk
export QC_MULTIMEDIA_INC_DIR=/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/include/amss/multimedia
export GL_INC_DIR=/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/AMSS/multimedia/graphics/include/public
export GL_LIB_DIR=/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/out/rel/libs/base:/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/out/rel/libs/multimedia/display:/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/out/rel/libs/multimedia/graphics:/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/out/rel/libs/platform/:/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/AMSS/multimedia/graphics/opengl/esx/build/integrity/prebuilt/

이 export 경로는 MULTI IDE 및 INTEGRITY를 설치할 때 /work/ghs/* 설치 디렉터리를 사용했다고 가정합니다( ‘플랫폼 종속성 설치’ 참조). 기본 디렉터리를 사용하지 않은 경우, export 경로를 그에 맞게 조정하십시오.

빌드 환경을 초기화하려면 터미널에서 다음 명령을 실행하십시오:

source ~/setEnvironment.sh

참고: Qt를 빌드하거나 qmake 또는 CMake 빌드 시스템을 사용할 때마다 터미널에서 이 명령을실행하십시오 .

Qt 소스 가져오기

Qt 계정에서 Qt 소스 코드를 다운로드할 수 있습니다.

Git 저장소에서 Qt 소스 코드를 가져올 수도 있습니다. 자세한 내용은 ‘소스 코드 가져오기’를 참조하십시오.

참고: Qt 소스 코드의 버전은 6.2 이상이어야 합니다.

참고: Qt for INTEGRITY에서 지원하는Qt 모듈 은 ‘지원되는 Qt 모듈’에 나열되어 있습니다.

크로스 컴파일 도구 사용을 위한 Qt Desktop 빌드

Qt를 크로스 컴파일하려면 호스트용 Qt 빌드가 준비되어 있어야 합니다. 빌드 과정에서 moc, rcc, qmlcachegen, qsb 등의 도구가 해당 호스트에서 호출됩니다. 더 자세한 내용은 ‘Qt 크로스 컴파일’을 참조하십시오.

다음 명령어를 실행하십시오:

mkdir hostbuild
cd hostbuild/
../qt5/configure -nomake tests -nomake examples -release -prefix /work/ghs/hostbuild
cmake --build . --parallel 6
cmake --install .

참고: ` ninja ` 실행 파일이 있는 경우,`configure `는 항상 Ninja 생성기 및 빌드 도구를 사용합니다. Ninja는 크로스 플랫폼 지원이 가능하며, 기능이 풍부하고 성능이 뛰어나 모든 플랫폼에서 권장됩니다. 다른 생성기를 사용해도 작동할 수는 있지만, 공식적으로 지원되지는 않습니다.

INTEGRITY용 툴체인 파일 생성

CMake를 사용하여 프로젝트를 크로스 컴파일하려면 툴체인 파일을 지정해야 합니다. 이 CMake 언어 파일은 플랫폼 이름, 사용되는 컴파일러/링커, 그리고 툴체인에 특화된 다양한 항목들에 대한 올바른 값을 설정합니다. Ubuntu에서 Integrity를 빌드하려면 다음 내용을 포함하는 toolchain.cmake 파일을 생성하십시오:

# Copyright (C) 2022 The Qt Company Ltd.
# SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

set(TARGET_ROOT_PATH "/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot")
set(CMAKE_BUILD_TYPE "Release")

set(CMAKE_C_COMPILER cxintarm64)
set(CMAKE_CXX_COMPILER cxintarm64)
set(CMAKE_ASM_COMPILER cxintarm64)

#generic
set(CMAKE_SYSTEM_NAME Integrity)
set(CMAKE_SYSTEM_PROCESSOR arm)
set(CMAKE_CROSSCOMPILING True)

set(EGL_FOUND True)
set(UNIX True)

set (CMAKE_C_COMPILE_FEATURES c_std_99)
set (CMAKE_CXX_COMPILE_FEATURES
cxx_alias_templates
cxx_alignas
cxx_alignof
cxx_attributes
cxx_auto_type
cxx_constexp
cxx_decltype
cxx_delegating_constructors
cxx_explicit_conversions
cxx_extern_templates
cxx_inheriting_constructors
cxx_lambdas
cxx_noexcept
cxx_nonstatic_member_init
cxx_nullptr
cxx_override
cxx_range_for
cxx_raw_string_literals
cxx_reference_qualified_functions
cxx_rvalue_references
cxx_static_assert
cxx_std_17
cxx_thread_local
cxx_unicode_literals
cxx_uniform_initialization
cxx_unrestricted_unions
cxx_variadic_macros
cxx_variadic_templates)

#graphical lib paths
set(EGL_LIBRARY_GRAPHIC_PATH ${TARGET_ROOT_PATH}/apps/ghs_apps_proc/qc_bsp/out/chk/libs/multimedia/graphics)
set(EGL_LIBRARY_PLATFORM_PATH ${TARGET_ROOT_PATH}/apps/ghs_apps_proc/qc_bsp/out/chk/libs/platform)
set(EGL_LIBRARY_BASE_PATH ${TARGET_ROOT_PATH}/apps/ghs_apps_proc/qc_bsp/out/chk/libs/base)
set(EGL_LIBRARY_CHK_PATH ${TARGET_ROOT_PATH}/apps/ghs_apps_proc/integrity/libs/arm64/chk)
set(EGL_LIBRARY_PREBUILD_PATH ${TARGET_ROOT_PATH}/apps/ghs_apps_proc/qc_bsp/AMSS/multimedia/graphics/opengl/esx/build/integrity/prebuilt)
set(EGL_LIBRARY_OPENWFD_PATH ${TARGET_ROOT_PATH}/apps/ghs_apps_proc/qc_bsp/out/chk/libs/multimedia/display)

#base
set(CMAKE_C_FLAGS  "-bsp $ENV{INTEGRITY_BSP} -os_dir $ENV{INTEGRITY_DIR} -non_shared -startfile_dir=$ENV{INTEGRITY_DIR}/libs/$ENV{INTEGRITY_BSP}/$ENV{INTEGRITY_BUILD_TARGET} --rtos_library_directory=libs/$ENV{INTEGRITY_BSP}/$ENV{INTEGRITY_BUILD_TARGET} --rtos_library_directory=libs/arm64/$ENV{INTEGRITY_BUILD_TARGET} -bigswitch -DINTEGRITY -llibposix.a")
set(CMAKE_C_FLAGS_DEBUG "-g -Omaxdebug")
set(CMAKE_C_FLAGS_RELEASE "-Ospeed -Olink -Omax -no_uvfd")
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} --signed_fields --diag_suppress=1,82,228,236,381,611,961,997,1795,1931,1974,3148 --c++17 --thread_local_storage --exceptions --defer_parse_function_templates")
set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -frigor=accurate --signed_fields --no_implicit_include --link_once_templates -non_shared --new_outside_of_constructor --commons -I $ENV{QC_MULTIMEDIA_INC_DIR}")
set(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
set(CMAKE_FIND_LIBRARY_PREFIXES "lib")
set(CMAKE_FIND_LIBRARY_SUFFIXES ".a")
set(BUILD_SHARED_LIBS OFF)
set(QT_CFLAGS_OPTIMIZE_FULL "-Ospeed -Olink -Omax -no_uvfd")
set(GLSLANG_OSDEP_PATH ../3rdparty/glslang/glslang/OSDependent/Unix)
set(GL_INC_DIR ${TARGET_ROOT_PATH}/apps/ghs_apps_proc/qc_bsp/AMSS/multimedia/graphics/include/public)
set(PKG_EGL_LIBRARY_DIRS ${TARGET_ROOT_PATH})

set(EGL_INCLUDE_DIR ${GL_INC_DIR})
set(EGL_LIBRARY "${EGL_LIBRARY_GRAPHIC_PATH}/libESXEGL_Adreno.a")

set(GLESv2_INCLUDE_DIR ${GL_INC_DIR})
set(GLESv2_LIBRARY "${EGL_LIBRARY_GRAPHIC_PATH}/libESXGLESv2_Adreno.a")

set(IntegrityPlatformGraphics_INCLUDE_DIR ${GL_INC_DIR})
set(IntegrityPlatformGraphics_LIBRARY "${EGL_LIBRARY_GRAPHIC_PATH}/libadreno_utils.a")
set(IntegrityPlatformGraphics_LIBRARIES_PACK
    "${EGL_LIBRARY_BASE_PATH}/libplanedef.a"
    "${EGL_LIBRARY_BASE_PATH}/libmmosalfile.a"
    "${EGL_LIBRARY_BASE_PATH}/libOSAbstraction.a"
    "${EGL_LIBRARY_OPENWFD_PATH}/libopenwfd.a"
    "${EGL_LIBRARY_GRAPHIC_PATH}/libOSUser.a"
    "${EGL_LIBRARY_GRAPHIC_PATH}/libpanel.a"
    "${EGL_LIBRARY_GRAPHIC_PATH}/libGSLUser.a"
    "${EGL_LIBRARY_PREBUILD_PATH}/libglnext-llvm.a"
    "${EGL_LIBRARY_PLATFORM_PATH}/libpmem.a"
    "${EGL_LIBRARY_CHK_PATH}/libposix.a"
    "${EGL_LIBRARY_CHK_PATH}/libivfs.a"
)

list(APPEND _qt_igy_gui_libs
    "${GLESv2_LIBRARY}"
    "${IntegrityPlatformGraphics_LIBRARY}"
    "${IntegrityPlatformGraphics_LIBRARIES_PACK}")

set(OPENGL_INCLUDE_DIR ${GL_INC_DIR})
set(OPENGL_opengl_LIBRARY ${EGL_LIBRARY})

INTEGRITY용 Qt 구성

다음 명령어를 사용하여 Qualcomm Snapdragon 8155P 보드용 Qt를 구성하십시오:

cd /work/ghs/targetbuild // Path to Qt installation directory
cmake ../qt5/ -DQT_HOST_PATH=/work/ghs/hostbuild/qtbase
-DCMAKE_TOOLCHAIN_FILE=/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/toolchain_integrity.cmake
-DQT_QMAKE_TARGET_MKSPEC=devices/integrity-armv8-SA8155P -DBUILD_qtdoc=OFF
-DBUILD_qttranslations=OFF -DFEATURE_printdialog=OFF --debug-trycompile -DFEATURE_dbus=OFF
-GNinja -DUNIX=ON
-DEGL_LIBRARY=/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/libeglmegapack.a
-DEGL_INCLUDE_DIR=/work/ghs/sa8155/es7/es7_dev_env/hlos_dev_boot/apps/ghs_apps_proc/qc_bsp/AMSS/multimedia/graphics/include/public
-DFEATURE_dnslookup=OFF -DFEATURE_glib=OFF -DFEATURE_libudev=OFF -DFEATURE_system_pcre2=OFF -DFEATURE_sql_mysql=OFF
-DCMAKE_INSTALL_PREFIX=/work/ghs/targetbuild

참고: INTEGRITY는 정적 Qt 빌드만 지원합니다.

참고: ` QT_HOST_PATH ` 변수는 Qt 6에서 도입되었습니다. 크로스 컴파일 시, 이 변수는 호스트 플랫폼용 Qt의 설치 위치로 설정되어야 합니다. 이 변수는 호스트에서 실행될 도구(moc, rcc, androiddeployqt 등)의 위치를 찾는 데 사용됩니다.

INTEGRITY용 Qt 빌드

터미널에서 cmake 를 호출하여 Qt를 빌드합니다. 호스트 머신의 코어 수를 원하는 만큼 지정하여 cmake 를 실행할 수 있습니다. 이 예제에서는 6개의 코어를 사용합니다:

cmake --build . --parallel 6

Qt 설치하기

'Qt 구성' 섹션에서 -prefix $PWD/qtbase 구성 옵션을 사용하지 않았다면, 터미널에서 다음 명령을 실행하십시오:

cd <Qt installation directory>
cmake --install .

-prefix $PWD/qtbase 구성 옵션을 사용한 경우, ` cmake install ` 명령을 실행하지 않고도 빌드 디렉터리에서 Qt를 사용할 수 있습니다.

이제 Qt가 sa8155 보드용으로 구성 및 빌드되었습니다.

Ubuntu 호스트에서 Qt 빌드하기 모놀리식 프로젝트 빌드하기

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.