Application QML Type (Singleton)

Proporciona acceso a las propiedades globales del estado de la aplicación compartidas por muchos componentes QML. Más...

Nota: Este tipo es un singleton QML. Sólo hay una instancia de este tipo en el motor QML.

• Lista de todos los miembros, incluidos los heredados
• Miembros obsoletos

Propiedades

• arguments : list<string>
• displayName : string
• domain : string
• font : font
• layoutDirection : enumeration
• name : string
• organization : string
• screens : list<Screen>
• state : enumeration
• styleHints : StyleHints
• supportsMultipleWindows : bool
• version : string

Señales

• aboutToQuit()

Descripción detallada

El singleton Application expone un subconjunto de las propiedades de QApplication a las aplicaciones QML.

También proporciona una señal aboutToQuit(), que es la misma que QCoreApplication::aboutToQuit().

import QtQuick

Window {
    id: root
    visible: true
    width: 800
    height: 680

    title: `${Application.name} (${Application.version})`

    Connections {
        target: Application
        function onAboutToQuit() {
            console.log("Bye!")
        }
    }
}

Véase también SystemPalette.

Documentación de propiedades

arguments : list<string>

Se trata de una lista de cadenas de los argumentos con los que se invocó al ejecutable.

displayName : string

Esta propiedad representa el nombre para mostrar de la aplicación establecido en la instancia QGuiApplication. Se puede escribir en esta propiedad para establecer el nombre de visualización de la aplicación.

Binding {
    target: Application
    property: "displayName"
    value: "My Awesome Application"
}

domain : string

Es el dominio de la organización establecido en la instancia QCoreApplication. Se puede escribir en esta propiedad para establecer el dominio de la organización.

font : font [read-only]

Devuelve la fuente predeterminada de la aplicación tal y como la devuelve QGuiApplication::font().

layoutDirection : enumeration [read-only]

Esta propiedad de sólo lectura puede utilizarse para consultar la dirección de diseño por defecto de la aplicación. Al iniciarse el sistema, la dirección predeterminada del diseño depende del idioma de la aplicación. La propiedad tiene un valor de Qt.RightToLeft en locales donde el texto y los elementos gráficos se leen de derecha a izquierda, y Qt.LeftToRight donde la dirección de lectura fluye de izquierda a derecha. Puede enlazar a esta propiedad para personalizar los diseños de su aplicación para que soporten ambas direcciones de diseño.

Consulte el enum de C++ Qt::LayoutDirection para conocer los valores posibles.

RowLayout {
    layoutDirection: Application.layoutDirection
}

name : string

Es el nombre de la aplicación establecido en la instancia QCoreApplication. Se puede escribir en esta propiedad para establecer el nombre de la aplicación.

organization : string

Es el nombre de la organización establecido en la instancia QCoreApplication. Se puede escribir en esta propiedad para establecer el nombre de la organización.

screens : list<Screen> [read-only]

Un array que contiene las descripciones de todas las pantallas conectadas. Los elementos del array son objetos con las mismas propiedades que el objeto conectado Screen. En la práctica, la matriz corresponde a la lista de pantallas devuelta por QGuiApplication::screens(). Además de examinar propiedades como el nombre, la anchura, la altura, etc., los elementos del array también pueden asignarse a la propiedad screen de los elementos Window, sirviendo así como alternativa a QWindow::setScreen() de C++.

Véase también Screen, Window, y Window.screen.

state : enumeration [read-only]

Esta propiedad representa el estado actual de la aplicación.

Consulte el enum de C++ Qt::ApplicationState para conocer los valores posibles.

Timer {
    interval: 1000; repeat: true
    active: Application.state === Qt.ApplicationActive
    onTriggered: imageFetcher.fetchLatestImages()
}

styleHints : StyleHints [read-only]

La propiedad styleHints proporciona sugerencias y ajustes de estilo específicos de la plataforma. Consulte la documentación de QStyleHints para más detalles.

El siguiente ejemplo utiliza styleHints para determinar si un elemento debe obtener el foco al pulsar el ratón o al soltarlo:

import QtQuick

MouseArea {
    id: button

    onPressed: {
        if (!Application.styleHints.setFocusOnTouchRelease)
            button.forceActiveFocus()
    }
    onReleased: {
        if (Application.styleHints.setFocusOnTouchRelease)
            button.forceActiveFocus()
    }
}

supportsMultipleWindows : bool [read-only]

Devuelve true si la plataforma admite múltiples ventanas. Algunas plataformas embebidas no soportan múltiples ventanas, por ejemplo.

version : string

Es la versión de la aplicación establecida en la instancia QCoreApplication. Se puede escribir en esta propiedad para establecer la versión de la aplicación.

Documentación de la señal

aboutToQuit()

Esta señal se emite cuando la aplicación está a punto de salir del bucle de eventos principal. La señal es particularmente útil si su aplicación tiene que hacer alguna limpieza de último momento. La interacción con el usuario no es posible en este estado. Para más información, consulte Window.closing.

Véase también QCoreApplication::aboutToQuit.