C

Telltales: Rendering Safety-Critical UI

TEMPLATE = app
TARGET = telltales
SOURCES = main.cpp
HEADERS += events.h

QT = qtsaferenderer qsrplatformadaptation

qnx {
    target.path = $$[QT_INSTALL_EXAMPLES]/saferenderer/telltales/qnx
    INSTALLS = target
} else:integrity {
    for(p, QMAKE_LIBDIR_EGL) {
        LIBS += -L$$p
    }
    LIBS += -lsrv_init -lmmgr_usr -lwm_usr -lprr_usr -lpool -livfs
    DEFINES += Q_OS_INTEGRITY
    DEFINES += IPMMU_VMR_INT_FIRST=0x0000000080000000
    DEFINES += IPMMU_VMR_INT_LAST=0x00000000BFFFFFFF
    INCLUDEPATH += $$[QT_INSTALL_HEADERS]
    INCLUDEPATH += $$QMAKE_INCDIR_EGL
    INCLUDEPATH += ../../../src/saferenderer
} else:boot2qt {
    CONFIG += resources
    SUBDIRS += valuesource
} else {
    DEFINES += QSR_HOST_BUILD
    QT += core gui
}

CONFIG += qtsafercctool exceptions
target.path = $$[QT_INSTALL_EXAMPLES]/saferenderer/telltales

layoutdata.files += ../layoutdata.qrc
layoutdata.path = $$[QT_INSTALL_EXAMPLES]/saferenderer

INSTALLS = target layoutdata
SAFE_RESOURCES += \
    $$PWD/../layoutdata.qrc

OTHER_FILES += layoutdata.qrc