MenuItemGroup QML Type

기본 메뉴 항목을 관리하기 위한 그룹입니다. 더 보기...

• 상속된 멤버를 포함한 모든 멤버 목록

속성

• checkedItem : MenuItem
• enabled : bool
• exclusive : bool
• items : list<MenuItem>
• visible : bool

신호

• hovered(MenuItem item)
• triggered(MenuItem item)

방법

• void addItem(MenuItem item)
• void clear()
• void removeItem(MenuItem item)

상세 설명

MenuItemGroup은 기본 메뉴 항목들을 한데 묶어줍니다.

MenuItemGroup은 기본적으로 배타적입니다. 배타적인 메뉴 항목 그룹에서는 한 번에 하나의 항목만 선택할 수 있으며, 다른 항목을 선택하면 이전에 선택되었던 항목의 선택이 자동으로 해제됩니다. MenuItemGroup을 비배타적으로 구성할 수 있으며, 이는 항목을 그룹 단위로 함께 표시, 숨김, 활성화 및 비활성화하는 데 특히 유용합니다.

MenuItemGroup을 사용하는 가장 간단한 방법은 항목 목록을 할당하는 것입니다.

Menu {
    id: verticalMenu
    title: qsTr("Vertical")

    MenuItemGroup {
        id: verticalGroup
        items: verticalMenu.items
    }

    MenuItem { text: qsTr("Top"); checkable: true }
    MenuItem { text: qsTr("Center"); checked: true }
    MenuItem { text: qsTr("Bottom"); checkable: true }
}

때로는 동일한 메뉴에 서로 배타적인 그룹에 포함되어서는 안 되는 항목이 포함될 수 있습니다. 이러한 경우는 group 속성을 사용하여 처리하는 것이 가장 좋습니다.

Menu {
    id: horizontalMenu
    title: qsTr("Horizontal")

    MenuItemGroup {
        id: horizontalGroup
    }

    MenuItem {
        checked: true
        text: qsTr("Left")
        group: horizontalGroup
    }
    MenuItem {
        checkable: true
        text: qsTr("Center")
        group: horizontalGroup
    }
    MenuItem {
        text: qsTr("Right")
        checkable: true
        group: horizontalGroup
    }

    MenuItem { separator: true }
    MenuItem { text: qsTr("Justify"); checkable: true }
    MenuItem { text: qsTr("Absolute"); checkable: true }
}

더 고급 사용 사례는 ` addItem()` 및 ` removeItem()` 메서드를 사용하여 처리할 수 있습니다.

MenuItem도 참조하십시오 .

속성 문서

checkedItem : MenuItem

이 속성은 그룹에서 현재 선택된 항목을 저장하며, 선택된 항목이 없는 경우에는 ` null `을 저장합니다.

enabled : bool

이 속성은 그룹이 활성화되어 있는지 여부를 나타냅니다. 기본값은 ‘ true ’입니다.

그룹의 활성화 상태는 그룹 내 각 항목의 활성화 상태에 영향을 미치지만, 명시적으로 비활성화된 항목은 그룹이 활성화되어 있더라도 활성화되지 않습니다.

exclusive : bool

이 속성은 그룹이 배타적인지 여부를 나타냅니다. 기본값은 ‘ true ’입니다.

배타적인 메뉴 항목 그룹에서는 한 번에 하나의 항목만 선택할 수 있으며, 다른 항목을 선택하면 이전에 선택했던 항목의 선택이 자동으로 해제됩니다.

items : list<MenuItem>

이 속성은 그룹에 포함된 항목들의 목록을 담고 있습니다.

visible : bool

이 속성은 그룹이 표시되는지 여부를 나타냅니다. 기본값은 ‘ true ’입니다.

그룹의 표시 여부는 그룹 내 각 항목의 표시 여부에 영향을 미치지만, 명시적으로 숨겨진 항목은 그룹이 표시되어 있더라도 표시되지 않습니다.

Signal 문서

hovered(MenuItem item)

그룹 내의 ‘ item ’ 위에 사용자가 마우스를 올릴 때 이 신호가 발생합니다.

MenuItem::hovered()도 참조하십시오 .

triggered(MenuItem item)

이 신호는 그룹 내의 item 가 사용자에 의해 트리거될 때 발생합니다.

MenuItem::triggered()도 참조하십시오 .

메서드 설명

void addItem(MenuItem item)

그룹에 ` item `를 추가합니다.

void clear()

그룹에서 모든 항목을 제거합니다.

void removeItem(MenuItem item)

그룹에서 ‘ item ’를 제거합니다.