CustomTheme QML Type

Define un tema personalizado con nombre. Más...

• Lista de todos los miembros, incluidos los heredados

Propiedades

• name : string
• theme : Component

Descripción detallada

CustomTheme le permite añadir temas adicionales más allá de light y dark. Mientras que los temas claros y oscuros se aplican automatically basándose en el esquema de colores del sistema operativo, un CustomTheme debe ser activado explícitamente por la aplicación. Aparte de esta diferencia, todos los temas funcionan igual.

Puede definir cualquier número de temas personalizados dentro de un Style.

Style {
    CustomTheme {
        name: "HighContrast"
        theme: Theme {
            control.background.color: "white"
            control.background.border.color: "black"
            control.background.border.width: 2
        }
    }

    CustomTheme {
        name: "Sepia"
        theme: Theme {
            control.text.color: "#5b4636"
            control.background.color: "#f4ecd8"
            control.background.border.color: "#c8b99a"
            applicationWindow.background.color: "#efe6d0"
        }
    }
}

Para activar un CustomTheme, configure Style::themeName con su nombre desde la aplicación:

ComboBox {
    model: StyleKit.style.themeNames
    onCurrentTextChanged: StyleKit.style.themeName = currentText
}

También puede establecer un CustomTheme como tema predeterminado al inicio:

ApplicationWindow {
    width: 1024
    height: 800
    visible: true

    StyleKit.style: MyStyleKitStyle {
        themeName: "HighContrast"
    }
}

Los temas personalizados definidos en un Estilo pueden consultarse en tiempo de ejecución desde Style::customThemeNames o Style::themeNames.

Véase también Theme, Style::themeName, y Style::customThemeNames.

Documentación de propiedades

name : string

El nombre de este tema. Es el valor que se asigna a Style::themeName para activarlo.

theme : Component

El componente Theme que define el tema. Sólo se instanciará cuando se active el tema.

Las propiedades no definidas en el tema vuelven a las definidas en Style.