LayoutMirroring QML Type

Propiedad utilizada para reflejar el comportamiento del diseño. Más...

• Lista de todos los miembros, incluidos los heredados

Propiedades

• childrenInherit : bool
• enabled : bool

Descripción detallada

El tipo de adjunto LayoutMirroring se utiliza para reflejar horizontalmente anclas de elementos, tipos de posicionadores (como Row y Grid) y vistas (como GridView y ListView horizontal). El reflejo es un cambio visual: las anclas izquierdas se convierten en anclas derechas, y los tipos de posicionador como Grid y Row invierten la disposición horizontal de los elementos hijos.

El reflejo se activa para un elemento estableciendo la propiedad enabled a true. Por defecto, esto sólo afecta al propio elemento; si se establece la propiedad childrenInherit a true, el comportamiento de reflejo se propaga también a todos los elementos hijos. Si no se ha definido el tipo de conexión LayoutMirroring para un elemento, no se habilitará la duplicación.

El siguiente ejemplo muestra la duplicación en acción. El siguiente Row está anclado a la izquierda de su padre. Sin embargo, como se ha activado la duplicación, el anclaje se invierte horizontalmente y ahora está anclado a la derecha. Además, como los elementos de Row se colocan por defecto de izquierda a derecha, ahora se colocan de derecha a izquierda, como demuestran la numeración y la opacidad de los elementos:

import QtQuick

Rectangle {
    LayoutMirroring.enabled: true
    LayoutMirroring.childrenInherit: true

    width: 300; height: 50
    color: "yellow"
    border.width: 1

    Row {
        anchors { left: parent.left; margins: 5 }
        y: 5; spacing: 5

        Repeater {
            model: 5

            Rectangle {
                color: "red"
                opacity: (5 - index) / 5
                width: 40; height: 40

                Text {
                    text: index + 1
                    anchors.centerIn: parent
                }
            }
        }
    }
}

La duplicación del diseño es útil cuando es necesario utilizar versiones de una aplicación con diseño de izquierda a derecha y de derecha a izquierda para diferentes áreas lingüísticas. La propiedad childrenInherit permite aplicar la duplicación del diseño sin tener que configurar manualmente el diseño de cada elemento de una aplicación. Tenga en cuenta, sin embargo, que la duplicación no afecta a ningún posicionamiento definido por el valor de coordenadas x de Item, por lo que incluso con la duplicación activada, a menudo será necesario aplicar algunas correcciones de diseño para admitir la dirección de diseño deseada. Además, puede ser necesario desactivar el reflejo de elementos hijo individuales (estableciendo LayoutMirroring.enabled en false para dichos elementos) si el reflejo no es el comportamiento deseado, o si el elemento hijo ya implementa el reflejo de alguna forma personalizada.

Para establecer la dirección del diseño basándose en la dirección por defecto de la aplicación, utilice el siguiente código:

LayoutMirroring.enabled: Qt.application.layoutDirection === Qt.RightToLeft

Consulte Interfaces de usuario de derecha a izquierda para obtener más detalles sobre el uso de LayoutMirroring y otras funciones relacionadas para implementar el soporte de derecha a izquierda en una aplicación.

Documentación de propiedades

childrenInherit : bool

Esta propiedad indica si el valor LayoutMirroring.enabled de este elemento es heredado por sus hijos.

El valor por defecto es false.

enabled : bool

Esta propiedad indica si el diseño del elemento se refleja horizontalmente. Establecerlo a true invierte horizontalmente la configuración de las anclas, de forma que las anclas de la izquierda se convierten en anclas de la derecha, y las anclas de la derecha se convierten en anclas de la izquierda. Para los tipos de posicionador (como Row y Grid) y los tipos de vista (como GridView y ListView) esto también refleja la dirección del diseño horizontal del elemento.

El valor por defecto es false.