En esta página

Rotation QML Type

Permite girar un elemento. Más...

Import Statement: import QtQuick

Propiedades

Descripción detallada

El tipo «Rotation» permite rotar un elemento « Item » mediante una transformación de tipo rotación.

Permite que la rotación (eje z) sea relativa a un punto arbitrario y, además, ofrece una forma de especificar rotaciones de tipo 3D para los elementos. Esto proporciona un mayor control sobre la rotación de los elementos que la propiedad « rotation ».

El siguiente ejemplo gira un «Rectangle» alrededor de su punto interior (25, 25):

Rectangle {
    width: 100; height: 100
    color: "blue"
    transform: Rotation { origin.x: 25; origin.y: 25; angle: 45}
}

Para las rotaciones de elementos de tipo 3D, debes especificar el eje de rotación además del punto de origen. El siguiente ejemplo muestra varias rotaciones de tipo 3D aplicadas a un « Image ».

import QtQuick

Row {
    x: 10; y: 10
    spacing: 10

    Image { source: "images/qt-logo.png" }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 18 }
    }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 36 }
    }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 54 }
    }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 72 }
    }
}

Cinco logotipos de Qt que muestran rotaciones en 3D alrededor del eje vertical

Véase también el ejemplo de control de dial y la demostración de «Qt Quick » (Relojes).

Documentación de propiedades

angle : real

El ángulo de rotación, en grados en el sentido de las agujas del reloj.

axis group

axis.x : real

axis.y : real

axis.z : real

El eje alrededor del cual se realiza la rotación. Para una rotación simple (2D) alrededor de un punto, no es necesario especificar un eje, ya que el eje por defecto es el eje z (axis { x: 0; y: 0; z: 1 }).

Para una rotación típica de tipo 3D, normalmente se especificarán tanto el origen como el eje.

Sistema de coordenadas 3D con un rectángulo morado girado alrededor del eje y en el plano XY

distanceToPlane : real [since 6.11]

Esta propiedad define la distancia entre el plano de visión (la pantalla virtual) y el observador en el modelo de proyección en perspectiva.

Una distancia menor produce un efecto de perspectiva más marcado, lo que hace que el objeto parezca alejarse o acercarse de forma más pronunciada durante la rotación. Un valor mayor da como resultado un aspecto más plano y ortográfico, con una distorsión de perspectiva menos visible.

El valor por defecto es « 1024.0 », que proporciona una perspectiva moderada adecuada para la mayoría de los casos de uso.

Cuando esta propiedad se establece en 0, no se aplica ninguna proyección en perspectiva. En este caso, la rotación se realiza directamente en el espacio 3D utilizando la transformación definida por QMatrix4x4::rotate().

Esta propiedad solo afecta a las rotaciones alrededor de los ejes x e y. Las rotaciones alrededor del eje z (rotaciones 2D) no se ven afectadas por esta propiedad.

Esta propiedad se introdujo en Qt 6.11.

origin group

origin.x : real

origin.y : real

El punto de origen de la rotación (es decir, el punto que permanece fijo respecto al elemento padre mientras el resto del elemento gira). Por defecto, el origen es (0, 0).

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.