ActionGroup QML Type

Agrupa las acciones. Más...

• Lista de todos los miembros, incluidos los heredados

Propiedades

• actions : list<Action>
• checkedAction : Action
• enabled : bool
• exclusive : bool

Propiedades anexas

• group : ActionGroup

Señales

• triggered(Action action)

Métodos

• void addAction(Action action)
• void removeAction(Action action)

Descripción detallada

ActionGroup es un grupo no visual de acciones. Un grupo de acciones mutuamente exclusive se utiliza con acciones en las que sólo se puede seleccionar una de las opciones a la vez.

La forma más directa de utilizar ActionGroup es declarar las acciones como hijas del grupo.

ActionGroup {
    id: alignmentGroup

    Action {
        checked: true
        checkable: true
        text: qsTr("Left")
    }

    Action {
        checkable: true
        text: qsTr("Center")
    }

    Action {
        checkable: true
        text: qsTr("Right")
    }
}

Alternativamente, la propiedad adjunta group permite declarar las acciones en otro lugar y asignarlas a un grupo específico.

ActionGroup { id: alignmentGroup }

Action {
    checked: true
    checkable: true
    text: qsTr("Left")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Center")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Right")
    ActionGroup.group: alignmentGroup
}

Casos de uso más avanzados pueden ser manejados usando los métodos addAction() y removeAction().

Véase también Action y ButtonGroup.

Documentación de propiedades

actions : list<Action> [default]

Esta propiedad contiene la lista de acciones del grupo.

Véase también group.

checkedAction : Action

Esta propiedad contiene la acción seleccionada actualmente en un grupo exclusivo, o null si no hay ninguna o el grupo no es exclusivo.

Por defecto, es la primera acción seleccionada añadida a un grupo de acciones exclusivo.

Véase también exclusive.

enabled : bool

Esta propiedad indica si el grupo de acciones está habilitado. El valor por defecto es true.

Si esta propiedad es false, todas las acciones del grupo están deshabilitadas. Si esta propiedad es true, todas las acciones del grupo están habilitadas, a menos que se deshabiliten explícitamente.

exclusive : bool

Esta propiedad indica si el grupo de acciones es exclusivo. El valor por defecto es true.

Si esta propiedad es true, sólo se puede comprobar una acción del grupo en un momento dado. El usuario puede activar cualquier acción para comprobarla, y esa acción sustituirá a la existente como acción comprobada en el grupo.

En un grupo exclusivo, el usuario no puede desmarcar la acción actualmente marcada activándola; en su lugar, debe activarse otra acción del grupo para establecer la nueva acción marcada para ese grupo.

En un grupo no exclusivo, marcar y desmarcar acciones no afecta a las demás acciones del grupo. Además, el valor de la propiedad checkedAction es null.

Documentación de la propiedad Attached

ActionGroup.group : ActionGroup

Esta propiedad asocia una acción a un grupo de acciones.

ActionGroup { id: group }

Action {
    checked: true
    text: qsTr("Option A")
    ActionGroup.group: group
}

Action {
    text: qsTr("Option B")
    ActionGroup.group: group
}

Véase también actions.

Documentación sobre señales

triggered(Action action)

Esta señal se emite cuando se ha disparado una action del grupo.

Esta señal es conveniente para implementar un manejador de señales común para todas las acciones del mismo grupo.

ActionGroup {
    onTriggered: console.log("triggered:", action.text)

    Action { text: "First" }
    Action { text: "Second" }
    Action { text: "Third" }
}

Véase también Action::triggered().

Documentación del método

void addAction(Action action)

Añade un action al grupo de acciones.

Véase también actions y group.

void removeAction(Action action)

Elimina un action del grupo de acciones.

Véase también actions y group.