ParentAnimation QML Type

Anima los cambios en los valores de los padres. Más...

• Lista de todos los miembros, incluidos los heredados

Propiedades

• newParent : Item
• target : Item
• via : Item

Descripción detallada

ParentAnimation se utiliza para animar un cambio de padre para un Item.

Por ejemplo, el siguiente ParentChange cambia blueRect para convertirse en hijo de redRect cuando se hace clic sobre él. La inclusión de ParentAnimation, que define un NumberAnimation que se aplicará durante la transición, garantiza que el elemento se anime suavemente al pasar a su nuevo padre:

import QtQuick

Item {
    width: 200; height: 100

    Rectangle {
        id: redRect
        width: 100; height: 100
        color: "red"
    }

    Rectangle {
        id: blueRect
        x: redRect.width
        width: 50; height: 50
        color: "blue"

        states: State {
            name: "reparented"
            ParentChange { target: blueRect; parent: redRect; x: 10; y: 10 }
        }

        transitions: Transition {
            ParentAnimation {
                NumberAnimation { properties: "x,y"; duration: 1000 }
            }
        }

        MouseArea { anchors.fill: parent; onClicked: blueRect.state = "reparented" }
    }
}

Una ParentAnimation puede contener cualquier número de animaciones. Estas animaciones se ejecutarán en paralelo; para ejecutarlas secuencialmente, defínalas dentro de un SequentialAnimation.

En algunos casos, como cuando se reparenting entre los elementos con recorte activado, es útil para animar el cambio de padre a través de otro elemento que no tiene recorte activado. Dicho elemento puede establecerse utilizando la propiedad via.

ParentAnimation se utiliza normalmente dentro de un Transition junto con un ParentChange. Cuando se utiliza de esta manera, anima cualquier ParentChange que se haya producido durante el cambio de estado. Esto puede anularse estableciendo un elemento de destino específico mediante la propiedad target.

Ver también Animación y Transiciones en Qt Quick y Qt Quick Ejemplos - Animación.

Documentación de Propiedades

newParent : Item

El nuevo padre al que animar.

Si ParentAnimation está definido dentro de Transition, este valor es por defecto el valor definido en el estado final de Transition.

target : Item

El elemento a reparentar.

Cuando se utiliza en una transición, si no se especifica ningún destino, todas las apariciones de ParentChange se animan con ParentAnimation.

via : Item

El elemento a reparent vía. Esto permite realizar una animación sin recorte cuando tanto el padre anterior como el nuevo están recortados.

ParentAnimation {
    target: myItem
    via: topLevelItem
    // ...
}