SignalTransition QML Type
El tipo SignalTransition proporciona una transición basada en una señal de Qt. Más información...
| Import Statement: | import QtQml.StateMachine 6.12 |
| Inherits: |
Propiedades
Descripción detallada
SignalTransition forma parte de la API QML de «Qt State Machine ».
Ejemplo de uso
import QtQuick
import QtQml.StateMachine as DSM
Rectangle {
DSM.StateMachine {
id: stateMachine
initialState: state
running: true
DSM.State {
id: state
DSM.SignalTransition {
targetState: finalState
signal: button.clicked
guard: guardButton.checked
}
}
DSM.FinalState {
id: finalState
}
onFinished: Qt.quit()
}
Row {
spacing: 2
Button {
id: button
text: "Finish state"
}
Button {
id: guardButton
checkable: true
text: checked ? "Press to block the SignalTransition" : "Press to unblock the SignalTransition"
}
}
}Véase también StateMachine, FinalState y TimeoutTransition.
Documentación de la propiedad
guard : bool
Las condiciones de guardia influyen en el comportamiento de una máquina de estados, ya que permiten las transiciones solo cuando su resultado es verdadero y las desactivan cuando es falso.
Cuando se emite la señal asociada a esta transición de señal, se evalúa la condición de guardia. En la condición de guardia, los argumentos de la señal pueden utilizarse tal y como se muestra en el ejemplo siguiente.
import QtQuick
import QtQml.StateMachine as DSM
Rectangle {
Button {
anchors.fill: parent
id: button
DSM.StateMachine {
DSM.State {
DSM.SignalTransition {
targetState: finalState
signal: button.mysignal
// the guard condition uses the mystr string argument from mysignal
guard: mystr == "test"
}
}
DSM.FinalState {
id: finalState
}
}
// define the signal the SignalTransition is connected with
signal mysignal(mystr: string)
// on clicking the button emit the signal with a single string argument
onClicked: button.mysignal("test")
}
}Véase también signal.
signal : signal
La señal asociada a esta transición de señal.
import QtQuick
import QtQml.StateMachine as DSM
Rectangle {
Button {
anchors.fill: parent
id: button
DSM.StateMachine {
DSM.State {
DSM.SignalTransition {
targetState: finalState
signal: button.clicked
}
}
DSM.FinalState {
id: finalState
}
}
}
}© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.