ActionGroup QML Type

Regroupe les actions. En savoir plus…

• Liste de tous les membres, y compris les membres hérités

Propriétés

• actions : list<Action>
• checkedAction : Action
• enabled : bool
• exclusive : bool

Propriétés associées

• group : ActionGroup

Signaux

• triggered(Action action)

Méthodes

• void addAction(Action action)
• void removeAction(Action action)

Description détaillée

ActionGroup est un groupe d'actions non visuel. Un groupe d'actions mutuellement exclusive s est utilisé avec des actions pour lesquelles une seule option peut être sélectionnée à la fois.

La manière la plus simple d'utiliser ActionGroup consiste à déclarer les actions en tant qu'enfants du groupe.

ActionGroup {
    id: alignmentGroup

    Action {
        checked: true
        checkable: true
        text: qsTr("Left")
    }

    Action {
        checkable: true
        text: qsTr("Center")
    }

    Action {
        checkable: true
        text: qsTr("Right")
    }
}

Il est également possible d’utiliser la propriété attachée « group » pour déclarer les actions ailleurs et les affecter à un groupe spécifique.

ActionGroup { id: alignmentGroup }

Action {
    checked: true
    checkable: true
    text: qsTr("Left")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Center")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Right")
    ActionGroup.group: alignmentGroup
}

Des cas d’utilisation plus avancés peuvent être gérés à l’aide des méthodes ` addAction() ` et ` removeAction() `.

Voir également Action et ButtonGroup.

Documentation sur les propriétés

actions : list<Action> [default]

Cette propriété contient la liste des actions du groupe.

Voir également group.

checkedAction : Action

Cette propriété contient l'action actuellement sélectionnée dans un groupe exclusif, ou la valeur « null » s'il n'y en a pas ou si le groupe est non exclusif.

Par défaut, il s'agit de la première action cochée ajoutée à un groupe d'actions exclusif.

Voir également « exclusive ».

enabled : bool

Cette propriété indique si le groupe d’actions est activé. La valeur par défaut est « true ».

Si cette propriété est définie sur « false », toutes les actions du groupe sont désactivées. Si cette propriété est définie sur « true », toutes les actions du groupe sont activées, sauf si elles sont explicitement désactivées.

exclusive : bool

Cette propriété indique si le groupe d'actions est exclusif. La valeur par défaut est « true ».

Si cette propriété est définie sur « true », une seule action du groupe peut être sélectionnée à un moment donné. L’utilisateur peut déclencher n’importe quelle action pour la sélectionner ; cette action remplacera alors l’action existante en tant qu’action sélectionnée dans le groupe.

Dans un groupe exclusif, l’utilisateur ne peut pas désélectionner l’action actuellement sélectionnée en la déclenchant ; il doit au contraire déclencher une autre action du groupe pour définir la nouvelle action sélectionnée pour ce groupe.

Dans un groupe non exclusif, le fait de cocher ou de décocher des actions n'affecte pas les autres actions du groupe. De plus, la valeur de la propriété « checkedAction » est « null ».

Documentation sur les propriétés associées

ActionGroup.group : ActionGroup [attached]

Cette propriété associe une action à un groupe d'actions.

ActionGroup { id: group }

Action {
    checked: true
    text: qsTr("Option A")
    ActionGroup.group: group
}

Action {
    text: qsTr("Option B")
    ActionGroup.group: group
}

Voir également actions.

Documentation sur les signaux

triggered(Action action)

Ce signal est émis lorsqu'une « action » du groupe a été déclenchée.

Ce signal est pratique pour implémenter un gestionnaire de signal commun à toutes les actions d'un même groupe.

ActionGroup {
    onTriggered: console.log("triggered:", action.text)

    Action { text: "First" }
    Action { text: "Second" }
    Action { text: "Third" }
}

Voir également Action::triggered().

Documentation de la méthode

void addAction(Action action)

Ajoute un objet « action » au groupe d'actions.

Voir également actions et group.

void removeAction(Action action)

Supprime un « action » du groupe d'actions.

Voir également actions et group.